gnuplot中的循环结构？

有什么方法可以迭代地从多个文件中检索数据并将它们绘制在gnuplot的同一图形上。假设我有data1.txt，data2.txt ...... data1000.txt之类的文件；每个具有相同的列数。现在我可以写一些类似的东西了

plot "data1.txt" using 1:2 title "Flow 1", \
     "data2.txt" using 1:2 title "Flow 2", \
      .
      .
      .
     "data1000.txt"  using 1:2 title "Flow 6"

但这确实很不方便。我想知道是否有一种方法可以循环遍历gnuplot中的绘图部分。

肯定有（在gnuplot 4.4+中）：

plot for [i=1:1000] 'data'.i.'.txt' using 1:2 title 'Flow '.i

变量i可以解释为变量或字符串，因此您可以执行以下操作

plot for [i=1:1000] 'data'.i.'.txt' using 1:($2+i) title 'Flow '.i

如果要使线彼此偏移。

help iteration在gnuplot命令行中键入以获取更多信息。

另外，请务必查看@DarioP有关do for语法的答案。这使您更接近传统for循环。

do { ... }从gnuplot 4.6开始，还请看一下该命令，因为它非常强大：

do for [t=0:50] {
  outfile = sprintf('animation/bessel%03.0f.png',t)
  set output outfile
  splot u*sin(v),u*cos(v),bessel(u,t/50.0) w pm3d ls 1
}

http://www.gnuplotting.org/gnuplot-4-6-do/

我有脚本all.p

set ...
...
list=system('ls -1B *.dat')
plot for [file in list] file w l u 1:2 t file

这里的最后两行是文字，而不是启发式。然后我跑

$ gnuplot -p all.p

更改*.dat为您拥有的文件类型，或添加文件类型。

下一步：将〜/ .bashrc添加到此行

alias p='gnuplot -p ~/./all.p'

并将文件放入all.p主目录和目录。您可以通过键入p并输入来绘制任何目录中的所有文件。

编辑我更改了命令，因为它不起作用。以前它包含list(i)=word(system(ls -1B *.dat),i)。

如果您要在图形中绘制离散列，请使用以下内容

do for [indx in "2 3 7 8"] {
  column = indx + 0
  plot ifile using 1:column ;  
}

我想使用通配符来绘制通常放置在不同目录中的多个文件，同时在任何目录下工作。我发现的解决方案是在中创建以下功能~/.bashrc

plo () {
local arg="w l"
local str="set term wxt size 900,500 title 'wild plotting'
set format y '%g'
set logs
plot"
while [ $# -gt 0 ]
        do str="$str '$1' $arg,"
        shift
done
echo "$str" | gnuplot -persist
}

并使用例如这样的方法plo *.dat ../../dir2/*.out来绘制.dat当前目录中的所有.out文件以及恰好是升级并被调用的目录中的所有文件dir2。

这是替代命令：

gnuplot -p -e 'plot for [file in system("find . -name \\*.txt -depth 1")] file using 1:2 title file with lines'