如何在Android Gradle中自动增加versionCode

78

我正在尝试基于Gradle的新的Android构建系统，并且在考虑，用它自动增加versionCode的最佳方法是什么。我在考虑两种选择

  1. 创建versionCode文件，从中读取编号，增加编号并将其写回到文件中
  2. 解析AndroidManifest.xml，从中读取versionCode，增加它并将其写回到AndroidManifest.xml

还有其他更简单或更合适的解决方案吗？

有没有人使用过其中一种方案，可以与我分享？

android  build  android-manifest  gradle  auto-increment 
— 海豹
source
从version.properties文件中读取stackoverflow.com/a/21405744
— Dori

Answers:

57

我决定第二种选择-解析AndroidManifest.xml。这是工作片段。

task('increaseVersionCode') << {
    def manifestFile = file("AndroidManifest.xml")
    def pattern = Pattern.compile("versionCode=\"(\\d+)\"")
    def manifestText = manifestFile.getText()
    def matcher = pattern.matcher(manifestText)
    matcher.find()
    def versionCode = Integer.parseInt(matcher.group(1))
    def manifestContent = matcher.replaceAll("versionCode=\"" + ++versionCode + "\"")
    manifestFile.write(manifestContent)
}

tasks.whenTaskAdded { task ->
    if (task.name == 'generateReleaseBuildConfig') {
        task.dependsOn 'increaseVersionCode'
    }
}

versionCode在这种情况下，发布用于发布版本。要增加其调试版本，请在task.whenTaskAdded回调中更改task.name方程。

— 海豹
source
5
一个问题，如何将这些代码集成到Cradle构建系统中？
— LiangWang 2014年
：另外，这里有些清洁剂的答案不会修改到位XML，但保持在道具文件的版本号stackoverflow.com/questions/21405457/...
— 保罗·坎特雷尔
1
如果您使用的是新项目结构，只需将file（“ AndroidManifest.xml”）更改为file（“ src / main / AndroidManifest.xml”）。
— Elhanan Mishraky 2015年
3
如果我未在AndroidManifest.xml中设置versionCode怎么办？
— IgorGanapolsky
@Jacky如果你们仍然没有得到解决方法，请参阅我的回答：stackoverflow.com/a/39619297/1150251
— 伊斯塔
39

我正在使用此代码通过“ major.minor.patch.build”方案来更新versionCode和versionName。

import java.util.regex.Pattern

task('increaseVersionCode') << {
    def manifestFile = file("src/main/AndroidManifest.xml")
    def pattern = Pattern.compile("versionCode=\"(\\d+)\"")
    def manifestText = manifestFile.getText()
    def matcher = pattern.matcher(manifestText)
    matcher.find()
    def versionCode = Integer.parseInt(matcher.group(1))
    def manifestContent = matcher.replaceAll("versionCode=\"" + ++versionCode + "\"")
    manifestFile.write(manifestContent)
}

task('incrementVersionName') << {
    def manifestFile = file("src/main/AndroidManifest.xml")
    def patternVersionNumber = Pattern.compile("versionName=\"(\\d+)\\.(\\d+)\\.(\\d+)\\.(\\d+)\"")
    def manifestText = manifestFile.getText()
    def matcherVersionNumber = patternVersionNumber.matcher(manifestText)
    matcherVersionNumber.find()
    def majorVersion = Integer.parseInt(matcherVersionNumber.group(1))
    def minorVersion = Integer.parseInt(matcherVersionNumber.group(2))
    def pointVersion = Integer.parseInt(matcherVersionNumber.group(3))
    def buildVersion = Integer.parseInt(matcherVersionNumber.group(4))
    def mNextVersionName = majorVersion + "." + minorVersion + "." + pointVersion + "." + (buildVersion + 1)
    def manifestContent = matcherVersionNumber.replaceAll("versionName=\"" + mNextVersionName + "\"")
    manifestFile.write(manifestContent)
}

tasks.whenTaskAdded { task ->
    if (task.name == 'generateReleaseBuildConfig' || task.name == 'generateDebugBuildConfig') {
        task.dependsOn 'increaseVersionCode'
        task.dependsOn 'incrementVersionName'
    }
}
— 安德烈斯
source
1
您忘记了在顶部导入Pattern：import java.util.regex.Pattern
— Mic92 2014年
1
我知道这个有点旧了，但是嘿，问这个问题并没有什么坏处，但是我尝试使用上面的代码片段，我对这个错误有Error:(48) Execution failed for task ':app:incrementVersionName'. > No match found任何想法吗？
— acrichm
1
@acrichm：确保您设置android:versionName="0.0.0.1"在清单中，否则不会有预期的比赛次数
— Jay Wick
它工作正常，但在BuildConfig.java中versionName为空，公共静态最终字符串VERSION_NAME =“”;
— Al-Mothafar'9
请注意，Android Studio中的“即时运行”会变慢，因为Full recompilation is required because 'BuildConfig.java' was changed.
— Ivan Chau
36

