您已经在按钮上添加了一个按钮，DataGridView并且希望在单击该按钮时运行一些代码。
简单轻松-只需按照以下步骤操作：
不要：
首先，这是不可以做的事情：
我会避免这里的其他答案中的建议，甚至会避免MSDN文档提供的建议来对列索引或列名进行硬编码，以确定是否单击了按钮。click事件会在整个网格中注册，因此您需要以某种方式确定按钮是否已单击，但不应通过假设按钮位于特定的列名或索引中来进行此操作……这是一种更简单的方法……
另外，请注意要处理的事件。同样，文档和许多示例也弄错了这一点。大多数示例处理CellClick将触发的事件：
单击单元格的任何部分时。
...但是每当单击行标题时也会触发。这就需要添加额外的代码来简单地确定该e.RowIndex值是否小于0
而是处理CellContentClick仅发生的：
单击单元格中的内容时
无论出于何种原因，列标题也被视为单元格中的“内容”，因此我们仍然必须在下面进行检查。
剂量：
所以这是你应该做的：
首先，将发送方强制转换为类型DataGridView以在设计时公开其内部属性。您可以修改参数的类型，但这有时会使添加或删除处理程序变得棘手。
接下来，要查看是否单击了按钮，只需检查以确保引发事件的列的类型DataGridViewButtonColumn。因为我们已经将发送方强制转换为类型DataGridView，所以我们可以获取Columns集合并使用选择当前列e.ColumnIndex。然后检查该对象是否为类型DataGridViewButtonColumn。
当然，如果需要区分每个网格的多个按钮，则可以基于列名称或索引进行选择，但这不应该是您的第一眼检查。始终确保先单击一个按钮，然后再适当处理其他任何事情。在大多数情况下，每个网格只有一个按钮，您可以直接跳到比赛中。
放在一起：
C＃：
private void dataGridView1_CellContentClick(object sender, DataGridViewCellEventArgs e)
{
var senderGrid = (DataGridView)sender;
if (senderGrid.Columns[e.ColumnIndex] is DataGridViewButtonColumn &&
e.RowIndex >= 0)
{
//TODO - Button Clicked - Execute Code Here
}
}
VB：
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso
e.RowIndex >= 0 Then
'TODO - Button Clicked - Execute Code Here
End If
End Sub
更新1-自定义事件
如果您想找点乐子，则可以添加自己的事件，只要在DataGrid上单击一个按钮即可。您不能将其添加到DataGrid本身，而不会弄乱继承等，但是您可以在表单中添加自定义事件，并在适当时触发它。还有更多代码，但是好处是，您已经分离出单击按钮时要执行的操作以及如何确定是否单击了按钮。
只需声明一个事件，在适当的时候引发它，然后处理它即可。它看起来像这样：
Event DataGridView1ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub DataGridView1_CellContentClick(sender As System.Object, e As DataGridViewCellEventArgs) Handles DataGridView1.CellContentClick
Dim senderGrid = DirectCast(sender, DataGridView)
If TypeOf senderGrid.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent DataGridView1ButtonClick(senderGrid, e)
End If
End Sub
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) Handles Me.DataGridView1ButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
更新2-扩展网格
最好的是，如果我们正在与一个为我们做这些事情的网格一起工作。我们可以轻松回答最初的问题：you've added a button to your DataGridView and you want to run some code when it's clicked。这是扩展的方法DataGridView。不必为每个库都提供自定义控件而麻烦，但是至少它最大程度地重用了用于确定是否单击按钮的代码。
只需将其添加到您的程序集中：
Public Class DataGridViewExt : Inherits DataGridView
Event CellButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs)
Private Sub CellContentClicked(sender As System.Object, e As DataGridViewCellEventArgs) Handles Me.CellContentClick
If TypeOf Me.Columns(e.ColumnIndex) Is DataGridViewButtonColumn AndAlso e.RowIndex >= 0 Then
RaiseEvent CellButtonClick(Me, e)
End If
End Sub
End Class
而已。永远不要再碰它。确保您的DataGrid的类型DataGridViewExt应与DataGridView完全相同。除了会引发一个额外的事件，您可以像这样处理：
Private Sub DataGridView1_ButtonClick(sender As DataGridView, e As DataGridViewCellEventArgs) _
Handles DataGridView1.CellButtonClick
'TODO - Button Clicked - Execute Code Here
End Sub
