综上所述
有几种方法可以做到这一点，其中大多数已被建议，但我想我将它们总结为另外两个方法：
- 每个目录的vimrc-缺点是必须在正确的目录中启动Vim：如果您的项目位于
~/project1并且您有~/project1/.vim.custom执行权限cd ~ ; vim project1/file.c，则找不到自定义设置。
- 模式行-非常有效，但缺点是需要将它们添加到所有文件中（记住要将它们添加到新文件中）
- 特定于目录的自动命令-这非常有效
- 扫描文件中的特定标头（请参见下文）-这是我过去在不同公司或明确命名的项目中使用最多的标头
- 打开文件时检查的每个目录的vimrc（请参见下文）。另一个相当容易实现的代码，尤其是当您的项目代码都放在一个地方时。
扫描标题
在许多组织中，每个源文件的顶部都有一个标准标头（带有版权声明和项目名称等）。在这种情况下，您可以使Vim自动扫描文件的前10行，以寻找关键字。如果找到它，它可以更改您的设置。我已经对其进行了修改，使其比我使用的表单（做很多其他事情）更简单，但是创建了一个表单~/.vim/after/filetype.vim（如果您还没有的话）并添加了以下内容：
au FileType * call <SID>ConfigureFiletypes(expand("<amatch>"))
" List of file types to customise
let s:GROUPNAMETypes = ['c', 'cpp', 'vhdl', 'c.doxygen']
func! <SID>CheckForGROUPNAMECode()
" Check if any of the first ten lines contain "GROUPNAME".
" Read the first ten lines into a variable
let header = getline(1)
for i in range(2, 10)
let header = header . getline(i)
endfor
if header =~ '\<GROUPNAME\>'
" Change the status line to make it clear which
" group we're using
setlocal statusline=%<%f\ (GROUPNAME)\ %h%m%r%=%-14.(%l,%c%V%)\ %P
" Do other customisation here
setlocal et
" etc
endif
endfunc
func! <SID>ConfigureFiletypes(filetype)
if index(s:GROUPNAMETypes, a:filetype) != -1
call <SID>CheckForGROUPNAMECode()
endif
endfunc
每当打开任何类型的文件并设置文件类型（该au FileType *行）时，ConfigureFiletypes都会调用该函数。这将检查文件类型是否在与当前组（GROUPNAME）关联的文件类型列表中，在本例中为“ c”，“ cpp”，“ vhdl”或“ c.doxygen”。如果是这样，它将调用CheckForGROUPNAMECode（），后者将读取文件的前10行，并且如果它们包含GROUPNAME，则会进行一些自定义。除了设置expandtabs或其他设置外，这还会更改状态栏以清楚显示组名，以便您一目了然。
打开时检查配置
与JS Bangs的建议非常相似，拥有自定义配置文件可能会很有用。但是，不要将其加载到vimrc中，请考虑类似这样的事情，它将检查何时在与.c文件相同的目录中为.vim.custom打开.c文件。
au BufNewFile,BufRead *.c call CheckForCustomConfiguration()
function! CheckForCustomConfiguration()
" Check for .vim.custom in the directory containing the newly opened file
let custom_config_file = expand('%:p:h') . '/.vim.custom'
if filereadable(custom_config_file)
exe 'source' custom_config_file
endif
endfunction