在SQL Server中正确使用事务

236

我有2个命令，需要两个命令都正确执行或都不执行。所以我认为我需要一笔交易，但是我不知道如何正确使用它。

以下脚本有什么问题？

BEGIN TRANSACTION [Tran1]

INSERT INTO [Test].[dbo].[T1]
    ([Title], [AVG])
VALUES ('Tidd130', 130), ('Tidd230', 230)

UPDATE [Test].[dbo].[T1]
  SET [Title] = N'az2' ,[AVG] = 1
  WHERE [dbo].[T1].[Title] = N'az'

COMMIT TRANSACTION [Tran1]
GO

该INSERT指令被执行，但该UPDATE命令有一个问题。

如果它们中的任何一个执行有错误，我该如何实现以回滚这两个命令？

— 赛义德
source

513

添加一个try / catch块，如果事务成功，它将提交更改；如果事务失败，则回滚事务：

BEGIN TRANSACTION [Tran1]

  BEGIN TRY

      INSERT INTO [Test].[dbo].[T1] ([Title], [AVG])
      VALUES ('Tidd130', 130), ('Tidd230', 230)

      UPDATE [Test].[dbo].[T1]
      SET [Title] = N'az2' ,[AVG] = 1
      WHERE [dbo].[T1].[Title] = N'az'

      COMMIT TRANSACTION [Tran1]

  END TRY

  BEGIN CATCH

      ROLLBACK TRANSACTION [Tran1]

  END CATCH

— 达伦
source

1

不BEGIN TRANSACTION [Tran1]应该放在里面TRY吗？无论如何-非常简单而优雅的代码段。

— Piotr Nawrot

4

@PiotrNawrot否，如果事务创建失败，则无需在捕获中回滚它。

— Monsignor

114

在存储过程开始时，应将SET XACT_ABORT设置为ON，以指示Sql Server在发生错误的情况下自动回滚事务。如果忽略或设置为OFF，则需要在每个语句后测试@@ ERROR或使用TRY ... CATCH回滚块。

— 尼古拉·马尔科维诺维奇
source

2

换句话说，除非先设置XACT_ABORT ON，否则事务不是原子的。

— 4

url下划线很难看到，但是其中有一个下划线XACT_ABORT

— BurnsBA

32

简单方法：

CREATE TABLE T
(
    C [nvarchar](100) NOT NULL UNIQUE,
);

SET XACT_ABORT ON -- Turns on rollback if T-SQL statement raises a run-time error.
SELECT * FROM T; -- Check before.
BEGIN TRAN
    INSERT INTO T VALUES ('A');
    INSERT INTO T VALUES ('B');
    INSERT INTO T VALUES ('B');
    INSERT INTO T VALUES ('C');
COMMIT TRAN
SELECT * FROM T; -- Check after.
DELETE T;

— 博丹
source