使用CMake使用/ MT而不是/ MD进行编译

我在带有Windows SDK和NMake Makefile的Windows上使用CMake。

默认情况下，它使用/MD编译器开关进行编译。

我如何更改它以使用/MT开关进行编译？

您可以修改CMAKE_CXX_FLAGS_<Build Type>和/或CMAKE_C_FLAGS_<Build Type>变量：

set(CMAKE_CXX_FLAGS_RELEASE "${CMAKE_CXX_FLAGS_RELEASE} /MT")
set(CMAKE_CXX_FLAGS_DEBUG "${CMAKE_CXX_FLAGS_DEBUG} /MTd")

如果您的CMake标志已经包含/MD，则可以确保在插入点之后执行上述命令/MD（以后的添加将/MT覆盖冲突的现有选项），或者可以从头开始设置标志：

set(CMAKE_CXX_FLAGS_RELEASE "/MT")
set(CMAKE_CXX_FLAGS_DEBUG "/MTd")

或者，您可以通过执行以下操作分别用和替换现有的/MD和/MDd值：/MT/MTd

set(CompilerFlags
        CMAKE_CXX_FLAGS
        CMAKE_CXX_FLAGS_DEBUG
        CMAKE_CXX_FLAGS_RELEASE
        CMAKE_C_FLAGS
        CMAKE_C_FLAGS_DEBUG
        CMAKE_C_FLAGS_RELEASE
        )
foreach(CompilerFlag ${CompilerFlags})
  string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
endforeach()

CMake最终在3.15版中使用MSVC_RUNTIME_LIBRARYtarget属性添加了对此的适当支持：

cmake_minimum_required(VERSION 3.15)
cmake_policy(SET CMP0091 NEW)
project(my_project)

add_executable(foo foo.c)
set_property(TARGET foo PROPERTY
             MSVC_RUNTIME_LIBRARY "MultiThreaded$<$<CONFIG:Debug>:Debug>")

您也可以通过设置CMAKE_MSVC_RUNTIME_LIBRARY变量来指定全局默认值。

看来，对于Visual Studio的2017年15和CMake的3.12的方式来代替/MD由/MT是加入该片段到的CMakeLists.txt文件：

if(MSVC)
    add_compile_options(
        $<$<CONFIG:>:/MT> #---------|
        $<$<CONFIG:Debug>:/MTd> #---|-- Statically link the runtime libraries
        $<$<CONFIG:Release>:/MT> #--|
    )
endif()

我在官方CMake存储库中找到了此解决方案：https : //gitlab.kitware.com/cmake/cmake/issues/18390

我必须使用它set( ... CACHE ... FORCE)来覆盖MSVC的默认缓存。

如果我不使用此方法，则MSVC仍会输出/MD选项。

set(CompilerFlags
        CMAKE_CXX_FLAGS
        CMAKE_CXX_FLAGS_DEBUG
        CMAKE_CXX_FLAGS_RELEASE
        CMAKE_CXX_FLAGS_MINSIZEREL
        CMAKE_CXX_FLAGS_RELWITHDEBINFO
        CMAKE_C_FLAGS
        CMAKE_C_FLAGS_DEBUG
        CMAKE_C_FLAGS_RELEASE
        CMAKE_C_FLAGS_MINSIZEREL
        CMAKE_C_FLAGS_RELWITHDEBINFO
        )
foreach(CompilerFlag ${CompilerFlags})
    string(REPLACE "/MD" "/MT" ${CompilerFlag} "${${CompilerFlag}}")
    set(${CompilerFlag} "${${CompilerFlag}}" CACHE STRING "msvc compiler flags" FORCE)
    message("MSVC flags: ${CompilerFlag}:${${CompilerFlag}}")
endforeach()

查看ucm_set_runtime-此宏将替换静态或动态运行时的标志-要查看效果，请使用ucm_print_flags（也请查看此Stack Overflow问题）。