如何在向量中找到项目的索引？

任何想法????应该是什么？有内置的吗？完成这项任务的最佳方法是什么？

(def v ["one" "two" "three" "two"])

(defn find-thing [ thing vectr ]
  (????))

(find-thing "two" v) ; ? maybe 1, maybe '(1,3), actually probably a lazy-seq

内建：

user> (def v ["one" "two" "three" "two"])
#'user/v
user> (.indexOf v "two")
1
user> (.indexOf v "foo")
-1

如果您想要所有匹配项的索引的延迟序列：

user> (map-indexed vector v)
([0 "one"] [1 "two"] [2 "three"] [3 "two"])
user> (filter #(= "two" (second %)) *1)
([1 "two"] [3 "two"])
user> (map first *1)
(1 3)
user> (map first 
           (filter #(= (second %) "two")
                   (map-indexed vector v)))
(1 3)

这篇文章http://www.mail-archive.com/clojure@googlegroups.com/msg34159.html的Stuart Halloway给出了一个非常好的答案。

(use '[clojure.contrib.seq :only (positions)])
(def v ["one" "two" "three" "two"])
(positions #{"two"} v) ; -> (1 3)

如果您想获取第一个值，请使用first结果。

(first (positions #{"two"} v)) ; -> 1

编辑：因为clojure.contrib.seq消失了，所以我用一个简单的实现示例更新了答案：

(defn positions
  [pred coll]
  (keep-indexed (fn [idx x]
                  (when (pred x)
                    idx))
                coll))

(defn find-thing [needle haystack]
  (keep-indexed #(when (= %2 needle) %1) haystack))

但是我要警告您不要摆弄索引：大多数情况下，它会减少惯用的，笨拙的Clojure。

从Clojure 1.4开始，clojure.contrib.seq（以及该positions函数）由于缺少维护者而无法使用：http : //dev.clojure.org/display/design/Where+Did+Clojure.Contrib+Go

的来源clojure.contrib.seq/positions及其依赖性clojure.contrib.seq/indexed是：

(defn indexed
  "Returns a lazy sequence of [index, item] pairs, where items come
  from 's' and indexes count up from zero.

  (indexed '(a b c d))  =>  ([0 a] [1 b] [2 c] [3 d])"
  [s]
  (map vector (iterate inc 0) s))

(defn positions
  "Returns a lazy sequence containing the positions at which pred
   is true for items in coll."
  [pred coll]
  (for [[idx elt] (indexed coll) :when (pred elt)] idx))

(positions #{2} [1 2 3 4 1 2 3 4]) => (1 5)

可在此处获得：http : //clojuredocs.org/clojure_contrib/clojure.contrib.seq/positions

我试图回答自己的问题，但是Brian为我打了一个更好的答案！

(defn indices-of [f coll]
  (keep-indexed #(if (f %2) %1 nil) coll))

(defn first-index-of [f coll]
  (first (indices-of f coll)))

(defn find-thing [value coll]
  (first-index-of #(= % value) coll))

(find-thing "two" ["one" "two" "three" "two"]) ; 1
(find-thing "two" '("one" "two" "three")) ; 1

;; these answers are a bit silly
(find-thing "two" #{"one" "two" "three"}) ; 1
(find-thing "two" {"one" "two" "two" "three"}) ; nil

这是我的贡献，使用looping结构并nil在失败时返回。

我会尽量避免循环，但似乎很适合这个问题。

(defn index-of [xs x]
  (loop [a (first xs)
         r (rest xs)
         i 0]
    (cond
      (= a x)    i
      (empty? r) nil
      :else      (recur (first r) (rest r) (inc i)))))

最近，我不得不多次查找索引，或者选择了索引，因为它比找出另一种解决问题的方法容易。一路上，我发现我的Clojure列表没有.indexOf（Object object，int start）方法。我这样处理这个问题：

(defn index-of
"Returns the index of item. If start is given indexes prior to
 start are skipped."
([coll item] (.indexOf coll item))
([coll item start]
  (let [unadjusted-index (.indexOf (drop start coll) item)]
    (if (= -1 unadjusted-index)
  unadjusted-index
  (+ unadjusted-index start)))))

我会用reduce-kv

(defn find-index [pred vec]
  (reduce-kv
    (fn [_ k v]
      (if (pred v)
        (reduced k)))
    nil
    vec))