它似乎不是您正在使用的确切设置，但是在我来说，构建是由jenkins运行的，我想使用其$ BUILD_NUMBER作为应用程序的versionCode。下面为我​​做了窍门。

defaultConfig {
    ...
    versionCode System.getenv("BUILD_NUMBER") as Integer ?: 9999
    ...
}
— 用户名
source
什么是System.genenv？
— IgorGanapolsky
使用詹金斯时，这实际上对我有很大帮助。您可以使用此插件创建带有内部版本号的环境变量，并System.getenv()在gradle中使用它进行读取。
— Lamorak 2015年
18

我正在使用时间戳作为版本代码： 

def date = new Date()
def formattedDate = date.format('yyMMddHHmm')
def code = formattedDate.toInteger()

defaultConfig {
    minSdkVersion 10
    targetSdkVersion 21
    versionCode code
}
— thanhbinh84
source
1
这是简单而天才。竖起大拇指
— ЄвгенГарастович
7

如果您将版本代码保存在build.gradle文件中，请使用下一个代码段：

import java.util.regex.Pattern    
task('increaseVersionCode') << {
    def buildFile = file("build.gradle")
    def pattern = Pattern.compile("versionCode\\s+(\\d+)")
    def manifestText = buildFile.getText()
    def matcher = pattern.matcher(manifestText)
    matcher.find()
    def versionCode = Integer.parseInt(matcher.group(1))
    def manifestContent = matcher.replaceAll("versionCode " + ++versionCode)
    buildFile.write(manifestContent)
}
— 埃尔哈南·米什拉基（Elhanan Mishraky）
source
该模式与versionCode不匹配。
— 拉各斯2015年
您可以发布build.gradle吗？
— Elhanan Mishraky
我的build.gradle是一个普通的构建文件。VersionCode行看起来像versionCode 18 。即使我在测试仪（"versionCode \d+"）上运行了您的正则表达式，它也不匹配。
— 拉各斯2015年
错误是还有一个空白。Android Studio在versionCode和数字上使用两个空格，因为它将与中的文本对齐versionName。
— 拉各斯2015年
4

要同时考虑产品风格和构建类型，并使用@sealskej的逻辑来解析清单：

android.applicationVariants.all { variant ->
    /* Generate task to increment version code for release */
    if (variant.name.contains("Release")) {
        def incrementVersionCodeTaskName = "increment${variant.name}VersionCode"
        task(incrementVersionCodeTaskName) << {
            if (android.defaultConfig.versionCode == -1) {
                def manifestFile = file(android.sourceSets.main.manifest.srcFile)
                def pattern = Pattern.compile("versionCode=\"(\\d+)\"")
                def manifestText = manifestFile.getText()
                def matcher = pattern.matcher(manifestText)
                matcher.find()
                def versionCode = Integer.parseInt(matcher.group(1))
                android.defaultConfig.versionCode = versionCode + 1
                def manifestContent = matcher.replaceAll("versionCode=\"" + android.defaultConfig.versionCode + "\"")
                manifestFile.write(manifestContent)
            }
        }
        def hookTask = variant.generateBuildConfig
        hookTask.dependsOn(incrementVersionCodeTaskName)
    }
}
— 麦克斯
source
1
我们需要在哪里编写此代码……我的意思是需要在哪个类/文件中添加此代码
— ChArAnJiT 2014年
这是build.gradle的一部分，因为这是构建过程的一部分
— Max Ch
3

递增VersionCode任务（整数）：

这可以通过将版本代码增加来实现1，例如：

  android:versionCode="1"

1 + 1 = 2

import java.util.regex.Pattern

task incrementVersionCode << {
    def manifestFile = file('AndroidManifest.xml')
    def matcher = Pattern.compile('versionCode=\"(\\d+)\"')
    .matcher(manifestFile.getText())
    matcher.find()
    def manifestContent = matcher.replaceAll('versionCode=\"' +
        ++Integer.parseInt(matcher.group(1)) + '\"')
    manifestFile.write(manifestContent)
}

递增VersionName任务（字符串）：

警告：必须包含正则1表达式的句点

可以通过以下方式来增加版本名称0.01：

android:versionName="1.0"

