Haskell中（^）的怪异行为

为什么GHCi在下面给出错误的答案？

GHCi

λ> ((-20.24373193905347)^12)^2 - ((-20.24373193905347)^24)
4.503599627370496e15

Python3

>>> ((-20.24373193905347)**12)**2 - ((-20.24373193905347)**24)
0.0

更新 我将实现Haskell的（^）函数，如下所示。

powerXY :: Double -> Int -> Double
powerXY x 0 = 1
powerXY x y
    | y < 0 = powerXY (1/x) (-y)
    | otherwise = 
        let z = powerXY x (y `div` 2)
        in  if odd y then z*z*x else z*z

main = do 
    let x = -20.24373193905347
    print $ powerXY (powerXY x 12) 2 - powerXY x 24 -- 0
    print $ ((x^12)^2) - (x ^ 24) -- 4.503599627370496e15

尽管我的版本看起来没有比@WillemVanOnsem下面提供的版本更正确，但奇怪的是，至少对于这种情况，它给出了正确的答案。

Python与此类似。

def pw(x, y):
    if y < 0:
        return pw(1/x, -y)
    if y == 0:
        return 1
    z = pw(x, y//2)
    if y % 2 == 1:
        return z*z*x
    else:
        return z*z

# prints 0.0
print(pw(pw(-20.24373193905347, 12), 2) - pw(-20.24373193905347, 24))

简短的回答：(^) :: (Num a, Integral b) => a -> b -> a和 之间有区别(**) :: Floating a => a -> a -> a。

该(^)函数仅适用于整数指数。通常，它将使用一种迭代算法，该算法每次都会检查幂是否可以被2整除，然后将幂除以2（如果不可整，则将结果乘以x）。因此，这意味着对于12，它将总共执行六个乘法。如果乘法运算具有一定的舍入误差，则该误差会“爆炸”。正如我们在源代码中看到的那样，该(^)函数实现为：

(^) :: (Num a, Integral b) => a -> b -> a
x0 ^ y0 | y0 < 0    = errorWithoutStackTrace "Negative exponent"
        | y0 == 0   = 1
        | otherwise = f x0 y0
    where -- f : x0 ^ y0 = x ^ y
          f x y | even y    = f (x * x) (y `quot` 2)
                | y == 1    = x
                | otherwise = g (x * x) (y `quot` 2) x         -- See Note [Half of y - 1]
          -- g : x0 ^ y0 = (x ^ y) * z
          g x y z | even y = g (x * x) (y `quot` 2) z
                  | y == 1 = x * z
                  | otherwise = g (x * x) (y `quot` 2) (x * z) -- See Note [Half of y - 1]

(**)至少对于Floats和Doubles而言，该功能是在浮点单元上实现的。确实，如果我们看一下的实现(**)，我们会看到：

instance Floating Float where
    -- …
    (**) x y = powerFloat x y
    -- …

因此powerFloat# :: Float# -> Float# -> Float#，这将重定向到该函数，该函数通常将由编译器链接到相应的FPU操作。

如果(**)改为使用，则对于64位浮点单元也将获得零：

Prelude> (a**12)**2 - a**24
0.0

例如，我们可以在Python中实现迭代算法：

def pw(x0, y0):
    if y0 < 0:
        raise Error()
    if y0 == 0:
        return 1
    return f(x0, y0)


def f(x, y):
    if (y % 2 == 0):
        return f(x*x, y//2)
    if y == 1:
        return x
    return g(x*x, y // 2, x)


def g(x, y, z):
    if (y % 2 == 0):
        return g(x*x, y//2, z)
    if y == 1:
        return x*z
    return g(x*x, y//2, x*z)

如果然后执行相同的操作，我将在本地获取：

>>> pw(pw(-20.24373193905347, 12), 2) - pw(-20.24373193905347, 24)
4503599627370496.0

这与我们(^)在GHCi中获得的价值相同。