从相对路径和/或文件名解析绝对路径

Windows批处理脚本中是否可以从包含文件名和/或相对路径的值返回绝对路径？

鉴于：

"..\"
"..\somefile.txt"

我需要相对于批处理文件的绝对路径。

例：

• “ somefile.txt”位于“ C：\ Foo \”中
• “ test.bat”位于“ C：\ Foo \ Bar”中。
• 用户在“ C：\ Foo”中打开命令窗口并调用 Bar\test.bat ..\somefile.txt
• 在批处理文件中，“ C：\ Foo \ somefile.txt”将来自 %1

在批处理文件中，如在标准C程序中一样，参数0包含当前执行脚本的路径。您可以%~dp0用来仅获取第0个参数的路径部分（这是当前脚本）-该路径始终是完全限定的路径。

您还可以使用来获取第一个参数的完全限定路径%~f1，但这会根据当前的工作目录提供一个路径，这显然不是您想要的。

就个人而言，我经常%~dp0%~1在批处理文件中使用惯用语，该惯用语解释相对于正在执行的批处理路径的第一个参数。但是它确实有一个缺点：如果第一个参数完全合格，它就会失败。

如果需要同时支持相对路径和绝对路径，则可以使用FrédéricMénez的解决方案：临时更改当前工作目录。

这是一个示例，将演示每种技术：

@echo off
echo %%~dp0 is "%~dp0"
echo %%0 is "%0"
echo %%~dpnx0 is "%~dpnx0"
echo %%~f1 is "%~f1"
echo %%~dp0%%~1 is "%~dp0%~1"

rem Temporarily change the current working directory, to retrieve a full path 
rem   to the first parameter
pushd .
cd %~dp0
echo batch-relative %%~f1 is "%~f1"
popd

如果将其另存为c：\ temp \ example.bat并从c：\ Users \ Public运行

c：\ Users \ Public> \ temp \ example.bat .. \ windows

...您将观察到以下输出：

%~dp0 is "C:\temp\"
%0 is "\temp\example.bat"
%~dpnx0 is "C:\temp\example.bat"
%~f1 is "C:\Users\windows"
%~dp0%~1 is "C:\temp\..\windows"
batch-relative %~f1 is "C:\Windows"

可以在以下位置找到批处理参数上允许使用的修饰符集的文档：https : //docs.microsoft.com/zh-cn/windows-server/administration/windows-commands/call

今天早上，我遇到了类似的需求：如何在Windows命令脚本中将相对路径转换为绝对路径。

以下是技巧：

@echo off

set REL_PATH=..\..\
set ABS_PATH=

rem // Save current directory and change to target directory
pushd %REL_PATH%

rem // Save value of CD variable (current directory)
set ABS_PATH=%CD%

rem // Restore original directory
popd

echo Relative path: %REL_PATH%
echo Maps to path: %ABS_PATH%

这些答案中的大多数似乎对复杂且超级的越野车感到疯狂，这是我的-它适用于任何环境变量（no %CD%或PUSHD/ POPD或for /f废话）-只是普通的旧批处理函数。-目录和文件甚至不必存在。

CALL :NORMALIZEPATH "..\..\..\foo\bar.txt"
SET BLAH=%RETVAL%

ECHO "%BLAH%"

:: ========== FUNCTIONS ==========
EXIT /B

:NORMALIZEPATH
  SET RETVAL=%~dpfn1
  EXIT /B

无需让另一个批处理文件将参数传递给（和使用参数运算符），您可以使用FOR /F：

FOR /F %%i IN ("..\relativePath") DO echo absolute path: %%~fi

其中iin %%~fi是在定义的变量/F %%i。例如。如果将其更改为，/F %%a则最后一部分将是%%~fa。

要在命令提示符处（而不是在批处理文件中）执行相同的操作，请替换%%为%...

这是为了帮助填补Adrien Plisson的答案中的空白（编辑后应立即予以删除；-)：

您也可以使用％〜f1获得第一个参数的完全限定路径，但这会根据当前路径给出一条路径，这显然不是您想要的。

不幸的是，我不知道如何将2混合在一起...

一个可以处理%0和%1同样：

• %~dpnx0对于批处理文件本身的标准驱动器+路径+名称+扩展名，
  %~f0也足够了；
• %~dpnx1对于第一个参数的标准驱动器+路径+名称+扩展名（如果完全是文件名），
  %~f1也就足够了；

%~f1将与您指定第一个参数的方式无关：使用相对路径或绝对路径（如果您在命名时未指定文件的扩展名%1，即使使用%~dpnx1- 也不会添加文件扩展名）。

但是，如果您一开始就不会在命令行中提供完整的路径信息，那么无论如何，您将如何命名另一个驱动器上的文件？

然而%~p0，%~n0，%~nx0并且%~x0可以派上用场了，你应该关心路径（无驱动器号），文件名（不含扩展名），文件全名以扩展或只有文件扩展名。但是请注意，虽然%~p1and %~n1可以找到第一个参数的路径或名称，%~nx1并且%~x1不会添加+显示扩展名，除非您已经在命令行中使用了它。

您也可以为此使用批处理功能：

@echo off
setlocal 

goto MAIN
::-----------------------------------------------
:: "%~f2" get abs path of %~2. 
::"%~fs2" get abs path with short names of %~2.
:setAbsPath
  setlocal
  set __absPath=%~f2
  endlocal && set %1=%__absPath%
  goto :eof
::-----------------------------------------------

