如何在CMake文件中添加链接器或编译标志？

我正在使用arm-linux-androideabi-g++编译器。当我尝试编译一个简单的“ Hello，World！”时 程序可以编译良好。当我通过在该代码中添加简单的异常处理来对其进行测试时，它也可以工作（添加-fexceptions.. 后，我认为默认情况下它是禁用的）。

这是针对Android设备的，我只想使用CMake，而不是ndk-build。

例如 - first.cpp

#include <iostream>

using namespace std;

int main()
{
   try
   {
   }
   catch (...)
   {
   }
   return 0;
}

./arm-linux-androideadi-g++ -o first-test first.cpp -fexceptions

没问题...

问题 ...我试图用CMake文件编译文件。

我想将其添加-fexceptions为标志。我尝试过

set (CMAKE_EXE_LINKER_FLAGS -fexceptions ) or set (CMAKE_EXE_LINKER_FLAGS "fexceptions" )

和

set ( CMAKE_C_FLAGS "fexceptions")

它仍然显示错误。

假设您要添加这些标志（最好在常量中声明它们）：

SET(GCC_COVERAGE_COMPILE_FLAGS "-fprofile-arcs -ftest-coverage")
SET(GCC_COVERAGE_LINK_FLAGS    "-lgcov")

有几种添加方式：

1. 最简单的方法（不是干净的方法，但简单又方便，并且仅适用于一次编译标志，C和C ++）：

   add_definitions(${GCC_COVERAGE_COMPILE_FLAGS})

2. 附加到相应的CMake变量：

   SET(CMAKE_CXX_FLAGS  "${CMAKE_CXX_FLAGS} ${GCC_COVERAGE_COMPILE_FLAGS}")
   SET(CMAKE_EXE_LINKER_FLAGS  "${CMAKE_EXE_LINKER_FLAGS} ${GCC_COVERAGE_LINK_FLAGS}")

3. 使用目标属性，请参见。doc CMake编译标志目标属性，并且需要知道目标名称。

   get_target_property(TEMP ${THE_TARGET} COMPILE_FLAGS)
   if(TEMP STREQUAL "TEMP-NOTFOUND")
     SET(TEMP "") # Set to empty string
   else()
     SET(TEMP "${TEMP} ") # A space to cleanly separate from existing content
   endif()
   # Append our values
   SET(TEMP "${TEMP}${GCC_COVERAGE_COMPILE_FLAGS}" )
   set_target_properties(${THE_TARGET} PROPERTIES COMPILE_FLAGS ${TEMP} )

现在我使用方法2。

在较新版本的CMake中，您可以分别使用target_compile_options和设置单个目标的编译器和链接器标志target_link_libraries（是的，后者也设置链接器选项）：

target_compile_options(first-test PRIVATE -fexceptions)

这种方法的优点是，您可以通过PUBLIC和控制选项向其他目标的传播PRIVATE。

从CMake 3.13开始，您还可以使用target_link_options添加链接器选项，以使意图更清晰。

尝试设置变量CMAKE_CXX_FLAGS而不是CMAKE_C_FLAGS：

set (CMAKE_CXX_FLAGS "-fexceptions")

该变量CMAKE_C_FLAGS仅影响C编译器，但是您正在编译C ++代码。

将标志添加到CMAKE_EXE_LINKER_FLAGS是多余的。

您还可以使用LINK_FLAGS属性将链接器标志添加到特定目标：

set_property(TARGET ${target} APPEND_STRING PROPERTY LINK_FLAGS " ${flag}")

如果要将此更改传播到其他目标，则可以创建要链接到的虚拟目标。

检出ucm的ucm_add_flags和ucm_add_linker_flags宏（我的一组有用的CMake宏）-它们处理附加的编译器/链接器标志。