无效循环之外的功能如何工作？

我习惯了Arduino草图，其中void setup()一部分可以运行一次，而void loop()一部分会不断循环。当main之外具有void函数时会发生什么void loop()？这些都将保持并行循环还是一个接一个地运行？还是某些void函数仅在满足某些条件时才运行（例如while循环）？

例如，在下面的代码中，void receiveData(int byteCount)和void sendData()函数何时运行？

//I2C_test

//This code demonstrates communication via an I2C bus between a raspberry pi and an arduino.
//When the Raspberry pi (master) sends data to the Arduino (slave), the Arduino uses this
//data to control a motor. After the Arduino has recieved data from the master, it then collects
//data from the external environment via a sensor and sends this data back to the Raspberry pi.

#include <Wire.h>
int number = 0; //Declare variables
int val = 0;

void setup() {
  //Anything between the curly brackets runs once when the arduino is turned on or reset
  pinMode(0, INPUT);
  //Set pin 0 as input and 3 as output
  pinMode(3, OUTPUT);
  Serial.begin(9600);
  //Set the data rate for serial transmission at 9600bps
  Wire.begin(0x04);
  //Initiate the Wire library, join the Arduino as a slave, and specify its 7 bit slave address
  Wire.onReceive(receiveData);
  //Define callbacks for i2c communication
  Wire.onRequest(sendData);
}

void loop() {
  //The code between the curly brackets keeps repeating
  delay(100);
}

void receiveData(int byteCount) {
  while(Wire.available()) {
    number = Wire.read();
    //Set the variable "number" to the data sent by the master
    analogWrite(3, number);
    //Write this number to pin 3 (PWM). This controls the motor speed
  }
  val = analogRead(0);
  //Read the voltage on pin 0 (connected to the sensor). Map input voltages between 0 and 5 volts into integer values between 0 and 1023
}

void sendData() {
  Wire.write(val);
  //Send the data read from the sensor to the master.
}

该setup()和loop()，因为他们是由Arduino的代码自动为你调用的函数是不寻常的。没有其他函数会以这种方式运行。

一般来说，除非您自己明确地调用它（例如，从内部setup()或loop()），或者指示程序的另一部分进行调用，否则该函数永远不会运行。（还有其他执行函数的方法，但这通常涉及一些非常高级的修补程序，最好避免。）

例如，pinMode()是与其他函数一样的函数。它仅在您实际pinMode(3, INPUT)在代码中放入类似内容时运行。到那时，它运行一次，结束，然后调用函数从中断处继续运行（它们从不并行运行）。

您发布的示例代码非常有趣。看一下这些行setup()：

Wire.onReceive(receiveData);
Wire.onRequest(sendData);

这些行告诉Wire对象要调用receiveData()并sendData()响应I2C事件。它通过传递由存储和使用的函数指针来做到这一点Wire。

如果您想了解更多有关C / C ++函数指针的信息，建议您在线搜索。您可能也有兴趣探索Arduino的attachInterrupt()功能。

难道不是setup()一次被调用又loop()被反复调用的情况？即有一个看不见的 main()可能看起来像这样：

void main(){
  setup();
  while(True){
    loop();
  }
}

抱歉，我只是研究Arduino而几乎没有C / C ++经验；我正在尝试loop()自己解决这种情况。

我无法评论Dee的回应。在主循环中执行的实际代码在这里：

    int main(void) {
    init();
    initVariant();

    setup();

    for (;;) {
        loop();
        if (serialEventRun) serialEventRun();
    }   
    return 0;
}

是的，setup()被调用一次，loop()并被重复调用（以及一些串行的东西）。

它作为正常功能工作，必须调用它才有意义。从main（）函数调用loop（）/ setup（），该函数是从Arduino目录编译并链接进来的。receiveData / sendData是从您的程序中调用的，该程序的根位于loop / setup函数中。