获取Windows批处理脚本（.bat）中传递的参数列表

我想找到Bash的Windows批处理副本，$@其中包含传递给脚本的所有参数的列表。

还是我不得不打扰shift？

%*对于所有命令行参数（脚本名称本身除外），dancavallaro都正确。这些对你也可能有用：

%0-用于调用批处理文件中的命令（可以是foo，..\foo，c:\bats\foo.bat，等等）
%1是第一个命令行参数，
%2是第二个命令行参数，
并以此类推，直到%9（并且SHIFT可用于与第九之后）。

%~nx0-批处理文件的实际名称，与调用方法无关（some-batch.bat）
%~dp0-脚本的驱动器和路径（d：\ scripts）
%~dpnx0-是脚本的标准路径名（d：\ scripts \ some -batch.bat）

有关更多信息示例，请访问https://www.ss64.com/nt/syntax-args.html和https://www.robvanderwoude.com/parameters.html

%* 似乎拥有传递给脚本的所有参数。

%1... %n并%*保留参数，但是访问它们可能很棘手，因为内容将被解释。
因此，不可能用普通语句处理这样的事情

myBatch.bat "&"^&

每行失败，因为cmd.exe尝试执行一个＆符（％1的内容为"&"&）

set var=%1
set "var=%1"
set var=%~1
set "var=%~1"

但是存在一个临时文件的解决方法

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt=$_"
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

诀窍是启用echo on和扩展%1after rem语句（也适用于％2 ..％*）。
但是要能够重定向的输出echo on，您需要两个FOR-LOOPS。

多余的字符* #用于防止出现类似内容/?（会显示REM的帮助）。
或者行尾的插入号^可以用作多行字符。

FOR / F应该在延迟扩展关闭的情况下工作，否则内容应带有“！” 将被摧毁。
删除多余的字符后param1，您就知道了。

为了param1安全使用，请启用延迟扩展。

编辑：对％0的一句话

%0包含用于调用该批处理的命令，还保留了类似情况，FoO.BaT
但在调用函数后在But中%0，还%~0包含了函数名称（或更佳的是用于调用该函数的字符串）。
但是%~f0您仍然可以回忆起文件名。

@echo off
echo main %0, %~0, %~f0
call :myLabel+xyz
exit /b

:MYlabel
echo func %0, %~0, %~f0
exit /b

输出量

main test.bat, test.bat, C:\temp\test.bat
func :myLabel+xyz, :myLabel+xyz, C:\temp\test.bat

我发现下一次您需要查找这些信息时。除了打开浏览器并用谷歌浏览器，您只需输入call /?您的cmd就可以了：

...

%* in a batch script refers to all the arguments (e.g. %1 %2 %3
    %4 %5 ...)

Substitution of batch parameters (%n) has been enhanced.  You can
now use the following optional syntax:

    %~1         - expands %1 removing any surrounding quotes (")
    %~f1        - expands %1 to a fully qualified path name
    %~d1        - expands %1 to a drive letter only
    %~p1        - expands %1 to a path only
    %~n1        - expands %1 to a file name only
    %~x1        - expands %1 to a file extension only
    %~s1        - expanded path contains short names only
    %~a1        - expands %1 to file attributes
    %~t1        - expands %1 to date/time of file
    %~z1        - expands %1 to size of file
    %~$PATH:1   - searches the directories listed in the PATH
                   environment variable and expands %1 to the fully
                   qualified name of the first one found.  If the
                   environment variable name is not defined or the
                   file is not found by the search, then this
                   modifier expands to the empty string

The modifiers can be combined to get compound results:

    %~dp1       - expands %1 to a drive letter and path only
    %~nx1       - expands %1 to a file name and extension only
    %~dp$PATH:1 - searches the directories listed in the PATH
                   environment variable for %1 and expands to the
                   drive letter and path of the first one found.
    %~ftza1     - expands %1 to a DIR like output line

In the above examples %1 and PATH can be replaced by other
valid values.  The %~ syntax is terminated by a valid argument
number.  The %~ modifiers may not be used with %*

检索脚本中所有参数的方法如下：

@ECHO off
ECHO The %~nx0 script args are...
for %%I IN (%*) DO ECHO %%I
pause

这是获取args并将其设置为env vars的一种相当简单的方法。在此示例中，我仅将它们称为键和值。

将以下代码示例另存为“ args.bat”。然后从命令行调用您保存的批处理文件。例如：arg.bat --x 90 --y 120

我提供了一些echo命令来逐步引导您完成此过程。但是最终结果是--x的值为90，而--y的值为120（也就是说，如果您按照上面指定的示例运行;-)）。

然后，您可以使用“如果已定义”条件语句来确定是否运行代码块。因此，可以说运行：“ arg.bat --x hello-world”，然后可以使用语句“ IF DEFINED –x echo％-x％”，结果将为“ hello-world”。如果运行批处理，应该更有意义。

