我对T-SQL中计算Levenshtein距离的算法感兴趣。
我对T-SQL中计算Levenshtein距离的算法感兴趣。
Answers:
我在TSQL中实现了标准的Levenshtein编辑距离功能，并进行了一些优化，这些速度可以提高我所知道的其他版本的速度。如果两个字符串的开头（共享前缀）具有共同字符，结尾两个字符（共享后缀），并且字符串较大且提供了最大编辑距离时，则速度会显着提高。例如，当输入是两个非常相似的4000个字符串，并且指定的最大编辑距离为2时，这比输入距离快了三个数量级。edit_distance_within函数接受的答案中，返回答案的时间为0.073秒（73毫秒）和55秒。它的存储效率也很高，使用等于两个输入字符串中较大者的空间加上一些恒定空间。它使用一个表示列的单个nvarchar“数组”，并在其中进行所有计算以及一些辅助int变量。
优化：
这是代码（2014年1月20日更新，以加快速度）：
-- =============================================
-- Computes and returns the Levenshtein edit distance between two strings, i.e. the
-- number of insertion, deletion, and sustitution edits required to transform one
-- string to the other, or NULL if @max is exceeded. Comparisons use the case-
-- sensitivity configured in SQL Server (case-insensitive by default).
--
-- Based on Sten Hjelmqvist's "Fast, memory efficient" algorithm, described
-- at http://www.codeproject.com/Articles/13525/Fast-memory-efficient-Levenshtein-algorithm,
-- with some additional optimizations.
-- =============================================
CREATE FUNCTION [dbo].[Levenshtein](
@s nvarchar(4000)
, @t nvarchar(4000)
, @max int
)
RETURNS int
WITH SCHEMABINDING
AS
BEGIN
DECLARE @distance int = 0 -- return variable
, @v0 nvarchar(4000)-- running scratchpad for storing computed distances
, @start int = 1 -- index (1 based) of first non-matching character between the two string
, @i int, @j int -- loop counters: i for s string and j for t string
, @diag int -- distance in cell diagonally above and left if we were using an m by n matrix
, @left int -- distance in cell to the left if we were using an m by n matrix
, @sChar nchar -- character at index i from s string
, @thisJ int -- temporary storage of @j to allow SELECT combining
, @jOffset int -- offset used to calculate starting value for j loop
, @jEnd int -- ending value for j loop (stopping point for processing a column)
-- get input string lengths including any trailing spaces (which SQL Server would otherwise ignore)
, @sLen int = datalength(@s) / datalength(left(left(@s, 1) + '.', 1)) -- length of smaller string
, @tLen int = datalength(@t) / datalength(left(left(@t, 1) + '.', 1)) -- length of larger string
, @lenDiff int -- difference in length between the two strings
-- if strings of different lengths, ensure shorter string is in s. This can result in a little
-- faster speed by spending more time spinning just the inner loop during the main processing.
IF (@sLen > @tLen) BEGIN
SELECT @v0 = @s, @i = @sLen -- temporarily use v0 for swap
SELECT @s = @t, @sLen = @tLen
SELECT @t = @v0, @tLen = @i
END
SELECT @max = ISNULL(@max, @tLen)
, @lenDiff = @tLen - @sLen
IF @lenDiff > @max RETURN NULL
-- suffix common to both strings can be ignored
WHILE(@sLen > 0 AND SUBSTRING(@s, @sLen, 1) = SUBSTRING(@t, @tLen, 1))
SELECT @sLen = @sLen - 1, @tLen = @tLen - 1
IF (@sLen = 0) RETURN @tLen
-- prefix common to both strings can be ignored
WHILE (@start < @sLen AND SUBSTRING(@s, @start, 1) = SUBSTRING(@t, @start, 1))
SELECT @start = @start + 1
IF (@start > 1) BEGIN
SELECT @sLen = @sLen - (@start - 1)
, @tLen = @tLen - (@start - 1)
-- if all of shorter string matches prefix and/or suffix of longer string, then
-- edit distance is just the delete of additional characters present in longer string
IF (@sLen <= 0) RETURN @tLen
SELECT @s = SUBSTRING(@s, @start, @sLen)
, @t = SUBSTRING(@t, @start, @tLen)
END
-- initialize v0 array of distances
SELECT @v0 = '', @j = 1
WHILE (@j <= @tLen) BEGIN
SELECT @v0 = @v0 + NCHAR(CASE WHEN @j > @max THEN @max ELSE @j END)
SELECT @j = @j + 1
END
SELECT @jOffset = @max - @lenDiff
, @i = 1
WHILE (@i <= @sLen) BEGIN
SELECT @distance = @i
, @diag = @i - 1
, @sChar = SUBSTRING(@s, @i, 1)
-- no need to look beyond window of upper left diagonal (@i) + @max cells
-- and the lower right diagonal (@i - @lenDiff) - @max cells
, @j = CASE WHEN @i <= @jOffset THEN 1 ELSE @i - @jOffset END
, @jEnd = CASE WHEN @i + @max >= @tLen THEN @tLen ELSE @i + @max END
WHILE (@j <= @jEnd) BEGIN
-- at this point, @distance holds the previous value (the cell above if we were using an m by n matrix)
SELECT @left = UNICODE(SUBSTRING(@v0, @j, 1))
, @thisJ = @j
SELECT @distance =
CASE WHEN (@sChar = SUBSTRING(@t, @j, 1)) THEN @diag --match, no change
ELSE 1 + CASE WHEN @diag < @left AND @diag < @distance THEN @diag --substitution
WHEN @left < @distance THEN @left -- insertion
ELSE @distance -- deletion
END END
SELECT @v0 = STUFF(@v0, @thisJ, 1, NCHAR(@distance))
, @diag = @left
, @j = case when (@distance > @max) AND (@thisJ = @i + @lenDiff) then @jEnd + 2 else @thisJ + 1 end
END
SELECT @i = CASE WHEN @j > @jEnd + 1 THEN @sLen + 1 ELSE @i + 1 END
END
RETURN CASE WHEN @distance <= @max THEN @distance ELSE NULL END
END
如该函数的注释中所述，字符比较的大小写敏感性将遵循有效的排序规则。默认情况下，SQL Server的排序规则将导致不区分大小写的比较。修改此功能使其始终区分大小写的一种方法是将特定的排序规则添加到比较字符串的两个位置。但是，我还没有对此进行彻底的测试，尤其是在数据库使用非默认排序规则时的副作用方面。以下是更改这两行以强制区分大小写的比较的方式：
-- prefix common to both strings can be ignored
WHILE (@start < @sLen AND SUBSTRING(@s, @start, 1) = SUBSTRING(@t, @start, 1) COLLATE SQL_Latin1_General_Cp1_CS_AS)
和
SELECT @distance =
CASE WHEN (@sChar = SUBSTRING(@t, @j, 1) COLLATE SQL_Latin1_General_Cp1_CS_AS) THEN @diag --match, no change
阿诺德Fribble对两个提案sqlteam.com/forums
这是2006年以来的更年轻的：
SET QUOTED_IDENTIFIER ON
GO
SET ANSI_NULLS ON
GO
CREATE FUNCTION edit_distance_within(@s nvarchar(4000), @t nvarchar(4000), @d int)
RETURNS int
AS
BEGIN
DECLARE @sl int, @tl int, @i int, @j int, @sc nchar, @c int, @c1 int,
@cv0 nvarchar(4000), @cv1 nvarchar(4000), @cmin int
SELECT @sl = LEN(@s), @tl = LEN(@t), @cv1 = '', @j = 1, @i = 1, @c = 0
WHILE @j <= @tl
SELECT @cv1 = @cv1 + NCHAR(@j), @j = @j + 1
WHILE @i <= @sl
BEGIN
SELECT @sc = SUBSTRING(@s, @i, 1), @c1 = @i, @c = @i, @cv0 = '', @j = 1, @cmin = 4000
WHILE @j <= @tl
BEGIN
SET @c = @c + 1
SET @c1 = @c1 - CASE WHEN @sc = SUBSTRING(@t, @j, 1) THEN 1 ELSE 0 END
IF @c > @c1 SET @c = @c1
SET @c1 = UNICODE(SUBSTRING(@cv1, @j, 1)) + 1
IF @c > @c1 SET @c = @c1
IF @c < @cmin SET @cmin = @c
SELECT @cv0 = @cv0 + NCHAR(@c), @j = @j + 1
END
IF @cmin > @d BREAK
SELECT @cv1 = @cv0, @i = @i + 1
END
RETURN CASE WHEN @cmin <= @d AND @c <= @d THEN @c ELSE -1 END
END
GO
IIRC，在SQL Server 2005和更高版本中，您可以使用任何.NET语言编写存储过程：在SQL Server 2005中使用CLR集成。这样就可以编写一个计算Levenstein距离的程序了。
一个简单的Hello，World！从帮助中提取：
using System;
using System.Data;
using Microsoft.SqlServer.Server;
using System.Data.SqlTypes;
public class HelloWorldProc
{
[Microsoft.SqlServer.Server.SqlProcedure]
public static void HelloWorld(out string text)
{
SqlContext.Pipe.Send("Hello world!" + Environment.NewLine);
text = "Hello world!";
}
}
然后在您的SQL Server中运行以下命令：
CREATE ASSEMBLY helloworld from 'c:\helloworld.dll' WITH PERMISSION_SET = SAFE
CREATE PROCEDURE hello
@i nchar(25) OUTPUT
AS
EXTERNAL NAME helloworld.HelloWorldProc.HelloWorld
现在您可以测试运行它了：
DECLARE @J nchar(25)
EXEC hello @J out
PRINT @J
希望这可以帮助。
您可以使用Levenshtein距离算法来比较字符串
在这里，您可以在以下网址找到T-SQL示例：http：//www.kodyaz.com/articles/fuzzy-string-matching-using-levenshtein-distance-sql-server.aspx
CREATE FUNCTION edit_distance(@s1 nvarchar(3999), @s2 nvarchar(3999))
RETURNS int
AS
BEGIN
DECLARE @s1_len int, @s2_len int
DECLARE @i int, @j int, @s1_char nchar, @c int, @c_temp int
DECLARE @cv0 varbinary(8000), @cv1 varbinary(8000)
SELECT
@s1_len = LEN(@s1),
@s2_len = LEN(@s2),
@cv1 = 0x0000,
@j = 1, @i = 1, @c = 0
WHILE @j <= @s2_len
SELECT @cv1 = @cv1 + CAST(@j AS binary(2)), @j = @j + 1
WHILE @i <= @s1_len
BEGIN
SELECT
@s1_char = SUBSTRING(@s1, @i, 1),
@c = @i,
@cv0 = CAST(@i AS binary(2)),
@j = 1
WHILE @j <= @s2_len
BEGIN
SET @c = @c + 1
SET @c_temp = CAST(SUBSTRING(@cv1, @j+@j-1, 2) AS int) +
CASE WHEN @s1_char = SUBSTRING(@s2, @j, 1) THEN 0 ELSE 1 END
IF @c > @c_temp SET @c = @c_temp
SET @c_temp = CAST(SUBSTRING(@cv1, @j+@j+1, 2) AS int)+1
IF @c > @c_temp SET @c = @c_temp
SELECT @cv0 = @cv0 + CAST(@c AS binary(2)), @j = @j + 1
END
SELECT @cv1 = @cv0, @i = @i + 1
END
RETURN @c
END
（功能由Joseph Gama开发）
用法：
select
dbo.edit_distance('Fuzzy String Match','fuzzy string match'),
dbo.edit_distance('fuzzy','fuzy'),
dbo.edit_distance('Fuzzy String Match','fuzy string match'),
dbo.edit_distance('levenshtein distance sql','levenshtein sql server'),
dbo.edit_distance('distance','server')
该算法仅返回stpe计数，即可通过一步替换一个不同的字符来将一个字符串更改为另一个字符串
我也在寻找Levenshtein算法的代码示例，很高兴在这里找到它。当然，我想了解算法是如何工作的，我在上面的例子之一中玩了一点，在Veve发表的内容中我玩了一点。为了更好地理解代码，我使用矩阵创建了EXCEL。
图片说了1000多个字。
通过这个EXCEL，我发现有可能进行其他性能优化。不需要计算右上方红色区域中的所有值。每个红色单元格的值将导致左侧单元格的值加1。这是因为，第二个字符串在该区域中的长度总是比第一个字符串长，这会使每个字符的距离增加1。
您可以通过使用该声明反映了IF @j <= @i和价值增加@i在此之前的语句。
CREATE FUNCTION [dbo].[f_LevenshteinDistance](@s1 nvarchar(3999), @s2 nvarchar(3999))
RETURNS int
AS
BEGIN
DECLARE @s1_len int;
DECLARE @s2_len int;
DECLARE @i int;
DECLARE @j int;
DECLARE @s1_char nchar;
DECLARE @c int;
DECLARE @c_temp int;
DECLARE @cv0 varbinary(8000);
DECLARE @cv1 varbinary(8000);
SELECT
@s1_len = LEN(@s1),
@s2_len = LEN(@s2),
@cv1 = 0x0000 ,
@j = 1 ,
@i = 1 ,
@c = 0
WHILE @j <= @s2_len
SELECT @cv1 = @cv1 + CAST(@j AS binary(2)), @j = @j + 1;
WHILE @i <= @s1_len
BEGIN
SELECT
@s1_char = SUBSTRING(@s1, @i, 1),
@c = @i ,
@cv0 = CAST(@i AS binary(2)),
@j = 1;
SET @i = @i + 1;
WHILE @j <= @s2_len
BEGIN
SET @c = @c + 1;
IF @j <= @i
BEGIN
SET @c_temp = CAST(SUBSTRING(@cv1, @j + @j - 1, 2) AS int) + CASE WHEN @s1_char = SUBSTRING(@s2, @j, 1) THEN 0 ELSE 1 END;
IF @c > @c_temp SET @c = @c_temp
SET @c_temp = CAST(SUBSTRING(@cv1, @j + @j + 1, 2) AS int) + 1;
IF @c > @c_temp SET @c = @c_temp;
END;
SELECT @cv0 = @cv0 + CAST(@c AS binary(2)), @j = @j + 1;
END;
SET @cv1 = @cv0;
END;
RETURN @c;
END;
('jane', 'jeanne')当距离应为2时，输入将返回3的距离。要更正此错误，应添加额外的代码，该代码应进行交换，@s1并且@s2如果@s1长度比短@s2。
在TSQL中，比较两项的最佳和最快方法是将索引表上的表联接在一起的SELECT语句。因此，如果您想受益于RDBMS引擎的优势，这就是我建议实现编辑距离的方式。TSQL循环也可以使用，但是对于大批量比较而言，在其他语言中，Levenstein距离计算将比在TSQL中更快。
我已经针对几个专用于此目的的临时表使用一系列Joins在多个系统中实现了编辑距离。它需要一些繁重的预处理步骤-临时表的准备-但在进行大量比较时效果很好。
简而言之：预处理包括创建，填充和索引临时表。第一个包含参考ID，一个字母列和一个charindex列。该表是通过运行一系列插入查询来填充的，该查询将每个单词分解为字母（使用SELECT SUBSTRING）以创建与源列表中单词包含字母的行一样多的行（我知道很多行，但是SQL Server可以处理数十亿行）行）。然后创建第二个表，该表具有2个字母的列，另一个表具有3个字母的列，依此类推。最终结果是一系列表，其中包含每个单词的参考ID和子字符串，以及它们位置的参考一句话。
完成此操作后，整个游戏就是复制这些表，并在GROUP BY选择查询中将它们与它们的副本连接起来，该查询计算匹配数。这将为每个可能的单词对创建一系列度量，然后将这些度量重新汇总为每对单词的单个Levenstein距离。
从技术上讲，这与Levenstein距离（或其变体）的大多数其他实现有很大不同，因此您需要深入了解Levenstein距离是如何工作的以及为何按原样设计。还应研究替代方案，因为使用该方法最终会获得一系列基础指标，这些指标可以帮助同时计算编辑距离的许多变化形式，从而为您提供有趣的机器学习潜力。
此页面上的先前答案已经提到的另一点：请尝试进行尽可能多的预处理，以消除不需要距离测量的线对。例如，应该排除两个没有共同字母的单词，因为可以从字符串的长度获得编辑距离。或者不要测量同一单词的两个副本之间的距离，因为它本质上为0。或者在进行测量之前删除重复项，如果您的单词列表来自长文本，则同一单词可能会出现多次，因此仅测量一次距离将节省处理时间，等等。