使用XSLT将XML转换为CSV

75

我有以下XML文档：

<projects>
  <project>
   <name>Shockwave</name> 
   <language>Ruby</language> 
   <owner>Brian May</owner> 
   <state>New</state> 
   <startDate>31/10/2008 0:00:00</startDate> 
  </project>
  <project>
   <name>Other</name> 
   <language>Erlang</language> 
   <owner>Takashi Miike</owner> 
   <state> Canceled </state> 
   <startDate>07/11/2008 0:00:00</startDate> 
  </project>
...

我想从转换（XSLT）结果中获得以下信息：

Shockwave,Ruby,Brian May,New,31/10/2008 0:00:00
Other,Erlang,Takashi Miike,Cancelled,07/11/2008 0:00:00

有人知道XSLT可以实现吗？我正在使用.net以防万一。

xml  xslt  csv 
— 帕勃罗·费尔南德斯（Pablo Fernandez）
source
.NET仅在使用仅支持xslt 1.0的XslTransform类时才重要。这是一个约束吗？如果是这样，应将其重新标记为xslt-1.0。
— 瑞安·盖茨
一个好的答案在这里也给了类似的问题，如果你使用Linux askubuntu.com/questions/174143/...
— 伦纳德Saers
有工具xml2csv。也许这对您也有用吗？
— koppor
xml2csv对我有用。我发现文档已损坏，但是花了一些时间来记录解决方法，该方法为我产生了可用的结果，请访问： github.com/fordfrog/xml2csv/issues/5#issuecomment-726542532
— Hugh Esco

Answers:

47

在此处找到了XML转换样式表（回溯机器链接，站点本身是德语的）

此处添加的样式表可能会有所帮助：

<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="text" encoding="iso-8859-1"/>

<xsl:strip-space elements="*" />

<xsl:template match="/*/child::*">
<xsl:for-each select="child::*">
<xsl:if test="position() != last()">"<xsl:value-of select="normalize-space(.)"/>",    </xsl:if>
<xsl:if test="position()  = last()">"<xsl:value-of select="normalize-space(.)"/>"<xsl:text>&#xD;</xsl:text>
</xsl:if>
</xsl:for-each>
</xsl:template>

</xsl:stylesheet>

也许您想删除xsl：if标记内的引号，以便它不会将值放入引号中，具体取决于您要在何处使用CSV文件。

— 施纳德
source
5
请注意，如果原始数据中有逗号，则不会将其转义。您可能要添加一个包含contains（）的测试，以及一个包含translate（）的转义符。
— bortzmeyer
2
我认为这不会处理数据中的双引号。要转义双引号，必须用两个双引号代替它。
— Sarel Botha 2010年
1
通常，如果一个值包含以下任意一项，则只需要用引号引起来：定界符（' ,'），引号（' "'），换行符（&#xD;）。如果需要引号，则必须先将所有内引号加倍（' ""'）。
— mousio 2011年
2
Unix上正确的换行是&#10;（\ n）。&#xD;是十六进制\ r
— igo 2014年
1
@ BotMaster3000：谢谢，取而代之的是
— 回程
57

这是带有可配置参数的版本，您可以通过编程方式进行设置：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text" encoding="utf-8" />

  <xsl:param name="delim" select="','" />
  <xsl:param name="quote" select="'&quot;'" />
  <xsl:param name="break" select="'&#xA;'" />

  <xsl:template match="/">
    <xsl:apply-templates select="projects/project" />
  </xsl:template>

  <xsl:template match="project">
    <xsl:apply-templates />
    <xsl:if test="following-sibling::*">
      <xsl:value-of select="$break" />
    </xsl:if>
  </xsl:template>

  <xsl:template match="*">
    <!-- remove normalize-space() if you want keep white-space at it is --> 
    <xsl:value-of select="concat($quote, normalize-space(), $quote)" />
    <xsl:if test="following-sibling::*">
      <xsl:value-of select="$delim" />
    </xsl:if>
  </xsl:template>

  <xsl:template match="text()" />
</xsl:stylesheet>
— 托玛拉克
source
1
我喜欢强制性报价。至少在导入Excel时，它会处理原始数据中有$ delim的情况。
— bortzmeyer
如果我们还想包括列名，该怎么办？
— 阿莫尔·哈立德
1
@omer有两种方法可以执行此操作，具体取决于您的XML。最好是问一个新问题，因为评论部分不是讨论此类问题的好地方，并且因为在该线程中它不是问题的一部分，所以我不会编辑答案。
— Tomalak
19

这xsl:stylesheet可以使用指定的列标题列表，并确保正确排列行。

