如何在CMake中设置警告级别？

如何使用CMake为项目（而不是整个解决方案）设置警告级别？应该可以在Visual Studio和GCC上使用。

我找到了各种选项，但大多数似乎不起作用或与文档不一致。

更新：此答案早于现代CMake时代。每个理智的CMake用户都应避免摆弄，CMAKE_CXX_FLAGS而应调用该target_compile_options命令。检查mrts的答案，该答案提供了建议的最佳实践。

您可以执行以下操作：

if(MSVC)
  # Force to always compile with W4
  if(CMAKE_CXX_FLAGS MATCHES "/W[0-4]")
    string(REGEX REPLACE "/W[0-4]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
  else()
    set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} /W4")
  endif()
elseif(CMAKE_COMPILER_IS_GNUCC OR CMAKE_COMPILER_IS_GNUCXX)
  # Update if necessary
  set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} -Wall -Wno-long-long -pedantic")
endif()

在现代CMake中，以下方法可以很好地工作：

if(MSVC)
  target_compile_options(${TARGET_NAME} PRIVATE /W4 /WX)
else()
  target_compile_options(${TARGET_NAME} PRIVATE -Wall -Wextra -pedantic -Werror)
endif()

我的同事建议了一个替代版本：

target_compile_options(${TARGET_NAME} PRIVATE
  $<$<CXX_COMPILER_ID:MSVC>:/W4 /WX>
  $<$<NOT:$<CXX_COMPILER_ID:MSVC>>:-Wall -Wextra -pedantic -Werror>
)

替换${TARGET_NAME}为实际的目标名称。-Werror是可选的，它将所有警告变为错误。

或者，add_compile_options(...)如果您想将其应用于@aldo在注释中建议的所有目标，请使用。

此外，一定要了解之间的差异PRIVATE和PUBLIC（公共选项将依赖于给定的目标对象继承）。

我编写的某些CMake模块包括实验性跨平台警告抑制：

sugar_generate_warning_flags(
    target_compile_options
    target_properties
    ENABLE conversion
    TREAT_AS_ERRORS ALL
)

set_target_properties(
    foo
    PROPERTIES
    ${target_properties}
    COMPILE_OPTIONS
    "${target_compile_options}"
)

Xcode的结果：

• 设置CLANG_WARN_SUSPICIOUS_IMPLICIT_CONVERSIONXcode属性（又名构建设置 -> 警告 -> 可疑的隐式转换 -> YES）
• 添加编译器标志： -Werror

Makefile gcc和clang：

• 添加编译器标志：-Wconversion，-Werror

视觉工作室：

• 添加编译器标志：/WX，/w14244

链接

• 可用警告列表
• 用法和更多选项

这是到目前为止我发现的最佳解决方案（包括编译器检查）：

if(CMAKE_BUILD_TOOL MATCHES "(msdev|devenv|nmake)")
    add_definitions(/W2)
endif()

这将在Visual Studio中设置警告级别2。我想用-W2它也可以在GCC中使用（未经测试）。

@Williams的更新：应该-Wall用于GCC。

根据Cmake 3.17.1文档：

if (MSVC)
    # warning level 4 and all warnings as errors
    add_compile_options(/W4 /WX)
else()
    # lots of warnings and all warnings as errors
    add_compile_options(-Wall -Wextra -pedantic -Werror)
endif()

GCC和Clang共享这些标志，因此这应涵盖所有3个标志。

if(MSVC)
    string(REGEX REPLACE "/W[1-3]" "/W4" CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS}")
endif()

如果使用target_compile_options-cmake将尝试使用double /W*标志，这将由编译器发出警告。