:MAIN
call :setAbsPath ABS_PATH ..\
echo %ABS_PATH%

endlocal

对BrainSlugs83的出色解决方案进行小的改进。通用化以允许在调用中命名输出环境变量。

@echo off
setlocal EnableDelayedExpansion

rem Example input value.
set RelativePath=doc\build

rem Resolve path.
call :ResolvePath AbsolutePath %RelativePath%

rem Output result.
echo %AbsolutePath%

rem End.
exit /b

rem === Functions ===

rem Resolve path to absolute.
rem Param 1: Name of output variable.
rem Param 2: Path to resolve.
rem Return: Resolved absolute path.
:ResolvePath
    set %1=%~dpfn2
    exit /b

如果从C:\project输出运行为：

C:\project\doc\build

我没有看到很多解决此问题的方法。一些解决方案使用CD进行目录遍历，而其他解决方案则使用批处理功能。我个人偏爱批处理功能，尤其是DosTips提供的MakeAbsolute功能。

该函数具有一些实际好处，首先是它不会更改您当前的工作目录，其次，甚至不必存在要评估的路径。您也可以在此处找到一些有关如何使用该功能的有用提示。

这是一个示例脚本及其输出：

@echo off

set scriptpath=%~dp0
set siblingfile=sibling.bat
set siblingfolder=sibling\
set fnwsfolder=folder name with spaces\
set descendantfolder=sibling\descendant\
set ancestorfolder=..\..\
set cousinfolder=..\uncle\cousin

call:MakeAbsolute siblingfile      "%scriptpath%"
call:MakeAbsolute siblingfolder    "%scriptpath%"
call:MakeAbsolute fnwsfolder       "%scriptpath%"
call:MakeAbsolute descendantfolder "%scriptpath%"
call:MakeAbsolute ancestorfolder   "%scriptpath%"
call:MakeAbsolute cousinfolder     "%scriptpath%"

echo scriptpath:       %scriptpath%
echo siblingfile:      %siblingfile%
echo siblingfolder:    %siblingfolder%
echo fnwsfolder:       %fnwsfolder%
echo descendantfolder: %descendantfolder%
echo ancestorfolder:   %ancestorfolder%
echo cousinfolder:     %cousinfolder%
GOTO:EOF

::----------------------------------------------------------------------------------
:: Function declarations
:: Handy to read http://www.dostips.com/DtTutoFunctions.php for how dos functions
:: work.
::----------------------------------------------------------------------------------
:MakeAbsolute file base -- makes a file name absolute considering a base path
::                      -- file [in,out] - variable with file name to be converted, or file name itself for result in stdout
::                      -- base [in,opt] - base path, leave blank for current directory
:$created 20060101 :$changed 20080219 :$categories Path
:$source http://www.dostips.com
SETLOCAL ENABLEDELAYEDEXPANSION
set "src=%~1"
if defined %1 set "src=!%~1!"
set "bas=%~2"
if not defined bas set "bas=%cd%"
for /f "tokens=*" %%a in ("%bas%.\%src%") do set "src=%%~fa"
( ENDLOCAL & REM RETURN VALUES
    IF defined %1 (SET %~1=%src%) ELSE ECHO.%src%
)
EXIT /b

并输出：

C:\Users\dayneo\Documents>myscript
scriptpath:       C:\Users\dayneo\Documents\
siblingfile:      C:\Users\dayneo\Documents\sibling.bat
siblingfolder:    C:\Users\dayneo\Documents\sibling\
fnwsfolder:       C:\Users\dayneo\Documents\folder name with spaces\
descendantfolder: C:\Users\dayneo\Documents\sibling\descendant\
ancestorfolder:   C:\Users\
cousinfolder:     C:\Users\dayneo\uncle\cousin

希望对您有所帮助...它肯定对我有所帮助:) PS再次感谢DosTips！你摇滚！

您可以将它们串联起来。

SET ABS_PATH=%~dp0 
SET REL_PATH=..\SomeFile.txt
SET COMBINED_PATH=%ABS_PATH%%REL_PATH%

路径中间的\ .. \看起来很奇怪，但是可以正常工作。无需做任何疯狂的事情:)

在您的示例中，从Bar \ test.bat，DIR / B / S .. \ somefile.txt将返回完整路径。

这些天，PowerShell很常见，因此我经常将它用作调用C＃的快速方法，因为它具有几乎所有功能：

@echo off
set pathToResolve=%~dp0\..\SomeFile.txt
for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo Resolved path: %resolvedPath%

它有点慢，但是除非不求助于实际的脚本语言，否则获得的功能很难被击败。

stijn的解决方案适用于下的子文件夹C:\Program Files (86)\，

@echo off
set projectDirMc=test.txt

for /f "delims=" %%a in ('powershell -Command "[System.IO.Path]::GetFullPath( '%projectDirMc%' )"') do @set resolvedPath=%%a

echo full path:    %resolvedPath%

文件查看所有其他答案

目录

随着..被你的相对路径，并假设您目前在D:\Projects\EditorProject：

cd .. & cd & cd EditorProject （相对路径）

返回绝对路径，例如

D:\Projects

SET CD=%~DP0

SET REL_PATH=%CD%..\..\build\

call :ABSOLUTE_PATH    ABS_PATH   %REL_PATH%

ECHO %REL_PATH%

ECHO %ABS_PATH%

pause

exit /b

:ABSOLUTE_PATH

SET %1=%~f2

exit /b