@setlocal enableextensions enabledelayedexpansion
@ECHO off
ECHO.
ECHO :::::::::::::::::::::::::: arg.bat example :::::::::::::::::::::::::::::::
ECHO :: By:      User2631477, 2013-07-29                                   ::
ECHO :: Version: 1.0                                                         ::
ECHO :: Purpose: Checks the args passed to the batch.                        ::
ECHO ::                                                                      ::
ECHO :: Start by gathering all the args with the %%* in a for loop.          ::
ECHO ::                                                                      ::
ECHO :: Now we use a 'for' loop to search for our keys which are identified  ::
ECHO :: by the text '--'. The function then sets the --arg ^= to the next    ::
ECHO :: arg. "CALL:Function_GetValue" ^<search for --^> ^<each arg^>         ::
ECHO ::                                                                      ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::

ECHO.

ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: From the command line you could pass... arg.bat --x 90 --y 220       ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO.Checking Args:"%*"

FOR %%a IN (%*) do (
    CALL:Function_GetValue "--","%%a" 
)

ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: Now lets check which args were set to variables...                   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO :: For this we are using the CALL:Function_Show_Defined "--x,--y,--z"   ::
ECHO ::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
CALL:Function_Show_Defined "--x,--y,--z"
endlocal
goto done

:Function_GetValue

REM First we use find string to locate and search for the text.
echo.%~2 | findstr /C:"%~1" 1>nul

REM Next we check the errorlevel return to see if it contains a key or a value
REM and set the appropriate action.

if not errorlevel 1 (
  SET KEY=%~2
) ELSE (
  SET VALUE=%~2
)
IF DEFINED VALUE (
    SET %KEY%=%~2
    ECHO.
    ECHO ::::::::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::
    ECHO :: The KEY:'%KEY%' is now set to the VALUE:'%VALUE%'                     ::
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
    ECHO %KEY%=%~2
    ECHO.
    REM It's important to clear the definitions for the key and value in order to
    REM search for the next key value set.
    SET KEY=
    SET VALUE=
)
GOTO:EOF

:Function_Show_Defined 
ECHO.
ECHO ::::::::::::::::::: %~0 ::::::::::::::::::::::::::::::::
ECHO :: Checks which args were defined i.e. %~2
ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
ECHO.
SET ARGS=%~1
for %%s in (%ARGS%) DO (
    ECHO.
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO :: For the ARG: '%%s'                         
    IF DEFINED %%s (
        ECHO :: Defined as: '%%s=!%%s!'                                             
    ) else (
        ECHO :: Not Defined '%%s' and thus has no value.
    )
    ECHO :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
    ECHO.
)
goto:EOF

:done

要使用循环以纯批处理方式获取所有参数：

Obs：不使用时：?*&<>

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!")

:: write/test these arguments/parameters ::
for /l %%l in (1 1 !_cnt!)do echo/ The argument n:%%l is: !_arg_[%%l]!

goto :eof 

您的代码已准备就绪，可以在需要的地方使用参数编号进行处理，例如...

@echo off && setlocal EnableDelayedExpansion

for %%Z in (%*)do set "_arg_=%%Z" && set/a "_cnt+=1+0" && call set "_arg_[!_cnt!]=!_arg_!"

echo= !_arg_[1]! !_arg_[2]! !_arg_[2]!> log.txt

以下代码模拟一个数组（' params'）-接受脚本接收的参数，并将它们存储在变量params_1..中params_n，其中n= params_0=数组元素的数量：

@echo off

rem Storing the program parameters into the array 'params':
rem Delayed expansion is left disabled in order not to interpret "!" in program parameters' values;
rem however, if a parameter is not quoted, special characters in it (like "^", "&", "|") get interpreted at program launch
set /a count=0
:repeat
    set /a count+=1
    set "params_%count%=%~1"
    shift
    if defined params_%count% (
        goto :repeat
    ) else (
        set /a count-=1
    )    
set /a params_0=count

rem Printing the program parameters stored in the array 'params':
rem After the variables params_1 .. params_n are set with the program parameters' values, delayed expansion can
rem be enabled and "!" are not interpreted in the variables params_1 .. params_n values
setlocal enabledelayedexpansion
    for /l %%i in (1,1,!params_0!) do (
        echo params_%%i: "!params_%%i!"
    )
endlocal

pause
goto :eof

如果引号中包含空格的参数%*将无法正常工作。我发现的最好的解决方案是有一个连接所有参数的循环：https : //serverfault.com/a/22541

set args=%1
shift
:start
if [%1] == [] goto done
set args=%args% %1
shift
goto start

:done
(use %args% here)

您可以使用ForCommad获取Arg的列表。

