如何在CMake中激活C ++ 11？

当我尝试运行CMake生成的makefile来编译程序时，出现以下错误：

C ++ 98模式不支持基于范围的循环。

我尝试添加add_definitions(-std=c++0x)到CMakeLists.txt，但没有帮助。

我也尝试过这个：

if(CMAKE_COMPILER_IS_GNUCXX)
    add_definitions(-std=gnu++0x)
endif()

当我这样做时g++ --version，我得到：

g ++（Ubuntu / Linaro 4.6.1-9ubuntu3）4.6.1

我也尝试过SET(CMAKE_CXX_FLAGS "-std=c++0x")，这也行不通。

我不明白如何使用CMake激活C ++ 11功能。

CMake 3.1引入了您可以使用的CMAKE_CXX_STANDARD变量。如果您知道将始终有CMake 3.1可用，则可以将其写在顶级CMakeLists.txt文件中，或者将其放在定义任何新目标之前：

set (CMAKE_CXX_STANDARD 11)

如果您需要支持较旧版本的CMake，可以使用以下宏：

macro(use_cxx11)
  if (CMAKE_VERSION VERSION_LESS "3.1")
    if (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
      set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=gnu++11")
    endif ()
  else ()
    set (CMAKE_CXX_STANDARD 11)
  endif ()
endmacro(use_cxx11)

该宏目前仅支持GCC，但将其扩展到其他编译器应该很简单。

然后，您可以use_cxx11()在任何定义使用C ++ 11的目标的CMakeLists.txt文件的顶部编写代码。

针对面向macOS的Clang用户的CMake问题＃15943

如果您使用CMake和clang定位macOS，则存在一个错误，该错误可能导致该CMAKE_CXX_STANDARD功能无法正常使用（不添加任何编译器标志）。确保执行以下操作之一：

• 使用cmake_minimum_required要求CMake 3.0或更高版本，或者

• 在project命令之前，在CMakeLists.txt文件顶部使用以下代码将策略CMP0025设置为NEW ：

  # Fix behavior of CMAKE_CXX_STANDARD when targeting macOS.
  if (POLICY CMP0025)
    cmake_policy(SET CMP0025 NEW)
  endif ()

CMake命令target_compile_features()用于指定所需的C ++功能cxx_range_for。然后，CMake将促使使用C ++标准。

cmake_minimum_required(VERSION 3.1.0 FATAL_ERROR)
project(foobar CXX)
add_executable(foobar main.cc)
target_compile_features(foobar PRIVATE cxx_range_for)

无需使用add_definitions(-std=c++11)或修改CMake变量CMAKE_CXX_FLAGS，因为CMake将确保使用适当的命令行标志调用C ++编译器。

也许您的C ++程序使用以外的其他C ++功能cxx_range_for。CMake全局属性CMAKE_CXX_KNOWN_FEATURES列出了可以选择的C ++功能。

除了使用之外，target_compile_features()还可以通过设置CMake属性CXX_STANDARD 和 CXX_STANDARD_REQUIREDCMake目标来显式指定C ++标准 。

另请参阅我的更详细的答案。

我在用

include(CheckCXXCompilerFlag)
CHECK_CXX_COMPILER_FLAG("-std=c++11" COMPILER_SUPPORTS_CXX11)
CHECK_CXX_COMPILER_FLAG("-std=c++0x" COMPILER_SUPPORTS_CXX0X)
if(COMPILER_SUPPORTS_CXX11)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")
elseif(COMPILER_SUPPORTS_CXX0X)
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++0x")
else()
        message(STATUS "The compiler ${CMAKE_CXX_COMPILER} has no C++11 support. Please use a different C++ compiler.")
endif()

但是，如果你要玩C++11，g++ 4.6.1是很老。尝试获取更新的g++版本。

设置Cxx标准的最简单方法是：

 set_property(TARGET tgt PROPERTY CXX_STANDARD 11)

有关更多详细信息，请参见CMake文档。

事实证明，SET(CMAKE_CXX_FLAGS "-std=c++0x")确实激活了许多C ++ 11功能。它不起作用的原因是该语句看起来像这样：

set(CMAKE_CXX_FLAGS "-std=c++0x ${CMAKE_CXX_FLAGS} -g -ftest-coverage -fprofile-arcs")

按照这种方法，该-std=c++0x标志以某种方式被覆盖并且不起作用。逐一设置标记或使用列表方法可以正常工作。

list( APPEND CMAKE_CXX_FLAGS "-std=c++0x ${CMAKE_CXX_FLAGS} -g -ftest-coverage -fprofile-arcs")

最简单的方法：

add_compile_options(-std=c++11)

对于CMake 3.8及更高版本，您可以使用

target_compile_features(target PUBLIC cxx_std_11)

这是启用C ++ 11支持的另一种方法，

ADD_DEFINITIONS(
    -std=c++11 # Or -std=c++0x
    # Other flags
)

我遇到了仅此方法有效而其他方法失败的实例。也许与最新版本的CMake有关。

在现代CMake（> = 3.1）上，设置全局需求的最佳方法是：

set(CMAKE_CXX_STANDARD 11)
set(CMAKE_CXX_STANDARD_REQUIRED ON)
set(CMAKE_CXX_EXTENSIONS OFF)

它翻译为“我希望所有目标都使用C ++ 11，这不是可选的，我不想使用任何GNU或Microsoft扩展。” 从C ++ 17开始，这仍然是恕我直言的最佳方法。

来源：在CMake中启用C ++ 11及更高版本

对我有用的是在CMakeLists.txt中设置以下行：

set (CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")

设置此命令将激活编译器的C ++ 11功能，执行该cmake ..命令后，您应该能够range based for loops在代码中使用并对其进行编译而不会出现任何错误。

我认为仅这两行就足够了。

set(CMAKE_CXX_STANDARD 11)

set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -std=c++11")

如果您想始终激活最新的C ++标准，这是我对David Grayson的回答的扩展，因为最近（CMake 3.8和CMake 3.11）对CMAKE_CXX_STANDARD分别添加了17和20值：

IF (CMAKE_VERSION VERSION_LESS "3.8")
    SET(CMAKE_CXX_STANDARD 14)
ELSEIF (CMAKE_VERSION VERSION_LESS "3.11")
    SET(CMAKE_CXX_STANDARD 17)
ELSE()
    SET(CMAKE_CXX_STANDARD 20)
ENDIF()

# Typically, you'll also want to turn off compiler-specific extensions:
SET(CMAKE_CXX_EXTENSIONS OFF)

（set (CMAKE_CXX_STANDARD 11)在链接的答案中使用该代码。）

现代cmake提供了更简单的方法来配置编译器以使用特定版本的C ++。任何人唯一要做的就是设置相关的目标属性。在cmake支持的属性中，用于确定如何配置编译器以支持特定版本的C ++ 的属性如下：

• CXX_STANDARD设置需要其功能来构建目标的C ++标准。将此设置为11目标C ++ 11。

• CXX_EXTENSIONS，一个布尔值，指定是否请求编译器特定的扩展。将此设置为Off会禁用对特定于编译器的扩展的支持。

为了演示，这是一个最小的工作示例CMakeLists.txt。

cmake_minimum_required(VERSION 3.1)

project(testproject LANGUAGES CXX )

set(testproject_SOURCES
    main.c++
    )

add_executable(testproject ${testproject_SOURCES})

set_target_properties(testproject
    PROPERTIES
    CXX_STANDARD 11
    CXX_EXTENSIONS off
    )

OS X和Homebrew LLVM相关：

不要忘记在其后调用cmake_minimum_required（VERSION 3.3）和project（）！

否则CMake将project()在第1行之前隐式插入，从而导致Clang版本检测出现问题，并可能引起其他类型的麻烦。这是一个相关的问题。