将PWM频率设置为25 kHz

我目前可以使用以下代码将四个PWM引脚设置为31 kHz左右：

void setup()
{
    TCCR1B = TCCR1B & B11111000 | B00000001; // Set PWM frequency for D9 & D10:
    pinMode(pwmPin9, OUTPUT); // Sets the pin as output
    pinMode(pwmPin10, OUTPUT); // Sets the pin as output


    TCCR2B = TCCR2B & B11111000 | B00000001; // Set PWM for D3 & D11
    pinMode(pwmPin3, OUTPUT); // Sets the pin as output
    pinMode(pwmPin11, OUTPUT); // Sets the pin as output
}

我在某处找到了此设置，但我不知道如何将这四个PWM引脚设置为25 kHz左右。那怎么可能？

我发布了第二个答案，因为我意识到可以在单个Arduino Uno上以161个步长使用25 kHz的4个PWM通道。这涉及将主时钟频率更改为8 MHz，这会产生一些副作用，因为整个程序的运行速度将降低一半。它还涉及重新配置三个定时器，该装置松动Arduino的计时功能（millis()，micros()，delay()和 delayMicroseconds()）。如果这些折衷是可以接受的，请按以下步骤进行：

void setup()
{
    // Set the main system clock to 8 MHz.
    noInterrupts();
    CLKPR = _BV(CLKPCE);  // enable change of the clock prescaler
    CLKPR = _BV(CLKPS0);  // divide frequency by 2
    interrupts();

    // Configure Timer 0 for phase correct PWM @ 25 kHz.
    TCCR0A = 0;           // undo the configuration done by...
    TCCR0B = 0;           // ...the Arduino core library
    TCNT0  = 0;           // reset timer
    TCCR0A = _BV(COM0B1)  // non-inverted PWM on ch. B
        | _BV(WGM00);  // mode 5: ph. correct PWM, TOP = OCR0A
    TCCR0B = _BV(WGM02)   // ditto
        | _BV(CS00);   // prescaler = 1
    OCR0A  = 160;         // TOP = 160

    // Same for Timer 1.
    TCCR1A = 0;
    TCCR1B = 0;
    TCNT1  = 0;
    TCCR1A = _BV(COM1A1)  // non-inverted PWM on ch. A
        | _BV(COM1B1)  // same on ch. B
        | _BV(WGM11);  // mode 10: ph. correct PWM, TOP = ICR1
    TCCR1B = _BV(WGM13)   // ditto
        | _BV(CS10);   // prescaler = 1
    ICR1   = 160;

    // Same for Timer 2.
    TCCR2A = 0;
    TCCR2B = 0;
    TCNT2  = 0;
    TCCR2A = _BV(COM2B1)  // non-inverted PWM on ch. B
        | _BV(WGM20);  // mode 5: ph. correct PWM, TOP = OCR2A
    TCCR2B = _BV(WGM22)   // ditto
        | _BV(CS20);   // prescaler = 1
    OCR2A  = 160;
}

void loop()
{
    analogWrite( 3,   1);  // duty cycle = 1/160
    analogWrite( 5,  53);  // ~ 1/3
    analogWrite( 9, 107);  // ~ 2/3
    analogWrite(10, 159);  // 159/160
}

与其他答案不同，它不需要以下版本的修改版本analogWrite()：标准版本 可以正常工作。仅应注意：

1. 写入的值应介于0（始终表示LOW）到160（始终表示HIGH）之间（包括端点值）。
2. 仅引脚3、5、9和10可用。尝试连接analogWrite() 到引脚6或11不仅会无法提供PWM输出，还会分别改变引脚5或3的频率。

您可以将定时器1配置为在相位校正PWM模式下以25 kHz的周期循环，并在引脚9和10上使用它的两个输出，如下所示：

// PWM output @ 25 kHz, only on pins 9 and 10.
// Output value should be between 0 and 320, inclusive.
void analogWrite25k(int pin, int value)
{
    switch (pin) {
        case 9:
            OCR1A = value;
            break;
        case 10:
            OCR1B = value;
            break;
        default:
            // no other pin will work
            break;
    }
}

void setup()
{
    // Configure Timer 1 for PWM @ 25 kHz.
    TCCR1A = 0;           // undo the configuration done by...
    TCCR1B = 0;           // ...the Arduino core library
    TCNT1  = 0;           // reset timer
    TCCR1A = _BV(COM1A1)  // non-inverted PWM on ch. A
           | _BV(COM1B1)  // same on ch; B
           | _BV(WGM11);  // mode 10: ph. correct PWM, TOP = ICR1
    TCCR1B = _BV(WGM13)   // ditto
           | _BV(CS10);   // prescaler = 1
    ICR1   = 320;         // TOP = 320

    // Set the PWM pins as output.
    pinMode( 9, OUTPUT);
    pinMode(10, OUTPUT);
}

void loop()
{
    // Just an example:
    analogWrite25k( 9, 110);
    analogWrite25k(10, 210);
    for (;;) ;  // infinite loop
}

用写入值0 analogWrite25k()表示该引脚将始终为低电平，而将320表示始终为高电平。常规analogWrite() 应该几乎可以工作，但是它将解释255与320相同（即始终为HIGH）。

该代码假定使用Arduino Uno或类似的板卡（ATmega168或328 @ 16 MHz）。这里使用的方法需要一个16位定时器，因此它使用定时器1，因为它是Uno上唯一可用的定时器。这就是为什么只有两个输出可用的原因。该方法可适用于具有16位定时器的其他基于AVR的板。正如Gerben指出的那样，该计时器应具有一个对应的ICRx寄存器。Arduino Mega上有4个这样的计时器，每个都有3个输出。