接收字符输入和返回日期格式的函数（输入错误）

我需要编写一个函数来接收字符串字符并返回日期格式。例如输入是20120101，我需要这个2012-01-01。问题是可能有一些不正确的输入，例如“ 2012ABCD”。在这种情况下，我希望函数返回固定日期，例如2020-01-01。到目前为止，我写的是：

Create Function ReturnDate
(@date varchar(8))

Returns date

  as

    begin
       declare @result date

          set @result = (select convert(date , @date,111))
                if(@@ROWCOUNT>0) return @result
                 else return '2020-01-01'
       return @result
    end

这不起作用，我只是不知道如何处理第二部分（当输入不正确时）。

在SQL Server 2012及更高版本上，您可以使用TRY_CONVERT来检查输入是否可以转换。如果不能，则返回NULL值，然后您可以执行COALESCE来获取转换后的值或固定日期。

begin
   declare @result date
   set @result = COALESCE(TRY_CONVERT(date, @date, 111), '2012-01-01')
   return @result
end

您也可以使用一个TRY CATCH块并在该CATCH块中返回固定日期，但是最好的做法是使用TRY_CONVERT，这样SQL Server不必处理错误，因为这需要更多的时间和资源。

与仅在查询中简单地使用相同的逻辑相比，用于这种类型的代码的函数会产生更多的开销，因此，如果每秒调用多次该函数，则可能会因为使用函数而浪费大量资源。我知道可以从许多代码中调用此函数，因此希望在需要更改默认日期的情况下使其成为一个函数-这样就无需更改已编译的代码，只需更新此函数即可。

如果要大量运行此代码，则应考虑其他选项，这些选项将提供比用户定义的函数更好的性能。请参阅所罗门的答案，以大致了解您的选择，并进一步解释为什么您可能会选择其中一个。

例如，下面显示了与内联表值函数实现的逻辑相同的逻辑，CROSS APPLY如果未提供静态值，则需要与之一起使用，但是其性能要比标量UDF好得多：

USE [tempdb];

GO
CREATE
OR ALTER -- comment out if using pre-SQL Server 2016 SP1
FUNCTION dbo.ReturnDate (@Date VARCHAR(8))
RETURNS TABLE
AS RETURN
  SELECT ISNULL(TRY_CONVERT(DATE, @Date, 111), '2020-01-01') AS [TheDate];
GO


SELECT *
FROM   (VALUES (1, '20120101'), (2, '2012ABCD')) tab(ID, Input)
CROSS APPLY dbo.ReturnDate(tab.[Input]) dt
/*
ID    Input       TheDate
1     20120101    2012-01-01
2     2012ABCD    2020-01-01
*/