如何将文件内容读取到批处理文件中的变量中？

此批处理文件释放从TEST到LIVE的构建。我想在此文件中添加检查约束，以确保特定文件夹中有相应的发行文档。

"C:\Program Files\Windows Resource Kits\Tools\robocopy.exe" "\\testserver\testapp$"        
"\\liveserver\liveapp$" *.* /E /XA:H /PURGE /XO /XD ".svn" /NDL /NC /NS /NP
del "\\liveserver\liveapp$\web.config"
ren "\\liveserver\liveapp$\web.live.config" web.config

所以我有几个关于如何实现这一目标的问题...

1. version.txt文件\\testserver\testapp$夹中有一个文件，此文件的唯一内容是内部版本号（例如，对于45，对于内部版本45）如何将version.txt文件内容读入批处理文件中的变量中？

2. 如何\\fileserver\myapp\releasedocs\ {build}.doc使用第1部分中的变量代替{build} 检查文件，是否存在？

将文件内容读入变量：

for /f "delims=" %%x in (version.txt) do set Build=%%x

要么

set /p Build=<version.txt

两者仅在文件中的一行中就可以起到相同的作用，对于更多行，for变体会将最后一行放入变量中，而set /p将使用第一行。

就像使用任何其他环境变量一样，使用变量毕竟是一个：

%Build%

因此，检查是否存在：

if exist \\fileserver\myapp\releasedocs\%Build%.doc ...

尽管很可能那里没有UNC路径。现在无法测试，但请记住这一点。

您可以像这样从文件中读取多个变量：

for /f "delims== tokens=1,2" %%G in (param.txt) do set %%G=%%H

其中param.txt：

PARAM1=value1
PARAM2=value2
...

做就是了：

type version.txt

它将显示为就像您键入：

set /p Build=<version.txt
echo %Build%

要将文件的所有行都加载到变量中，需要延迟扩展，因此请执行以下操作：

SETLOCAL EnableDelayedExpansion

for /f "Tokens=* Delims=" %%x in (version.txt) do set Build=!Build!%%x

有一些特殊字符的问题，虽然特别;，%和!