1.00 + 0.01 -> 1.01
1.01 + 0.01 -> 1.02
1.10 + 0.01 -> 1.11
1.99 + 0.01 -> 2.0
1.90 + 0.01 -> 1.91

import java.util.regex.Pattern

task incrementVersionName << {
    def manifestFile = file('AndroidManifest.xml')
    def matcher = Pattern.compile('versionName=\"(\\d+)\\.(\\d+)\"')
    .matcher(manifestFile.getText())
    matcher.find()
    def versionName = String.format("%.2f", Integer
        .parseInt(matcher.group(1)) + Double.parseDouble("." + matcher
            .group(2)) + 0.01)
    def manifestContent = matcher.replaceAll('versionName=\"' +
        versionName + '\"')
    manifestFile.write(manifestContent)
}

之前：

<?xml version="1.0" encoding="utf-8"?>
<manifest xmlns:android="http://schemas.android.com/apk/res/android"
    package="com.exmaple.test"
    android:installLocation="auto"
    android:versionCode="1"
    android:versionName="1.0" >

后：

<?xml version="1.0" encoding="utf-8"?>
<manifest xmlns:android="http://schemas.android.com/apk/res/android"
    package="com.exmaple.test"
    android:installLocation="auto"
    android:versionCode="2"
    android:versionName="1.01" >
— 贾里德·伯罗斯（Jared Burrows）
source
3

如果你写你versionCode的gradle.build文件（目前大多数情况下），这里是一个解决办法。有点愚蠢（更新“ self”），但是可以！

import java.util.regex.Pattern

task('increaseVersionCode') << {
    def buildFile = file("build.gradle")
    def pattern = Pattern.compile("versionCode(\\s+\\d+)")
    def buildText = buildFile.getText()
    def matcher = pattern.matcher(buildText)
    matcher.find()
    def versionCode = android.defaultConfig.versionCode
    def buildContent = matcher.replaceAll("versionCode " + ++versionCode)
    buildFile.write(buildContent)

    System.out.println("Incrementing Version Code ===> " + versionCode)
}

tasks.whenTaskAdded { task ->
    if (task.name == 'generateReleaseBuildConfig') {
        task.dependsOn 'increaseVersionCode'
    }
}
— 爱星
source
2

要添加到@sealskej的帖子中，这是您可以同时更新版本代码和版本名称的方法（此处，我假设您的主要版本和次要版本均为0）：

task('increaseVersion') << {
    def manifestFile = file("AndroidManifest.xml")
    def patternVersionCode = Pattern.compile("versionCode=\"(\\d+)\"")
    def manifestText = manifestFile.getText()
    def matcherVersionCode = patternVersionCode.matcher(manifestText)
    matcherVersionCode.find()
    def versionCode = Integer.parseInt(matcherVersionCode.group(1))
    def manifestContent = matcherVersionCode.replaceAll("versionCode=\"" + ++versionCode + "\"")

    manifestFile.write(manifestContent)

    def patternVersionNumber = Pattern.compile("versionName=\"0.0.(\\d+)\"")
    manifestText = manifestFile.getText()
    def matcherVersionNumber = patternVersionNumber.matcher(manifestText)
    matcherVersionNumber.find()
    def versionNumber = Integer.parseInt(matcherVersionNumber.group(1))
    manifestContent = matcherVersionNumber.replaceAll("versionName=\"0.0." + ++versionNumber + "\"")
    manifestFile.write(manifestContent)
}
— 卡里姆·瓦雷拉（Karim Varela）
source
1

那这个呢 ？添加到build.gradle（应用程序模块）

def getBuildVersionCode() {
    def date = new Date()
    def formattedDate = date.format('yyyyMMdd')
    def formattedSeconds = date.format('HHmmssSSS')
    def formatInt = formattedDate as int;
    def SecondsInt = formattedSeconds as int;
    return (formatInt + SecondsInt) as int
}

   defaultConfig {
    applicationId "com.app"
    minSdkVersion 17
    targetSdkVersion 22
    versionCode getBuildVersionCode()
    versionName "1.0"
}
— 卡罗利
source
2
好(20160129 + 000000000) < (20160128 + 125959999)
— 主意
0

因此，当我研究大多数解决方案时，它们很好但是还不够，所以我写了这个，每多次部署增加一个：

这将在编译调试版本时增加构建，并在部署时增加点和版本代码。

import java.util.regex.Pattern

