获取目录中所有文件的列表（递归）

我正在尝试获取（不打印，这很容易）目录及其子目录中的文件列表。

我试过了：

def folder = "C:\\DevEnv\\Projects\\Generic";
def baseDir = new File(folder);
files = baseDir.listFiles();

我只得到目录。我也尝试过：

def files = [];

def processFileClosure = {
        println "working on ${it.canonicalPath}: "
        files.add (it.canonicalPath);
    }

baseDir.eachFileRecurse(FileType.FILES, processFileClosure);

但是“文件”在闭包范围内不被识别。

如何获得清单？

该代码对我有用：

import groovy.io.FileType

def list = []

def dir = new File("path_to_parent_dir")
dir.eachFileRecurse (FileType.FILES) { file ->
  list << file
}

然后，列表变量包含给定目录及其子目录的所有文件（java.io.File）：

list.each {
  println it.path
}

较新版本的Groovy（1.7.2+）提供了JDK扩展，可以更轻松地遍历目录中的文件，例如：

import static groovy.io.FileType.FILES
def dir = new File(".");
def files = [];
dir.traverse(type: FILES, maxDepth: 0) { files.add(it) };

有关更多示例，请参见[1]。

[1] http://mrhaki.blogspot.nl/2010/04/groovy-goodness-traversing-directory.html

以下内容适用于build.gradleAndroid项目的Gradle / Groovy中的我，而无需导入groovy.io.FileType（注意：不递归子目录，但是当我找到此解决方案时，我不再关心递归，因此您可能也不愿意）：

FileCollection proGuardFileCollection = files { file('./proguard').listFiles() }
proGuardFileCollection.each {
    println "Proguard file located and processed: " + it
}

这是我为gradle构建脚本想到的：

task doLast {
    ext.FindFile = { list, curPath ->
        def files = file(curPath).listFiles().sort()

        files.each {  File file ->

            if (file.isFile()) {
                list << file
            }
            else {
                list << file  // If you want the directories in the list

                list = FindFile( list, file.path) 
            }
        }
        return list
    }

    def list = []
    def theFile = FindFile(list, "${project.projectDir}")

    list.each {
        println it.path
    }
}