Groovy内置的REST / HTTP客户端？

我听说Groovy具有内置的REST / HTTP客户端。我唯一可以找到的库是HttpBuilder，这是吗？

基本上，我正在寻找一种从Groovy代码内部执行HTTP GET的方法，而不必导入任何库（如果可能的话）。但是由于该模块似乎不是核心Groovy的一部分，所以我不确定此处是否具有正确的库。

本地Groovy GET和POST

// GET
def get = new URL("https://httpbin.org/get").openConnection();
def getRC = get.getResponseCode();
println(getRC);
if(getRC.equals(200)) {
    println(get.getInputStream().getText());
}

// POST
def post = new URL("https://httpbin.org/post").openConnection();
def message = '{"message":"this is a message"}'
post.setRequestMethod("POST")
post.setDoOutput(true)
post.setRequestProperty("Content-Type", "application/json")
post.getOutputStream().write(message.getBytes("UTF-8"));
def postRC = post.getResponseCode();
println(postRC);
if(postRC.equals(200)) {
    println(post.getInputStream().getText());
}

如果您的需求很简单，并且希望避免添加其他依赖项，则可以使用getText()Groovy添加到java.net.URL类中的方法：

new URL("http://stackoverflow.com").getText()

// or

new URL("http://stackoverflow.com")
        .getText(connectTimeout: 5000, 
                readTimeout: 10000, 
                useCaches: true, 
                allowUserInteraction: false, 
                requestProperties: ['Connection': 'close'])

如果您期望返回二进制数据，则这些newInputStream()方法还提供了类似的功能。

最简单的一个是：

def html = "http://google.com".toURL().text

您可以利用诸如with（）的Groovy功能，对URLConnection的改进以及简化的getter / setter方法：

得到：

String getResult = new URL('http://mytestsite/bloop').text

开机自检：

String postResult
((HttpURLConnection)new URL('http://mytestsite/bloop').openConnection()).with({
    requestMethod = 'POST'
    doOutput = true
    setRequestProperty('Content-Type', '...') // Set your content type.
    outputStream.withPrintWriter({printWriter ->
        printWriter.write('...') // Your post data. Could also use withWriter() if you don't want to write a String.
    })
    // Can check 'responseCode' here if you like.
    postResult = inputStream.text // Using 'inputStream.text' because 'content' will throw an exception when empty.
})

请注意，当你尝试读取从HttpURLConnection的值，如POST将启动responseCode，inputStream.text或getHeaderField('...')。

HTTPBuilder就是它。很好用。

import groovyx.net.http.HTTPBuilder

def http = new HTTPBuilder('https://google.com')
def html = http.get(path : '/search', query : [q:'waffles'])

如果您需要错误处理和通常更多的功能，而不仅仅是使用GET提取内容，则它特别有用。

我不认为http-builder是Groovy模块，而是在apache http-client之上的外部API，因此您确实需要导入类并下载大量API。您最好使用Gradle或@Grab下载jar和依赖项：

@Grab(group='org.codehaus.groovy.modules.http-builder', module='http-builder', version='0.7.1' )
import groovyx.net.http.*
import static groovyx.net.http.ContentType.*
import static groovyx.net.http.Method.*

注意：由于CodeHaus站点出现故障，因此可以在以下位置找到JAR：（https://mvnrepository.com/artifact/org.codehaus.groovy.modules.http-builder/http-builder）

import groovyx.net.http.HTTPBuilder;

public class HttpclassgetrRoles {
     static void main(String[] args){
         def baseUrl = new URL('http://test.city.com/api/Cirtxyz/GetUser')

         HttpURLConnection connection = (HttpURLConnection) baseUrl.openConnection();
         connection.addRequestProperty("Accept", "application/json")
         connection.with {
           doOutput = true
           requestMethod = 'GET'
           println content.text
         }

     }
}