用vim中的空格替换制表符

我想将制表符转换为gVim中的空格。我将以下行添加到我的_vimrc：

set tabstop=2

它可以在两个空格处停下来，但看起来仍然插入了一个制表键（我试图在以后使用h键来计算空格）。

我不确定如何使gVim将制表符转换为空格？

IIRC，类似：

set tabstop=2 shiftwidth=2 expandtab

应该可以。如果您已经有了制表符，请在其后添加一个不错的全局RE，以将其替换为双空格。

按照其他答案展开扩展标签后，根据新设置转换现有文件的极为便捷的方法是：

:retab

它将在当前缓冲区上工作。

尝试

set expandtab

用于软标签。

修复现有标签：

:%s/\t/  /g

因为您已经将Tabstop设置为2个空格，所以我使用了两个空格。

这为我工作：

您可以先查看以下标签：

:set list

然后使替换标签成为可能，然后执行以下操作：

:set expandtab

然后

:retab

现在，所有标签页都已替换为空格，然后您可以返回正常查看状态，如下所示：

:set nolist

gg=G 会重新缩进整个文件，并删除我从同事那里获得的大多数（如果不是全部）选项卡。

在.vimrc中添加以下行

set expandtab
set tabstop=4
set shiftwidth=4
map <F2> :retab <CR> :wq! <CR>

在vim中打开文件，然后按F2键。选项卡将转换为4个空格，并且文件将自动保存。

如果要保持\t等于8个空格，请考虑设置：

   set softtabstop=2 tabstop=8 shiftwidth=2

每<TAB>按一次将为您提供两个空格，但是\t在您的代码中实际仍将被视为8个字符。

这对我有用：

:set tabstop=2 shiftwidth=2 expandtab | retab

首先在文件中搜索选项卡：/ ^ I：set expandtab：retab

将工作。

本文有一个出色的vimrc脚本，用于处理制表符和空格，并在它们之间进行转换。

提供以下命令：

Space2Tab仅 将空格转换为制表符。

Tab2Space 将制表符转换为空格，仅以缩进形式。

RetabIndent 执行Space2Tab（如果设置了'expandtab'）或Tab2Space（否则）。

每个命令都接受一个参数，该参数指定选项卡列中的空格数。默认情况下，使用“ tabstop”设置。

资料来源：http : //vim.wikia.com/wiki/Super_retab#Script

" Return indent (all whitespace at start of a line), converted from
" tabs to spaces if what = 1, or from spaces to tabs otherwise.
" When converting to tabs, result has no redundant spaces.
function! Indenting(indent, what, cols)
  let spccol = repeat(' ', a:cols)
  let result = substitute(a:indent, spccol, '\t', 'g')
  let result = substitute(result, ' \+\ze\t', '', 'g')
  if a:what == 1
    let result = substitute(result, '\t', spccol, 'g')
  endif
  return result
endfunction

" Convert whitespace used for indenting (before first non-whitespace).
" what = 0 (convert spaces to tabs), or 1 (convert tabs to spaces).
" cols = string with number of columns per tab, or empty to use 'tabstop'.
" The cursor position is restored, but the cursor will be in a different
" column when the number of characters in the indent of the line is changed.
function! IndentConvert(line1, line2, what, cols)
  let savepos = getpos('.')
  let cols = empty(a:cols) ? &tabstop : a:cols
  execute a:line1 . ',' . a:line2 . 's/^\s\+/\=Indenting(submatch(0), a:what, cols)/e'
  call histdel('search', -1)
  call setpos('.', savepos)
endfunction

command! -nargs=? -range=% Space2Tab call IndentConvert(<line1>,<line2>,0,<q-args>)
command! -nargs=? -range=% Tab2Space call IndentConvert(<line1>,<line2>,1,<q-args>)
command! -nargs=? -range=% RetabIndent call IndentConvert(<line1>,<line2>,&et,<q-args>)

这比我初次寻找解决方案时的回答对我有所帮助。

expand是用于将制表符转换为空格的Unix实用程序。如果您不想set在vim中执行任何操作，则可以使用vim中的shell命令：

:!% expand -t8