别名 - 新标签中的“显示原始”

更新：
在到目前为止的两个答案后，我略微移动了球门柱。我需要多个选择＆amp;标签 - 现有答案;一个有多选功能，另一个给我标签，我已经意识到这是要走的路。

我决定在不打扰原始层次结构的情况下跟踪已发布照片目录的最佳方法是将别名拖到一个单独的位置。

但是，许多用例需要原件;他们无法应对别名本身，例如网站或Photos.app

右键单击 - Show Original坚持在同一个窗口容器中显示它，因此返回别名文件夹失去位置，选择就消失了。在一个大文件夹中，这确实会测试你的记忆，以确定你在哪里。

有没有办法强制它在新窗口中打开，类似于Cmd /双击文件夹，从而保留在别名文件夹中的位置？

目前在High Sierra 10.13.4上

我环顾四周，找到了一个只需要你想要的AppleScript（可以变成一个快捷方式）。不幸的是，它不应该像它应该的那样超级简单。它总比没有好，你只需要做一次。从长远来看，它将为您节省时间。

1）打开Automator。

2）创建新的“服务”

3）在“Finder”中将服务接收设置为“无输入”

4）添加'Run applescript'

5）将此代码放入其中：

-- duplicateFinderTab.scpt
-- Uses a hacky workaroud to duplicate the frontmost Finder tab,
-- since Apple hasn't provided great AppleScript support for this.

----------------------------------------------
on run {}
    tell application "Finder"
        if (count of Finder windows) > 0 then set duplicate_me to target of front Finder window
        set _sel to the selection
    end tell

    new_tab()

    tell application "Finder"
        set target of front Finder window to duplicate_me
        select _sel
    end tell

    open_orig()

end run

----------------------------------------------
on new_tab()
    tell application "System Events" to tell application process "Finder"
        set frontmost to true
        tell front menu bar to tell menu "File" to tell menu item "New Tab"
            perform action "AXPress"
        end tell
    end tell
end new_tab
----------------------------------------------
on open_orig()
    tell application "System Events" to tell application process "Finder"
        set frontmost to true
        tell front menu bar to tell menu "File" to tell menu item "Show Original"
            perform action "AXPress"
        end tell
    end tell
end open_orig

6）保存它（如果你打开一个取景器窗口，并选择你的别名，然后回到automator并点击'run'，那么它将在这一点工作） - 注意：它可能会提示你添加'Automator'到'系统偏好' - ＆gt; '安全＆amp;隐私' - ＆gt; '辅助功能'权限。

7）在系统偏好中转到'键盘' - ＆gt; '快捷方式' - ＆gt; '服务' - ＆gt; '无论你命名它'......选择一个快捷方式（如“^ -CMD-O”）。

其他事情：

它可能要求您执行一次：

选择取景器后，在菜单中，

'Finder' - ＆gt; '服务' - ＆gt; '无论你怎么命名'

或者如果没有出现：

'Finder' - ＆gt; '服务' - ＆gt; '服务首选项..' - ＆gt;选中系统首选项中调用应用程序的框

根据您的系统设置方式，您可能会收到其他权限错误，但是，您应该注意到在步骤6或步骤5之后点击“运行”时脚本可以正常工作。只需首先在查找器中选择文件然后交换到automator应用程序并点击“运行”。

如果一切顺利，你的cmd-cntl-O快捷方式应该适合你，所以你可以做那个快捷方式（打开一个相同选择的新选项卡），然后右键单击并选择'show original'

由OP编辑
如果您收到错误“com.automator.runner.xpc不允许辅助访问”，则解决方法不明显。
您不能将com.automator.runner.xpc本身添加到Assistive Access，也不能添加Automator或Automator Runner帮助，但是在重新启动后线索是两个错误被触发，而不仅仅是一个。

将Finder本身添加到Assistive Access允许脚本运行。

没有UI脚本的更简洁，更简洁的解决方案：

打开Automator，创建一个新服务，从Finder接受文件和文件夹，添加一个 运行AppleScript 行动并输入以下内容：

on run {input, parameters}
    repeat with aFile in input
        tell application "Finder"
            try
                set origFile to original item of aFile
                set aWindow to make new Finder window
                set aWindow's target to origFile's parent
                select origFile
            end try
        end tell
    end repeat
end run

你的屏幕应该是这样的：

将Automator服务保存为 在新窗口中显示 然后打开 系统偏好设置/键盘/快捷方式/服务 。找出 在新窗口中显示 服务，点击 添加快捷方式 并输入 ⌥ ⌘ [R 。你的屏幕应该是这样的：

关闭并在Finder中尝试该服务，方法是选择一个或多个别名并按下所选的快捷方式 ⌥ ⌘ [R 。它适用于多个文件，文件夹，即使某些项目实际上不是别名，也可以执行显示（因此脚本中的try / end尝试）。

在...的帮助下 堆栈溢出 ＆安培;从两个答案中提出的想法开始 brw59 boris42 ，我现在有了这个，通过 user3439894

on run {input, parameters}
    set madeNewWindow to false
    repeat with i from 1 to count input
        tell application "Finder"
            if (kind of item i of input) is equal to "Alias" then
                set origFile to original item of item i of input
                if not madeNewWindow then
                    set aWindow to make new Finder window
                    set madeNewWindow to true
                else
                    my makeNewTab()
                end if
                set aWindow's target to origFile's parent
                select origFile
            end if
        end tell
    end repeat
end run

on makeNewTab()
    tell application "System Events" to tell application process "Finder"
        set frontmost to true
        tell front menu bar to tell menu "File" to tell menu item "New Tab"
            perform action "AXPress"
        end tell
    end tell
end makeNewTab

它结合了我 思想 我需要的是我 其实 需要，同时使用UI和非UI脚本和＆amp;给我一个新的窗口，很好地填充了标签，所有选择了一个别名，所以我可以翻阅标签＆amp;一次处理一个选择，然后关闭，留下我原来的窗口。