Vim：在保存时创建父目录

如果我调用vim foo/bar/somefile但foo/bar尚不存在，Vim拒绝保存。

我知道我可以切换到shell或:!mkdir foo/bar从Vim进行操作，但是我很懒：)有没有办法让Vim在保存缓冲区时自动执行此操作？

augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * if expand("<afile>")!~#'^\w\+:/' && !isdirectory(expand("%:h")) | execute "silent! !mkdir -p ".shellescape(expand('%:h'), 1) | redraw! | endif
augroup END

注意以下情况：expand("<afile>")!~#'^\w\+:/'将防止vim为类似文件创建目录，ftp://*并!isdirectory防止昂贵的mkdir调用。

更新：更好的解决方案，它还会检查非空buftype并使用mkdir()：

function s:MkNonExDir(file, buf)
    if empty(getbufvar(a:buf, '&buftype')) && a:file!~#'\v^\w+\:\/'
        let dir=fnamemodify(a:file, ':h')
        if !isdirectory(dir)
            call mkdir(dir, 'p')
        endif
    endif
endfunction
augroup BWCCreateDir
    autocmd!
    autocmd BufWritePre * :call s:MkNonExDir(expand('<afile>'), +expand('<abuf>'))
augroup END

根据对我的问题的建议，以下是我得出的结论：

function WriteCreatingDirs()
    execute ':silent !mkdir -p %:h'
    write
endfunction
command W call WriteCreatingDirs()

这定义了:W命令。理想情况下，我想有所有的:w!，:wq，:wq!，:wall等工作相同，但我不知道是否有可能基本上没有重新实现他们所有的自定义功能。

我将此添加到我的〜/ .vimrc

cnoremap mk. !mkdir -p <c-r>=expand("%:h")<cr>/

如果需要创建目录，请输入，:mk.并将其替换为“！mkdir -p / path / to / my / file /”，并允许我在调用该命令之前先对其进行检查。

:saveas!如果丢失，我创建了目录：https : //github.com/henrik/dotfiles/commit/54cc9474b345332cf54cf25b51ddb8a9bd00a0bb

此代码将提示您使用创建目录:w，或仅使用:w!以下命令创建目录：

augroup vimrc-auto-mkdir
  autocmd!
  autocmd BufWritePre * call s:auto_mkdir(expand('<afile>:p:h'), v:cmdbang)
  function! s:auto_mkdir(dir, force)
    if !isdirectory(a:dir)
          \   && (a:force
          \       || input("'" . a:dir . "' does not exist. Create? [y/N]") =~? '^y\%[es]$')
      call mkdir(iconv(a:dir, &encoding, &termencoding), 'p')
    endif
  endfunction
augroup END

我认为我成功地做到了三行，结合了其他人对此答案的看法。

这似乎可以解决问题：

if has("autocmd")
  autocmd BufWritePre * :silent !mkdir -p %:p:h
end

保存缓冲区时，它将尝试自动创建文件夹。如果发生任何不良情况（即权限问题），它将关闭并让文件写入失败。

如果有人发现任何明显的缺陷，请发表评论。我对vimscript不太了解。

编辑：感谢ZyX

• 如果您的文件夹上有空格（显然它们没有正确转义或其他原因），则此功能将不起作用
• 或者，如果您正在处理伪文件。
• 或者，如果您正在采购vimrc。
• 但是儿子，很短。