如何在Emacs中设置字体大小？

我也想将字体大小保存在.emacs文件中。

(set-face-attribute 'default nil :height 100)

该值的单位是1 / 10pt，因此100等于10pt，依此类推。

在Emacswiki中，GNU Emacs 23具有内置的组合键：

C-xC-+并C-xC--增加或减少缓冲区文本的大小

按下Shift键和第一个鼠标键。您可以通过以下方式更改字体大小： 该网站有更多详细信息。

M-x customize-face RET default 将允许您设置脸部 default所有其他面孔都基于的面孔。在那里您可以设置字体大小。

这是我的.emacs中的内容。实际上，颜色主题将设置基础知识，然后我的自定义面部设置将覆盖某些内容。自定义界面由emacs的custom-face机制编写：

;; my colour theme is whateveryouwant :)
(require 'color-theme)
(color-theme-initialize)
(color-theme-whateveryouwant)

(custom-set-faces
  ;; custom-set-faces was added by Custom.
  ;; If you edit it by hand, you could mess it up, so be careful.
  ;; Your init file should contain only one such instance.
  ;; If there is more than one, they won't work right.
 '(default ((t (:stipple nil :background "white" :foreground "black" :inverse-video nil :box nil :strike-through nil :overline nil :underline nil :slant normal :weight normal :height 98 :width normal :foundry "unknown" :family "DejaVu Sans Mono"))))
 '(font-lock-comment-face ((t (:foreground "darkorange4"))))
 '(font-lock-function-name-face ((t (:foreground "navy"))))
 '(font-lock-keyword-face ((t (:foreground "red4"))))
 '(font-lock-type-face ((t (:foreground "black"))))
 '(linum ((t (:inherit shadow :background "gray95"))))
 '(mode-line ((t (nil nil nil nil :background "grey90" (:line-width -1 :color nil :style released-button) "black" :box nil :width condensed :foundry "unknown" :family "DejaVu Sans Mono")))))

这是另一个简单的解决方案。同样适用于24

(set-default-font "Monaco 14")

捷径：

`C-+` increases font size
`C--` Decreases font size

我的内容如下.emacs：

(defun fontify-frame (frame)
  (set-frame-parameter frame 'font "Monospace-11"))

;; Fontify current frame
(fontify-frame nil)
;; Fontify any future frames
(push 'fontify-frame after-make-frame-functions) 

您可以将选择的任何字体替换为"Monospace-11"。可用选项集高度依赖于系统。使用M-x set-default-font并查看制表符补全将为您提供一些想法。在我的系统，使用Emacs 23和启用抗锯齿，可以选择按名称，例如，系统字体Monospace，Sans Serif等等。

在X11中打开emacs，转到菜单选项，选择“设置默认字体...”，更改字体大小。在同一菜单中选择“保存选项”。做完了

zoom.cfg和global-zoom.cfg提供字体大小更改绑定（来自EmacsWiki）

• C-或C-mousewheel-up：增加字体大小。
• C- +或C-mousewheel-down：减小字体大小。
• C-0将字体大小恢复为默认值。

这是一个用于交互式调整字体高度的选项，一次仅需一点：

;; font sizes
(global-set-key (kbd "s-=")
                (lambda ()
                  (interactive)
                  (let ((old-face-attribute (face-attribute 'default :height)))
                    (set-face-attribute 'default nil :height (+ old-face-attribute 10)))))

(global-set-key (kbd "s--")
                (lambda ()
                  (interactive)
                  (let ((old-face-attribute (face-attribute 'default :height)))
                    (set-face-attribute 'default nil :height (- old-face-attribute 10)))))

当您要调整所有缓冲区中的文本大小时，这是首选方法。我不喜欢使用text-scale-increase和的解决方案，text-scale-decrease因为装订线中的行号之后可能会被切断。

Firefox和其他程序允许您使用C- +和C--增大和减小字体大小。我设置了.emacs，以便通过添加以下代码行来具有相同的功能：

(global-set-key [C-kp-add] 'text-scale-increase)

(global-set-key [C-kp-subtract] 'text-scale-decrease)

Aquamacs：

(set-face-attribute 'default nil :font "Monaco-16" )

从Emacs Wiki 全局更改默认字体，它说您可以使用以下任一方法：

(set-face-attribute 'default nil :font FONT )

(set-frame-font FONT nil t)

哪里FONT是一样的东西"Monaco-16"，如：

(set-face-attribute 'default nil :font "Monaco-16" )

Wiki上的第一个建议中有一个额外的右括号，这导致启动时出错。我终于注意到了多余的右括号，随后我更正了Wiki上的建议。然后，这两个建议对我都有效。

这完全取决于更改字体大小的含义。此EmacsWiki部分提供了最佳和最完整的信息。它区分了各种情况（文本缩放，框架字体，缓冲区/框架等）：更改字体大小。

在NTEmacs 23.1中，“选项”菜单具有“设置默认字体...”选项。

我对控制台emacs（emacs -nw）感到满意，现代vterm实现（例如gnome-terminal）往往具有更好的字体支持。另外，如果您习惯了这一点，则可以使用tmux，因此即使没有X，也可以在远程服务器上使用完整环境。

在AquaMacs中CMD +，CMD -调整当前缓冲区的字体大小。

我使用hydra包通过按f2 + + + +/来连续控制字体的增/减f2 - - - -，这意味着按f2一次，然后使用+/ -仅控制，并通过恢复默认字体大小f2 0。因为我有键盘，所以我也将键盘绑定到字体设置。

(defhydra hydra-zoom (global-map "<f2>")
  "zoom"
  ("<kp-add>" text-scale-increase "in")
  ("+" text-scale-increase "in")
  ("-" text-scale-decrease "out")
  ("<kp-subtract>" text-scale-decrease "out")
  ("0" (text-scale-set 0) "reset")
  ("<kp-0>" (text-scale-set 0) "reset"))

以及以下按键绑定所支持的现代编辑器鼠标控件功能，请按Control +鼠标滚轮来增加/减少字体。

(global-set-key (kbd "<C-wheel-up>") 'text-scale-increase)
(global-set-key (kbd "<C-wheel-down>") 'text-scale-decrease)

这是一个片段，使您可以使用交互式功能直接指定全局字体大小：

(defun set-font-size ()
    "Set the font size."
  (interactive)
  (set-face-attribute
   'default nil :height
   (string-to-number
    (read-string "Font size: " (number-to-string (face-attribute 'default :height nil))))))