<?xml version="1.0"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:csv="csv:csv">
    <xsl:output method="text" encoding="utf-8" />
    <xsl:strip-space elements="*" />

    <xsl:variable name="delimiter" select="','" />

    <csv:columns>
        <column>name</column>
        <column>sublease</column>
        <column>addressBookID</column>
        <column>boundAmount</column>
        <column>rentalAmount</column>
        <column>rentalPeriod</column>
        <column>rentalBillingCycle</column>
        <column>tenureIncome</column>
        <column>tenureBalance</column>
        <column>totalIncome</column>
        <column>balance</column>
        <column>available</column>
    </csv:columns>

    <xsl:template match="/property-manager/properties">
        <!-- Output the CSV header -->
        <xsl:for-each select="document('')/*/csv:columns/*">
                <xsl:value-of select="."/>
                <xsl:if test="position() != last()">
                    <xsl:value-of select="$delimiter"/>
                </xsl:if>
        </xsl:for-each>
        <xsl:text>&#xa;</xsl:text>

        <!-- Output rows for each matched property -->
        <xsl:apply-templates select="property" />
    </xsl:template>

    <xsl:template match="property">
        <xsl:variable name="property" select="." />

        <!-- Loop through the columns in order -->
        <xsl:for-each select="document('')/*/csv:columns/*">
            <!-- Extract the column name and value -->
            <xsl:variable name="column" select="." />
            <xsl:variable name="value" select="$property/*[name() = $column]" />

            <!-- Quote the value if required -->
            <xsl:choose>
                <xsl:when test="contains($value, '&quot;')">
                    <xsl:variable name="x" select="replace($value, '&quot;',  '&quot;&quot;')"/>
                    <xsl:value-of select="concat('&quot;', $x, '&quot;')"/>
                </xsl:when>
                <xsl:when test="contains($value, $delimiter)">
                    <xsl:value-of select="concat('&quot;', $value, '&quot;')"/>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:value-of select="$value"/>
                </xsl:otherwise>
            </xsl:choose>

            <!-- Add the delimiter unless we are the last expression -->
            <xsl:if test="position() != last()">
                <xsl:value-of select="$delimiter"/>
            </xsl:if>
        </xsl:for-each>

        <!-- Add a newline at the end of the record -->
        <xsl:text>&#xa;</xsl:text>
    </xsl:template>

</xsl:stylesheet>
— 碘喹
source
2
很好，但是不起作用。replace()是XPath 2.0函数。在XSLT 1.0中，您必须使用递归字符串替换模板。
— Tomalak
1
使用xsltproc / libxslt为我工作-足够好。不过，感谢您指出要求。
— ioquatix 2012年
@ hd1，我仍在生产中使用此脚本，所以可能您在做错什么？
— ioquatix 2014年
@MrSamuel很有可能，毕竟我是SO上最大的傻瓜
— hd1 2014年
2
根本没有使用xsl，而是决定使用SAX
— hd1 2014年
2

这个CsvEscape功能是XSLT 1.0和逸出列值,，"和换行等RFC 4180或Excel。它利用了您可以递归调用XSLT模板的事实：

  • 该模板EscapeQuotes从字符串的开头递归地用2个双引号替换所有双引号。
  • 模板CsvEscape检查文本是否包含逗号或双引号，如果包含，则用双引号将整个字符串括起来并调用EscapeQuotes该字符串。

用法示例： xsltproc xmltocsv.xslt file.xml > file.csv

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="text" encoding="UTF-8"/>

  <xsl:template name="EscapeQuotes">
    <xsl:param name="value"/>
    <xsl:choose>
      <xsl:when test="contains($value,'&quot;')">
    <xsl:value-of select="substring-before($value,'&quot;')"/>
    <xsl:text>&quot;&quot;</xsl:text>
    <xsl:call-template name="EscapeQuotes">
      <xsl:with-param name="value" select="substring-after($value,'&quot;')"/>
    </xsl:call-template>
      </xsl:when>
      <xsl:otherwise>
    <xsl:value-of select="$value"/>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template name="CsvEscape">
    <xsl:param name="value"/>
    <xsl:choose>
    <xsl:when test="contains($value,',')">
      <xsl:text>&quot;</xsl:text>
      <xsl:call-template name="EscapeQuotes">
    <xsl:with-param name="value" select="$value"/>
      </xsl:call-template>
      <xsl:text>&quot;</xsl:text>
    </xsl:when>
    <xsl:when test="contains($value,'&#xA;')">
      <xsl:text>&quot;</xsl:text>
      <xsl:call-template name="EscapeQuotes">
    <xsl:with-param name="value" select="$value"/>
      </xsl:call-template>
      <xsl:text>&quot;</xsl:text>
    </xsl:when>
    <xsl:when test="contains($value,'&quot;')">
      <xsl:text>&quot;</xsl:text>
      <xsl:call-template name="EscapeQuotes">
    <xsl:with-param name="value" select="$value"/>
      </xsl:call-template>
      <xsl:text>&quot;</xsl:text>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$value"/>
    </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

  <xsl:template match="/">
    <xsl:text>project,name,language,owner,state,startDate</xsl:text>
    <xsl:text>&#xA;</xsl:text>
    <xsl:for-each select="projects/project">
      <xsl:call-template name="CsvEscape"><xsl:with-param name="value" select="normalize-space(name)"/></xsl:call-template>
      <xsl:text>,</xsl:text>
      <xsl:call-template name="CsvEscape"><xsl:with-param name="value" select="normalize-space(language)"/></xsl:call-template>
      <xsl:text>,</xsl:text>
      <xsl:call-template name="CsvEscape"><xsl:with-param name="value" select="normalize-space(owner)"/></xsl:call-template>
      <xsl:text>,</xsl:text>
      <xsl:call-template name="CsvEscape"><xsl:with-param name="value" select="normalize-space(state)"/></xsl:call-template>
      <xsl:text>,</xsl:text>
      <xsl:call-template name="CsvEscape"><xsl:with-param name="value" select="normalize-space(startDate)"/></xsl:call-template>
      <xsl:text>&#xA;</xsl:text>
    </xsl:for-each>
  </xsl:template>
</xsl:stylesheet>
— 杰米塞雷斯
source
By using our site, you acknowledge that you have read and understand our Cookie Policy and Privacy Policy.
Licensed under cc by-sa 3.0 with attribution required.