如何避免选择的一些例子
使用Dim'd变量
Dim rng as Range
Set变量到所需范围。有很多方法可以引用单细胞范围
Set rng = Range("A1")
Set rng = Cells(1,1)
Set rng = Range("NamedRange")
或多单元格范围
Set rng = Range("A1:B10")
Set rng = Range("A1", "B10")
Set rng = Range(Cells(1,1), Cells(10,2))
Set rng = Range("AnotherNamedRange")
Set rng = Range("A1").Resize(10,2)
您可以使用该Evaluate方法的快捷方式，但这效率较低，通常应在生产代码中避免使用。
Set rng = [A1]
Set rng = [A1:B10]
以上所有示例均涉及活动工作表上的单元格。除非您特别想只使用活动工作表，否则最好也将Worksheet变量变暗
Dim ws As Worksheet
Set ws = Worksheets("Sheet1")
Set rng = ws.Cells(1,1)
With ws
Set rng = .Range(.Cells(1,1), .Cells(2,10))
End With
如果您确实想使用ActiveSheet，为了清楚起见，最好是明确的。但是请注意，因为某些Worksheet方法会更改活动工作表。
Set rng = ActiveSheet.Range("A1")
同样，这是指活动工作簿。除非您特别希望仅使用ActiveWorkbook或ThisWorkbook，否则也最好对Workbook变量进行调暗。
Dim wb As Workbook
Set wb = Application.Workbooks("Book1")
Set rng = wb.Worksheets("Sheet1").Range("A1")
如果您确实想使用ActiveWorkbook，为了清楚起见，最好是明确的。但请注意，因为许多WorkBook方法都会更改现成的书。
Set rng = ActiveWorkbook.Worksheets("Sheet1").Range("A1")
您也可以使用该ThisWorkbook对象来引用包含运行代码的书。
Set rng = ThisWorkbook.Worksheets("Sheet1").Range("A1")
常见的（不好的）代码是打开一本书，获取一些数据然后再次关闭
这是不好的：
Sub foo()
Dim v as Variant
Workbooks("Book1.xlsx").Sheets(1).Range("A1").Clear
Workbooks.Open("C:\Path\To\SomeClosedBook.xlsx")
v = ActiveWorkbook.Sheets(1).Range("A1").Value
Workbooks("SomeAlreadyOpenBook.xlsx").Activate
ActiveWorkbook.Sheets("SomeSheet").Range("A1").Value = v
Workbooks(2).Activate
ActiveWorkbook.Close()
End Sub
最好是这样的：
Sub foo()
Dim v as Variant
Dim wb1 as Workbook
Dim wb2 as Workbook
Set wb1 = Workbooks("SomeAlreadyOpenBook.xlsx")
Set wb2 = Workbooks.Open("C:\Path\To\SomeClosedBook.xlsx")
v = wb2.Sheets("SomeSheet").Range("A1").Value
wb1.Sheets("SomeOtherSheet").Range("A1").Value = v
wb2.Close()
End Sub
将范围作为范围变量传递给Subs和Functions
Sub ClearRange(r as Range)
r.ClearContents
'....
End Sub
Sub MyMacro()
Dim rng as Range
Set rng = ThisWorkbook.Worksheets("SomeSheet").Range("A1:B10")
ClearRange rng
End Sub
您还应该将方法（例如Find和Copy）应用于变量
Dim rng1 As Range
Dim rng2 As Range
Set rng1 = ThisWorkbook.Worksheets("SomeSheet").Range("A1:A10")
Set rng2 = ThisWorkbook.Worksheets("SomeSheet").Range("B1:B10")
rng1.Copy rng2
如果要遍历某个单元格的范围，通常最好（更快）先将范围值复制到一个变量数组，然后遍历该单元格
Dim dat As Variant
Dim rng As Range
Dim i As Long
Set rng = ThisWorkbook.Worksheets("SomeSheet").Range("A1:A10000")
dat = rng.Value ' dat is now array (1 to 10000, 1 to 1)
for i = LBound(dat, 1) to UBound(dat, 1)
dat(i,1) = dat(i,1) * 10 'or whatever operation you need to perform
next
rng.Value = dat ' put new values back on sheet
这是一个可能的小尝试者。
Select和/或ActiveSheet等等是完全不可避免的。这里有一个例子，我发现：stackoverflow.com/questions/22796286/...