自切换到优胜美地以来，AppleScript“延迟”命令不起作用

注意：问题delay已在OS X 10.11 El Capitan中修复。

自从我升级到优胜美地以来，使用延迟的Applescript停止运行。我怎样才能解决这个问题？

举一个简单的例子，这是世界上最简单的Applescript：

set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0
delay 5
set volume output volume 20
delay 5
set volume output volume 0

这需要30秒才能完成。如果我在脚本编辑器（以前称为Applescript编辑器）中运行它，则需要30秒才能完成。但是，如果我将此脚本另存为应用程序，则在启动该应用程序时，延迟将被忽略，并且该应用程序将花费一秒钟的时间来完成。

在进入下一步之前，如何强制Applescript延迟指定的时间？这是优胜美地故障吗？有可靠的解决方法吗？

注意：问题delay已在OS X 10.11 El Capitan中修复。

@ 2oh1，您的答案中有正确的基本概念，但这是一个完整而正确的答案：

解决此问题的唯一合理方法是在循环中调用“延迟”，以确保在继续操作之前经过了所需的持续时间。最好的方法是使用自定义处理程序覆盖“延迟”：

on delay duration
  set endTime to (current date) + duration
  repeat while (current date) is less than endTime
    tell AppleScript to delay endTime - (current date)
  end repeat
end delay

这使您可以保留脚本的其余部分不变，并且可以正常使用“延迟”，例如，

delay 5
display alert "I like cake!"

[注意：通常，自定义处理程序将使用“持续延迟持续时间”来调用内置的“延迟”，但是我发现，尽管这在脚本编辑器中有效，但在applet中使用时会返回错误（“可以” t继续延迟。（-1708）”）。我通过直接告诉AppleScript处理delay命令而不是使用“ continue”到达那里来解决该问题。

问题在于，delay在暂停脚本的同时会处理用户输入，因此您仍然可以单击小程序显示的菜单或窗口，并且存在一个错误（已在10.11中修复），该错误导致用户输入delay在恢复脚本执行之前未等待完整的持续时间。如果您不与小程序交互，则delay可以正常工作。

在解决同一问题时，我遇到了一个不太相关的问题的答案，因此决定尝试一下，它似乎对我有用。

只需替换delay 5为do shell script "/bin/sleep 5"，即可获得相同的结果。

我并不是说这是最好的解决方案，但似乎已经解决了我的问题。我不再使用简单的延迟（由于我不明白的原因而被忽略），我改用获取时间并循环直到到达新的时间（它仍然使用延迟，但是忽略则无所谓延迟，因为脚本要到指定时间才会继续执行）。

# Pause for five minutes
set GetTheTime to current date
set NewTime to GetTheTime + (5 * minutes)
repeat while (current date) is less than NewTime
    delay 60
end repeat

我仍然很想知道为什么延迟被忽略（或者大大加快了速度！！ ？？），但这可以完成工作，而且笨拙。

我在德语论坛帖子中找到了解决方法。将这些行添加到脚本顶部：

use framework "Foundation"
use scripting additions
current application's NSThread's sleepForTimeInterval:1

我认为carzyj是最好的答案，但是当与Chris Page的方法结合使用时，您会得到：

on delay duration
  do shell script "/bin/sleep " & duration
end delay

您可以通过“结束延迟”注释掉“延迟”，以恢复为原始延迟。

这是对@ chris-page解决方案的修改

这似乎是响应性和准确捕获延迟之间的平衡。

on delay duration
    set endTime to (current date) + duration
    repeat while (current date) is less than endTime
        set delta to duration / 100
        if duration < 0.2 then
            set delta to 0.2
        end if
        tell AppleScript to delay delta
    end repeat
end delay

但是，我们并没有告诉Applescript延迟整个持续时间，而只是告诉它延迟了整个持续时间的一小部分。如果周期小于苹果允许的时间（1/60秒），那么我们就将其设置为该增量。我们可以保持一些响应能力，但仍然是准确的。令人怀疑的是，有时延迟不起作用，所以repeat while循环将使线程锁定，但是在成功的情况下，我们希望延迟增量较短，以便仍然可以中断进程

因此，综上所述，我相信克里斯的意思是：

on delay duration
   set endTime to (current date) + duration
   repeat while (current date) is less than endTime
      tell AppleScript to delay endTime - (current date)
   end repeat
end delay