创建AppleScript以进行击键

我一直在努力做我自己的AppleScript让我的Mac按C 13次，按左箭头键，按C 13次，按右箭头键并以1.7秒的间隔重复从头开始。

目前我只设法做一个工作脚本，使其多次按C键。有人可以帮我这个吗？这就是我现在所拥有的

set i to 0
repeat while i < 1.0E+300
    set i to i + 1
    delay 1.7
    tell application "System Events" to keystroke "c"
end repeat

要开始了，人数1.0E+300是一个非常真的大数目。这比整个宇宙中的原子数多了几个。

你的剧本并不遥远。要按"c"十三次，你可以这样做：

repeat 13 times
    tell application "System Events" to keystroke "c"
    -- delay 0.1
end repeat

（你可能需要一点点延迟来记录个别击键，但是你可以试一试，看看哪个有效）;

或者你可以这样做：

tell application "System Events" to keystroke "ccccccccccccc"

这相当于没有延迟的重复循环。

左右箭头键分别为key code 123和key code 124。所以，在键击之间添加：

tell application "System Events"
    keystroke "ccccccccccccc"
    delay 0.1
    key code 123 -- left arrow
    delay 0.1
    keystroke "ccccccccccccc"
    delay 0.1
    key code 124 -- right arrow
end tell

要么：

tell application "System Events"
    repeat 13 times
        keystroke "c"
        delay 0.1
    end repeat

    key code 123 -- left arrow
    delay 0.1

    repeat 13 times
        keystroke "c"
        delay 0.1
    end repeat

    key code 124 -- right arrow
end tell

最后，以1.7秒的间隔在循环上无限制地执行此广告将产生类似于此的内容：

tell application "System Events" to repeat
    repeat 13 times
        keystroke "c"
        delay 0.1
    end repeat

    key code 123 -- left arrow
    delay 0.1

    repeat 13 times
        keystroke "c"
        delay 0.1
    end repeat

    key code 124 -- right arrow

    delay 1.7
end repeat

需要注意的是外界最重复循环没有while，until或times限制其延续。它将永远循环，直到您手动停止脚本。

我也没有将0.1秒的延迟归因于整个1.7秒的延迟。较小的延迟总共超过1.7秒，但我会让您根据需要调整时间。