帮助：For /? 帮助：Setlocal /?

这是我的方式=

@echo off
::For Run Use This = cmd /c ""Args.cmd" Hello USER Scientist etc"
setlocal EnableDelayedExpansion
set /a Count=0
for %%I IN (%*) DO (
 Echo Arg_!Count! = %%I
 set /a Count+=1 
)
Echo Count Of Args = !Count!
Endlocal

不需要Shift命令。

@回声关闭
：开始

::在此处插入您的代码
echo。%% 1现在是：％〜1
::最后在此处插入您的代码

如果“％〜2” NEQ“”（
    转移
    转到：开始
）

上面的许多信息使我进一步研究，最终得到了答案，因此我想贡献自己的努力，希望对其他人有所帮助：

• 我还想将各种变量传递给批处理文件，以便可以在文件中对其进行处理。

• 我可以使用引号将它们传递到批处理文件中

• 我希望它们的处理类似于以下内容-但使用循环而不是手动写出：

所以我想执行这个：

prog_ZipDeleteFiles.bat "_appPath=C:\Services\Logs\PCAP" "_appFile=PCAP*.?"

并通过for循环的魔术在批处理文件中执行以下操作：

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

我遇到的问题是，我尝试使用for循环的所有尝试均无效。下面的例子：

for /f "tokens* delims= " in %%A (%*) DO (
   set %%A
)

会做：

set "_appPath=C:\Services\Logs\PCAP"

并不是：

set "_appPath=C:\Services\Logs\PCAP"
set "_appFile=PCAP*.?"

即使设定后

SETLOCAL EnableDelayedExpansion

原因是for循环读取了整行，并在循环的第一次迭代期间将我的第二个参数分配给%% B。因为％*代表所有参数，所以仅需处理一行-因此，仅执行一次for循环。事实证明，这是设计使然，我的逻辑是错误的。

因此，我停止尝试使用for循环，并通过使用if，shift和goto语句简化了尝试执行的操作。同意了一点技巧，但它更适合我的需求。我可以遍历所有参数，然后在处理完所有参数后使用if语句退出循环。

我要完成的成就的获奖声明：

echo on
:processArguments
:: Process all arguments in the order received
if defined %1 then (
    set %1
    shift
    goto:processArguments
) ELSE (
    echo off 
)

更新-我不得不修改为以下内容，而是在尝试引用％1并以这种方式使用shift时公开了所有环境变量：

echo on
shift
:processArguments
:: Process all arguments in the order received
if defined %0 then (
    set %0
    shift
    goto:processArguments
) ELSE (
    echo off 
)

有时我需要提取几个命令行参数，但不是全部，而不是从第一个中提取。让我们假设以下调用：

Test.bat uno dos tres cuatro cinco seis siete

当然，至少在同一文件夹中有test.exe时，不需要扩展名“ .bat”。我们想要的是获得输出“ tres cuatro cinco”（无论是一行还是三行）。目标是只有我需要三个参数，并且从第三个参数开始。为了有一个简单的例子，每个动作都只是“回声”，但是您可以考虑对所选参数进行其他更复杂的动作。

我提供了一些示例（选项），以便您可以查看哪个更适合您。不幸的是，在诸如“（％3，1，％5）中的%% i”之类的范围内，没有一种基于for循环的好方法（或者我不知道）。

@echo off 
setlocal EnableDelayedExpansion

echo Option 1: one by one (same line)
echo %3, %4, %5
echo.

echo Option 2: Loop For one by one
for %%a in (%3, %4, %5) do echo %%a
echo.

echo Option 3: Loop For with check of limits
set i=0
for %%a in (%*) do (
    set /A i=i+1
    If !i! GTR 2 if !i! LSS 6 echo %%a
)
echo.

echo Option 4: Loop For with auxiliary list
for /l %%i in (3,1,5) do  (
    set a=%%i
    set b=echo %%
    set b=!b!!a!
    call !b!
)
echo.

echo Option 5: Assigning to an array of elements previously
set e[0]=%0
set i=0 
for %%a in (%*) do (
    set /A i=i+1
    set e[!i!]=%%a
)
for  /l %%i in (3,1,5) do (
    echo !e[%%i]!
)
echo.

echo Option 6: using shift and goto loop. It doesn't work with for loop
set i=2
:loop6
    set /A i=i+1
    echo %3
    shift
    If %i% LSS 5 goto :loop6

可能您可以找到更多选项或将多个选项组合在一起。享用它们。

Windows版本（虽然需要socat）

C:\Program Files (x86)\Git\bin>type gitproxy.cmd
socat STDIO PROXY:proxy.mycompany.de:%1:%2,proxyport=3128

设置：

C:\Users\exhau\AppData\Roaming\npm>git config --global core.gitproxy gitproxy.cmd