从`cmake`使用`pkg-config`的正确方法是什么？

在网上环顾四周，我看到了很多这样的代码：

include(FindPkgConfig)
pkg_search_module(SDL2 REQUIRED sdl2)

target_include_directories(app SYSTEM PUBLIC ${SDL2_INCLUDE_DIRS}
target_link_libraries(app ${SDL2_LIBRARIES})

但是，这样做似乎是错误的方法，因为它仅使用include目录和库，但忽略了定义，库路径和可能由返回的其他标志pkg-config。

做到这一点并确保编译pkg-config器使用返回的所有编译和链接标志的正确方法是什么app？是否有单个命令来完成此操作，即类似target_use(app SDL2)？

参考：

• include()
• FindPkgConfig

如果您以非常普通的方式使用cmake和pkg-config，则此解决方案有效。

但是，如果您在某个开发目录（例如/ home / me / hack / lib）中存在一个库，则使用此处显示的其他方法无法配置链接器路径。在典型安装位置下找不到的库将导致链接器错误，例如/usr/bin/ld: cannot find -lmy-hacking-library-1.0。此解决方案解决了这种情况下的链接器错误。

另一个问题可能是pkg-config文件未正常安装，并且在cmake运行时需要使用PKG_CONFIG_PATH环境变量添加项目的pkg-config路径（请参阅与此有关的其他Stack Overflow问题）。假设您设置了正确的pkg-config路径，此解决方案也可以解决该问题。

解决方案归结为工作的CMakeLists.txt的最终版本：

cmake_minimum_required(VERSION 3.14)
project(ya-project C)

# the `pkg_check_modules` function is created with this call
find_package(PkgConfig REQUIRED) 

# these calls create special `PkgConfig::<MODULE>` variables
pkg_check_modules(MY_PKG REQUIRED IMPORTED_TARGET any-package)
pkg_check_modules(YOUR_PKG REQUIRED IMPORTED_TARGET ya-package)

add_executable(program-name file.c ya.c)

target_link_libraries(program-name PUBLIC
        PkgConfig::MY_PKG
        PkgConfig::YOUR_PKG)

请注意，target_link_libraries这不仅仅更改链接器命令。它还传播指定目标的其他PUBLIC属性，例如：编译器标志，编译器定义，包含路径等。

首先，调用：

include(FindPkgConfig)

应替换为：

find_package(PkgConfig)

该find_package()调用更加灵活，并允许诸如之类的选项REQUIRED自动执行某些操作，而这些操作可能需要手动执行include()。

其次，pkg-config应尽可能避免手动调用。CMake带有丰富的软件包定义集，可在Linux下找到/usr/share/cmake-3.0/Modules/Find*cmake。与对的原始调用相比，它们为用户提供了更多的选择和选择pkg_search_module()。

至于提到的假设target_use()命令，CMake已经以PUBLIC | PRIVATE | INTERFACE的方式内置了该命令。像这样的调用target_include_directories(mytarget PUBLIC ...)将使include目录在使用的每个目标中自动使用 mytarget，例如target_link_libraries(myapp mytarget)。但是，此机制似乎仅适用于在CMakeLists.txt文件中创建的库，而不适用于使用捕获的库pkg_search_module()。该呼叫add_library(bar SHARED IMPORTED)可能用于此目的，但我尚未对此进行研究。

对于主要问题，此方法在大多数情况下适用：

find_package(PkgConfig REQUIRED)
pkg_check_modules(SDL2 REQUIRED sdl2)
...
target_link_libraries(testapp ${SDL2_LIBRARIES})
target_include_directories(testapp PUBLIC ${SDL2_INCLUDE_DIRS})
target_compile_options(testapp PUBLIC ${SDL2_CFLAGS_OTHER})

该SDL2_CFLAGS_OTHER包含必要的定义和其他标志一个成功的编译。但是，标记SDL2_LIBRARY_DIRS和SDL2_LDFLAGS_OTHER仍然被忽略，不知道这会成为问题的频率。

此处提供更多文档http://www.cmake.org/cmake/help/v3.0/module/FindPkgConfig.html

很少有人只需要链接SDL2。当前流行的答案用于pkg_search_module()检查给定的模块，并使用第一个有效的模块。

您更可能希望与SDL2和SDL2_Mixer和SDL2_TTF链接，等等。。。pkg_check_modules()检查所有给定的模块。

# sdl2 linking variables
find_package(PkgConfig REQUIRED)
pkg_check_modules(SDL2 REQUIRED sdl2 SDL2_ttf SDL2_mixer SDL2_image)

# your app
file(GLOB SRC "my_app/*.c")
add_executable(my_app ${SRC})
target_link_libraries(my_app ${SDL2_LIBRARIES})
target_include_directories(my_app PUBLIC ${SDL2_INCLUDE_DIRS})
target_compile_options(my_app PUBLIC ${SDL2_CFLAGS_OTHER})

免责声明：如果我有足够的街头信誉与stackoverflow，我会简单评论Grumbel的自我回答。

大多数可用的答案都无法为pkg-config库配置头。在对FindPkgConfig的文档进行冥想之后，我想出了一个解决方案，该解决方案还提供了以下解决方案：

include(FindPkgConfig)
if(NOT PKG_CONFIG_FOUND)
  message(FATAL_ERROR "pkg-config not found!" )
endif()
 
pkg_check_modules(<some-lib> REQUIRED IMPORTED_TARGET <some-lib>)
 
target_link_libraries(<my-target> PkgConfig::<some-lib>)

（相应地，将您的目标替换为，<my-target>而将任何库替换为<some-lib>。）

该IMPORTED_TARGET选项似乎很关键，可以使所有内容在PkgConfig::名称空间下可用。这是所有需要的，也应该是所有需要的。

1. 没有这样的命令target_use。但是我知道有几个项目已经为内部使用编写了这样的命令。但是，每个项目都希望传递其他标志或定义，因此在一般的CMake中使用它是没有意义的。没有它的另一个原因是像Eigen这样的C ++模板库，没有库，但是只有一堆include文件。

2. 所描述的方法通常是正确的。对于某些库来说可能有所不同，那么您必须添加_LDFLAGS或_CFLAGS。没有的另一个原因target_use。如果对您不起作用，请询问有关SDL2或您要使用的任何库的新问题。

如果您还希望从库中添加定义，add_definitions则此处提供了说明。文档可以在这里找到，以及添加编译器标志的更多方法。

以下代码段使用此指令将GTKGL添加到项目中：

pkg_check_modules(GTKGL REQUIRED gtkglext-1.0)
include_directories(${GTKGL_INCLUDE_DIRS})
link_directories(${GTKGL_LIBRARY_DIRS})
add_definitions(${GTKGL_CFLAGS_OTHER})
set(LIBS ${LIBS} ${GTKGL_LIBRARIES})

target_link_libraries([insert name of program] ${LIBS})