作为对Paul的回答的补充，我编写了一个简短的程序来演示如何驱动他的图形的7段4位数字显示：
这实际上是一个普通的阴极显示器，因此该程序假定该情况以及图中的特定布线。有趣的部分是refresh_display()函数，应该定期调用它。算法如下：
- 用我们想要显示的数字之一的适当信号驱动7个阳极
- 设置
HIGH通过NPN晶体管控制该数字阴极的输出
- 等待2.5毫秒（刷新率为100 Hz）
- 设置
LOW阴极控制输出
- 移至下一位。
应该注意的是，通过使用Blink Without Delay Arduino教程中描述的技术，可以在不阻塞CPU的情况下完成等待。这是程序：
const int NB_DIGITS = 4; // 4-digit display
const int FIRST_ANODE = 2; // anodes a..g on pins 2..8
const int FIRST_CATHODE = 9; // cathodes, right to left, on pins 9..12
// Digits to display, from right to left.
uint8_t digits[NB_DIGITS];
// Set all the used pins as outputs.
void init_display()
{
for (int i = 0; i < 7; i++)
pinMode(FIRST_ANODE + i, OUTPUT);
for (int i = 0; i < NB_DIGITS; i++)
pinMode(FIRST_CATHODE + i, OUTPUT);
}
// This should be called periodically.
void refresh_display()
{
// Our 7-segment "font".
static const uint8_t font[10] = {
//abcdefg
0b1111110, // 0
0b0110000, // 1
0b1101101, // 2
0b1111001, // 3
0b0110011, // 4
0b1011011, // 5
0b1011111, // 6
0b1110000, // 7
0b1111111, // 8
0b1111011 // 9
};
// Wait for 2.5 ms before switching digits.
static uint32_t last_switch;
uint32_t now = micros();
if (now - last_switch < 2500) return;
last_switch = now;
// Switch off the current digit.
static uint8_t pos;
digitalWrite(FIRST_CATHODE + pos, LOW);
// Set the anodes for the next digit.
pos = (pos + 1) % NB_DIGITS;
uint8_t glyph = font[digits[pos]];
for (int i = 0; i < 7; i++)
digitalWrite(FIRST_ANODE + i, glyph & 1 << (6-i));
// Switch digit on.
digitalWrite(FIRST_CATHODE + pos, HIGH);
}
/***********************************************************************
* Example usage.
*/
void setup()
{
init_display();
}
void loop()
{
uint32_t now = millis();
// Change the number displayed every second.
static uint32_t last_change;
if (now - last_change >= 1000) {
digits[3] = digits[2];
digits[2] = digits[1];
digits[1] = digits[0];
digits[0] = (digits[0] + 1) % 10;
last_change = now;
}
refresh_display();
}
Paul提供了有关Parallax教程的链接，该链接
建议使用
Multiplex7Seg
Arduino库。该库比上面的示例代码更通用，因为它不对使用的引脚做任何假设。但是库和此代码之间的最大区别在于计时的管理方式：
- 该库由定时器2溢出中断驱动。这应该提供一个非常稳定的计时，但要为此花费一个计时器。
- 上面的代码依赖于用户
refresh_display()经常调用。它不需要专用的硬件资源，但不能与花费太长时间的程序配合使用loop()：它不喜欢您调用delay()。
