XSLT字符串替换

我不太了解XSL，但是我需要修复此代码，为了简化起见，我对其进行了缩小。
我收到此错误

无效的XSLT / XPath函数

在这条线上

<xsl:variable name="text" select="replace($text,'a','b')"/>

这是XSL

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:inm="http://www.inmagic.com/webpublisher/query" version="1.0">
    <xsl:output method="text" encoding="UTF-8" />

    <xsl:preserve-space elements="*" />
    <xsl:template match="text()" />

    <xsl:template match="mos">
        <xsl:apply-templates />

        <xsl:for-each select="mosObj">
          'Notes or subject' 
           <xsl:call-template
                name="rem-html">
                <xsl:with-param name="text" select="SBS_ABSTRACT" />
            </xsl:call-template>
        </xsl:for-each>
    </xsl:template>

    <xsl:template name="rem-html">
        <xsl:param name="text" />
        <xsl:variable name="text" select="replace($text, 'a', 'b')" />
    </xsl:template>
</xsl:stylesheet>

谁能告诉我这是怎么回事？

replace 不适用于XSLT 1.0。

Codesling有一个用于字符串替换的模板，您可以用它代替该函数：

<xsl:template name="string-replace-all">
    <xsl:param name="text" />
    <xsl:param name="replace" />
    <xsl:param name="by" />
    <xsl:choose>
        <xsl:when test="$text = '' or $replace = ''or not($replace)" >
            <!-- Prevent this routine from hanging -->
            <xsl:value-of select="$text" />
        </xsl:when>
        <xsl:when test="contains($text, $replace)">
            <xsl:value-of select="substring-before($text,$replace)" />
            <xsl:value-of select="$by" />
            <xsl:call-template name="string-replace-all">
                <xsl:with-param name="text" select="substring-after($text,$replace)" />
                <xsl:with-param name="replace" select="$replace" />
                <xsl:with-param name="by" select="$by" />
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="$text" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

调用为：

<xsl:variable name="newtext">
    <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="$text" />
        <xsl:with-param name="replace" select="a" />
        <xsl:with-param name="by" select="b" />
    </xsl:call-template>
</xsl:variable>

另一方面，如果您只需要用一个字符替换另一个字符，则可以调用translate具有相似签名的字符。这样的事情应该可以正常工作：

<xsl:variable name="newtext" select="translate($text,'a','b')"/>

另外，请注意，在此示例中，我将变量名称更改为“ newtext”，因为XSLT中的变量是不可变的，所以您不能做与$foo = $foo原始代码中相同的操作。

这是XSLT函数，其功能类似于C＃的String.Replace（）函数。

该模板具有以下3个参数

文字：-您的主要字串

replace：-您要替换的字符串

通过：-将由新字符串答复的字符串

以下是模板

<xsl:template name="string-replace-all">
  <xsl:param name="text" />
  <xsl:param name="replace" />
  <xsl:param name="by" />
  <xsl:choose>
    <xsl:when test="contains($text, $replace)">
      <xsl:value-of select="substring-before($text,$replace)" />
      <xsl:value-of select="$by" />
      <xsl:call-template name="string-replace-all">
        <xsl:with-param name="text" select="substring-after($text,$replace)" />
        <xsl:with-param name="replace" select="$replace" />
        <xsl:with-param name="by" select="$by" />
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$text" />
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

下面的示例显示了如何调用它

<xsl:variable name="myVariable ">
  <xsl:call-template name="string-replace-all">
    <xsl:with-param name="text" select="'This is a {old} text'" />
    <xsl:with-param name="replace" select="'{old}'" />
    <xsl:with-param name="by" select="'New'" />
  </xsl:call-template>
</xsl:variable>

您也可以参考下面的URL了解详细信息。

注意：如果你想使用算法中已经提到的，你需要替换源字符串中的情况下（在长文本如新线）的数量庞大的情况下，有较高的概率你会结束了StackOverflowException，因为递归呼叫。

我解决了这个问题，这要归功于Xalan的内置Java类型嵌入（在Saxon中不怎么做）：

<xsl:stylesheet version="1.0" exclude-result-prefixes="xalan str"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:xalan="http://xml.apache.org/xalan"
                xmlns:str="xalan://java.lang.String"
        >
...
<xsl:value-of select="str:replaceAll(
    str:new(text()),
    $search_string,
    $replace_string)"/>
...
</xsl:stylesheet>

当处理器在.NET上运行或使用MSXML（而不是基于Java的处理器或其他本机处理器）时，可以使用以下代码。它使用msxsl:script。

确保将名称空间添加xmlns:msxsl="urn:schemas-microsoft-com:xslt"到您的根xsl:stylesheet或xsl:transform元素。

另外，绑定outlet到任何您喜欢的名称空间，例如xmlns:outlet = "http://my.functions"。

<msxsl:script implements-prefix="outlet" language="javascript">
function replace_str(str_text,str_replace,str_by)
{
     return str_text.replace(str_replace,str_by);
}
</msxsl:script>


<xsl:variable name="newtext" select="outlet:replace_str(string(@oldstring),'me','you')" />

我一直在寻找答案。但是它们都没有列出xsltproc（可能是大多数XSLT 1.0处理器）最简单的解决方案：

1. 将exslt字符串名称添加到样式表中，即：

<xsl:stylesheet
  version="1.0"
  xmlns:str="http://exslt.org/strings"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

2. 然后像这样使用它：

<xsl:value-of select="str:replace(., ' ', '')"/>

例程非常好，但是它导致我的应用程序挂起，因此我需要添加大小写：

  <xsl:when test="$text = '' or $replace = ''or not($replace)" >
    <xsl:value-of select="$text" />
    <!-- Prevent thsi routine from hanging -->
  </xsl:when>

在递归调用函数之前。

我从这里得到答案： 当测试陷入无限循环时

谢谢！