在小牛上显示隐藏文件的热键不见了？

在OS X的早期版本中，可以使用Command-Shift-Period在Finder对话框中显示隐藏文件（打开，保存等）。

在Mavericks中，该功能不适用于我。还有另一个可以使用的命令吗？我不希望全局启用隐藏文件。

编辑：我是提供赏金的人。似乎我无法发表评论，因为我现在没有足够的代表:)

所以...是的，我也正在运行10.9.1，它不起作用。我在OSX的早期版本中使用过它，并且效果很好。提到的脚本可以在Finder中显示隐藏的文件，但是在使用“打开/保存”对话框时效果不佳。

我的用例：有时我需要打开/保存文件到/tmp目录。在OSX的CommandShift.早期版本中，我只是使用对话框访问磁盘根目录，然后按，然后可以看到/tmp目录（实际上是/private/tmp）。

因此，如果你们使用的是相同版本的OSX，并且确实适合您，我想必须有一种重新激活它的方法。有任何想法吗？

键绑定在Maverick上的“列”视图模式下不起作用，但在“列表”视图模式下起作用。在“列表”视图模式下进行切换后，切换回“列”视图模式，然后显示隐藏的文件。

我当前正在运行OS X（10.9.1），只是在保存对话框中尝试了⌘+ ⇧+ .键盘快捷键，所以效果很好。

我还使用^+ ⌘+ ⇧+ 键盘快捷方式在计算机上设置了AppleScript .，可在需要时在Finder中切换隐藏文件的可见性。这样，我不必手动运行终端命令来显示隐藏文件，而且我可以快速将其关闭以避免意外修改系统文件。我使用FastScripts（在Mac App Store中也有售）来允许我为AppleScript设置键盘快捷键，并将AppleScript放在~/Library/Scripts文件夹中。

更新资料

我已经更新了我的脚本，以便您不必每次希望显示/隐藏隐藏文件的显示时都将Finder杀死。正如markhunte所指出的，您可以切换Finder窗口的视图状态，这将刷新内容列表。感谢markhunte向我指出了这一点！这是更新的脚本：

(*
    Author: Anil Natha
    Description: 
        This script toggles the visibility of hidden files in OS X. This includes
        showing hidden files in Finder windows and on the desktop.
    Last Updated: 2015-02-20
*)
tell application "System Events"

    try
        set hiddenFilesDisplayStatus to do shell script "defaults read com.apple.finder AppleShowAllFiles"
    on error
        set hiddenFilesDisplayStatus to "NO"
    end try
    set hiddenFilesNewDisplayStatus to "NO"

    if hiddenFilesDisplayStatus is "NO" then
        set hiddenFilesNewDisplayStatus to "YES"
    end if

    do shell script "defaults write com.apple.finder AppleShowAllFiles " & hiddenFilesNewDisplayStatus

end tell

tell application "Finder"

    set allWindows to windows

    repeat with currentWindow in allWindows
        set currentWindowView to get the current view of the currentWindow
        set alternateWindowView to list view
        if currentWindowView is list view then
            set alternateWindowView to icon view
        end if
        set the current view of the currentWindow to alternateWindowView
        set the current view of the currentWindow to currentWindowView
    end repeat

end tell

下面列出了较旧版本的脚本。尽管它可以工作，但是由于上面的脚本可以更有效地工作，所以我不建议您再使用它。

tell application "System Events"

    set hiddenFilesDisplayStatus to do shell script "defaults read com.apple.finder AppleShowAllFiles"
    set hiddenFilesNewDisplayStatus to "NO"

    if hiddenFilesDisplayStatus is "NO" then
        set hiddenFilesNewDisplayStatus to "YES"
    end if

    do shell script "defaults write com.apple.finder AppleShowAllFiles " & hiddenFilesNewDisplayStatus
    do shell script "killall Finder"

end tell

从来不知道该功能存在。但是，然后，我一直使用一种不同的方式，该方式仍然适用于10.9：

该系统扩展默认文件夹X。这是老货，仍然运转良好。

其高级选项之一是Option在选择“打开/保存”时按住以显示所有文件，包括隐藏的文件。

它仍然可以正常工作，但是对我来说却有很多问题。

我不得不更改目录，然后返回到第一个文件夹。然后显示隐藏文件。

关闭/重新打开对话框无济于事。我不确定错误的发生范围或触发的原因（这款笔记本电脑开箱不到48小时）。

快捷方式⌘⇧。在Mavericks上仍然对我有效。自从以前的OS X版本以来，似乎没有更改。

您可以尝试一些事情…

• 确保您正在查看的文件夹具有隐藏的文件/文件夹。

  • 您可以ls在终端中使用以查看是否存在隐藏的文件/文件夹：

    cd /path/to/folder && ls -la
    

• 确保您没有将快捷方式重新映射到其他内容。

  • 检查系统偏好设置 → 键盘 → 快捷方式以查找到⌘⇧的任何映射。
  • 检查所有3 ^次第三方应用的映射⌘⇧。

正如许多其他人所说，它仍然可以正常工作。也许您更改了此快捷方式，并且该快捷方式掩盖了要显示隐藏文件的预期任务。

这不是解决热键的方法，但我将分享我用于此任务的内容。Funter应用

您可以默认使用以下终端命令将其打开：

defaults write com.apple.finder AppleShowAllFiles -boolean true
killall Finder

...但是，与键盘快捷键相比，这不方便...但是您可以创建一个Automator工作流，该工作流运行一项服务，该服务运行一个Terminal命令，这些命令全部分配给了System Preferences Keyboard Shortcut ...，但仍然不那么方便。