def incrementVersionName(int length, int index) {
    def gradleFile = file("build.gradle")
    def versionNamePattern = Pattern.compile("versionName\\s*\"(.*?)\"")
    def gradleText = gradleFile.getText()
    def matcher = versionNamePattern.matcher(gradleText)
    matcher.find()

    def originalVersion = matcher.group(1)
    def originalVersionArray = originalVersion.split("\\.")
    def versionKeys = [0, 0, 0, 0]
    for (int i = 0; i < originalVersionArray.length; i++) {
        versionKeys[i] = Integer.parseInt(originalVersionArray[i])
    }
    def finalVersion = ""
    versionKeys[index]++;
    for (int i = 0; i < length; i++) {
        finalVersion += "" + versionKeys[i]
        if (i < length - 1)
            finalVersion += "."
    }

    System.out.println("Incrementing Version Name: " + originalVersion + " ==> " + finalVersion)

    def newGradleContent = gradleText.replaceAll("versionName\\s*\"(.*?)\"", "versionName \"" + finalVersion + "\"")
    gradleFile.write(newGradleContent)
}

def incrementVersionCode() {
    def gradleFile = file("build.gradle")
    def versionCodePattern = Pattern.compile("versionCode\\s*(\\d+)")
    def gradleText = gradleFile.getText()
    def matcher = versionCodePattern.matcher(gradleText)
    matcher.find()

    def originalVersionCode = Integer.parseInt(matcher.group(1) + "")
    def finalVersionCode = originalVersionCode + 1;
    System.out.println("Incrementing Version Code: " + originalVersionCode + " ==> " + finalVersionCode)

    def newGradleContent = gradleText.replaceAll("versionCode\\s*(\\d+)", "versionCode " + finalVersionCode)
    gradleFile.write(newGradleContent)
}

task('incrementVersionNameBuild') << {
    incrementVersionName(4, 3)
}

task('incrementVersionNamePoint') << {
    incrementVersionName(3, 2)
}

task('incrementVersionCode') << {
    incrementVersionCode()
}


def incrementedBuild = false
def incrementedRelease = false

tasks.whenTaskAdded { task ->
    System.out.println("incrementedRelease: " + incrementedRelease)
    System.out.println("incrementedBuild: " + incrementedBuild)
    System.out.println("task.name: " + task.name)

    if (!incrementedBuild && task.name.matches('generate.*?DebugBuildConfig')) {
        task.dependsOn 'incrementVersionNameBuild'
        incrementedBuild = true
        return
    }

    if (!incrementedRelease && task.name.matches('generate.*?ReleaseBuildConfig')) {
        task.dependsOn 'incrementVersionCode'
        task.dependsOn 'incrementVersionNamePoint'
        incrementedRelease = true
        return
    }
}
— TacB0sS
source
-1

我的方法是从构建文件夹中读取清单文件，并从那里获取buildVersion，而不是删除文件夹。当任务创建新的清单时，我递增的buildVersion变量已经在那里。

def versionPattern = "Implementation-Version=(\\d+.\\d+.\\d+.\\d+\\w+)"

task generateVersion (dependsOn : 'start') {
    // read build version from previous manifest
    def file = file("build/libs/MANIFEST.MF")
    if (file.exists()) {
        def pattern = Pattern.compile(versionPattern)
        def text = file.getText()
        def matcher = pattern.matcher(text)
        matcher.find()
        buildNumber = Integer.parseInt(matcher.group(1))
        // increment build version
        version = "${majorVer}.${minorVer}.${patchVer}.${++buildNumber}${classifier}_${access}"
    } 
    else 
        version = "${majorVer}.${minorVer}.${patchVer}.1${classifier}_${access}"
}

task specifyOutputDir (dependsOn : 'generateVersion', type : JavaCompile) {
    // create a folder for new build
    destinationDir = file("build/${version}/")
}

task clean (dependsOn : 'generateVersion', type : Delete) {
    doLast {
        delete "build/${version}"
        println 'Build directory is deleted'
    }
}

task configureJar (dependsOn : 'generateVersion', type : Jar) {
    baseName = applicationName
    version = project.version
    archiveName = "${applicationName}_ver${version}.${extension}"
    manifest {[
            "Main-Class" : mainClassName,
            "Implementation-Title" : name,
            "Implementation-Version" : version,
            "Access" : access,
            "Developer" : developer
    ]}
}
— 福寿胜
source
这不能为问题提供答案。一旦您拥有足够的声誉，您就可以在任何帖子中发表评论；相反，请提供不需要问询者澄清的答案。-评分
— MLavoie
@MLavoie现在检查一下我的WIP代码片段
— Katoteshi Fuku 2016年
By using our site, you acknowledge that you have read and understand our Cookie Policy and Privacy Policy.
Licensed under cc by-sa 3.0 with attribution required.