AppleScript：关闭所有打开的Windows

我正在尝试编写一个苹果脚本来关闭所有打开的Windows。以下是我尝试的内容：

tell application "System Events"
  repeat with theProcess in (application processes where visible is true)
      tell application theProcess
          close
      end tell
   end repeat
end tell

这似乎不起作用。我明白了：

脚本错误：系统事件出错：无法获取应用程序（每个应用程序进程的第1项，其visible = true）。号码-1728

如果应用程序退出或者窗口关闭，我不在乎。

我试着调试这个，但我无法在Xcode中打开这个脚本。

编辑：感谢user3439894我已经确定了以下脚本，它只是发送Command + Q到每个可见的应用程序：

tell application "System Events"
    set theVisibleApps to (name of application processes where visible is true)
end tell



repeat with thisApp in theVisibleApps
    try
        tell application thisApp to activate
        tell application "System Events"
            keystroke "q" using command down
        end tell
    on error errMsg
        display dialog errMsg
    end try
end repeat

这对我来说现在很有用。正如user3439894建议的那样，我需要了解AppleScript语言指南

第一个问题是什么(application processes where visible is true)回报。

例如，在仅使用Finder和脚本编辑器打开的干净安装的macOS 10.13上：

tell application "System Events" to get application processes where visible is true

返回：

{application process "Script Editor" of application "System Events", application process "Finder" of application "System Events"}

您真正想要的是获取可见的应用程序名称列表，例如：

tell application "System Events" to get name of every application process where visible is true

返回：

{"Script Editor", "Finder"}

以下示例 AppleScript 代码将尝试关闭每个应用程序的所有打开文档，并在出错时关闭所有窗口。

现在我在TextEdit和Preview中打开了一些文档，然后Finder中的一些窗口运行了示例 AppleScript 代码。它关闭了TextEdit和Preview中的所有打开文档以及Finder中的所有窗口，但不关闭脚本编辑器。

注意：这不会关闭和脚本编辑器文档和静默错误：

error "The document can’t be closed while the script is running."

示例 AppleScript 代码：

tell application "System Events"
    set theVisibleApps to (name of application processes where visible is true)
end tell

repeat with thisApp in theVisibleApps
    try
        tell application thisApp
            try
                close every document without saving
            on error
                close every window
            end try
        end tell
    end try
end repeat

另外请注意，这个例子 的AppleScript 码作为编码不会关闭每个文件或关闭每一个窗口的的应用程序不支持这些命令，应该默默地失败因为的try 命令。

此示例 AppleScript 代码用于说明您当前代码的错误以及如何帮助实现目标的示例。