有没有机会写“ C major”而不是“ major C”？

我在音乐项目中遇到了一个美学上的小问题，并且困扰了我一段时间。

我有一个类型data Key = C | D | ...，可以Scale从Key和构造一个Mode。该Mode例如主要的和次要的规模进行了区分。

我可以将Mode类型定义为从Keyto 的函数Scale。在这种情况下，模式将使用小写名称（可以），我可以得到一个这样的Scale

aScale = major C

但是音乐家不会这样说话。他们将此比例称为C大尺度，而不是C大尺度。

我想要的是

理想情况下，我想写

aScale = C major

这有可能吗？

我尝试了什么

我可以创建Key一个Scale从构造a的函数Mode，所以我可以写

aScale = c Major

但是我不能将关键限制在构建音阶上。其他事物也需要它们（例如，构建和弦）。也Key应该是的实例Show。

当我使用额外的函数（或值构造函数）时，可以放在Mode后面Key：

aScale = scale C major 与 scale :: Key -> Mode -> Scale

但是额外的单词标度看起来很吵，并且与名称相反，它scale实际上与标度无关。聪明的地方在于major，scale确实是公正flip ($)。

使用a newtype Mode = Major | Minor ...并不会带来太大变化，只是scale需要更加智能：

aScale = scale C Major

解决方案1：

用这个

data Mode  = Major | Minor
data Scale = C Mode | D Mode | E Mode | F Mode | G Mode | A Mode | B Mode 

现在您可以写（用大写字母C和大写字母M）

aScale = C Major

解决方案2a：

这也是可能的

data Mode  = Major | Minor
data Key   = C | D | E | F | G | A | B 

data Scale = Scale Key Mode  

现在你写

aScale = Scale C Major

解决方案2b：

这也是可能的

data Mode  = Major | Minor
data Key   = C | D | E | F | G | A | B 

type Scale = (Key, Mode)  

现在你写

aScale = (C, Major)

这是我不怎么推荐的一种异想天开的解决方案，但是看起来很“音乐”：

infix 8 ♮
(♮) :: Key -> Mode -> Scale
(♮) = (Data.Function.&)
 -- ≡ flip ($)

那你可以写

> C♮ major :: Scale

当然，在这真的是针对的是，你还必须F♯ minor和B♭ major等。

如果您不介意使用多余的运算符，则可以使用&from Data.Function。假设这major是一个函数Key -> Scale，您可以编写C & major。产生一个Scale值：

Prelude Data.Function> :t C & major
C & major :: Scale

已经有好几个答案，但是这里有一个延续传递样式的解决方案可能会有所帮助（可能不是针对此特定示例，而是在需要某种反向应用程序语法的其他情况下）。

使用一些问题域类型的标准定义：

data Mode = Major | Minor                 deriving (Show)
data Key = C | D | E | F | G | A | B      deriving (Show)
data Semitone = Flat | Natural | Sharp    deriving (Show)

data Note = Note Key Semitone             deriving (Show)
data Scale = Scale Note Mode              deriving (Show)
data Chord = Chord [Note]                 deriving (Show)

您可以引入延续传递类型：

type Cont a r = (a -> r) -> r

并编写原始的笔记构建类型以构建如下Cont类型：

a, b, c :: Cont Note r
a = mkNote A
b = mkNote B
c = mkNote C
-- etc.
mkNote a f = f $ Note a Natural

flat, natural, sharp :: Note -> Cont Note r
flat    = mkSemi Flat
natural = mkSemi Natural
sharp   = mkSemi Sharp
mkSemi semi (Note k _) f = f $ Note k semi

然后，音阶，音符和和弦构建函数可以将Conts 解析为任何一种后缀形式的普通类型（即，作为要传递给的延续Cont）：

major, minor :: Note -> Scale
major n = Scale n Major
minor n = Scale n Minor

note :: Note -> Note
note = id

或前缀形式（即以Conts作为参数）：

chord :: [Cont Note [Note]] -> Chord
chord = Chord . foldr step []
  where step f acc = f (:acc)

现在，您可以编写：

> c sharp note
Note C Sharp
> c note
Note C Natural
> c major
Scale (Note C Natural) Major
> b flat note
Note B Flat
> c sharp major
Scale (Note C Sharp) Major
> chord [a sharp, c]
Chord [Note A Sharp,Note C Natural]

请注意，c它本身没有Show实例，但是c note有。

通过对Note类型的修改，您可以轻松地支持两次偶然事件（例如c sharp sharp，与区别d），等等。

但是我不能将关键限制在构建音阶上。其他事物也需要它们（例如，构建和弦）。Key也应该是Show的实例。

您可以使用类型类巧妙地解决此问题：

{-# LANGUAGE FlexibleInstances #-}

data Key = C | D | E | F | G | A | B deriving(Show)

data Mode = Major | Minor

data Scale = Scale Key Mode

class UsesKey t where
  c, d, e, f, g, a, b :: t

instance UsesKey Key where
  c = C
  d = D
  e = E
  f = F
  g = G
  a = A
  b = B

instance UsesKey (Mode -> Scale) where
  c = Scale C
  d = Scale D
  e = Scale E
  f = Scale F
  g = Scale G
  a = Scale A
  b = Scale B

aScale :: Scale
aScale = c Major

现在，您也可以通过定义适当的实例，将小写字母用于其他类型。