KB4525236更改了GetRef的内存消耗（垃圾回收）

在Windows 2016 Server / Windows 10客户端上安装KB4525236后，我们会遇到内存不足的问题。通过调用函数时，内存被垃圾回收时，此安全修复程序似乎已发生更改GetRef。

PréKB4525236

GetRef在实例变量设置为时，在通过调用的函数中创建的每个实例都会被垃圾回收。nothing

帖子KB4525236

在通过调用的函数中创建的每个实例都GetRef保留在内存中，并且仅在整个函数完成时才进行垃圾回收。在循环中创建实例时，这可能会迅速累加并导致内存不足，尤其是在32位进程中。

问题

• 我们在网上找不到任何相关内容，因此我们希望获得其他遇到相同问题的人的确认。
  编辑从零开始：这是相同的问题，但尚未解决
  _{（自KB4524570（2019年11月12日）Windows 10 1903起vbscript.dll class_terminate bug}
• 如果有人可以验证并知道可行的解决方案，那就太好了。

POC

在安装了KB4525236的设备上运行的以下脚本显示了以下情况下垃圾收集的区别：

• 直接调用：仅在第一个实例销毁后才创建第二个实例（这是我们期望的行为）
• 通过调用GetRef：第二个实例在第一个实例被销毁之前创建，因此有两个实例使用内存。

_{另存为：KB4525236.vbs
运行为：wscript KB4525236.vbs}

Dim Name, Log

Class IDummyInstance
  Dim FName
  Sub Class_Initialize
    FName = Name
    Log = Log & "Initialize " & FName & VbNewLine
  End Sub
  Sub Class_Terminate
    Log = Log & "Terminate " & FName & vbNewLine
  End Sub
End Class

Sub CreateDestroyTwoInstances
  Dim DummyInstance
  Name = "First Instance"
  Set DummyInstance = New IDummyInstance
  Set DummyInstance = Nothing
  Name = "Second Instance"
  Set DummyInstance = New IDummyInstance
  Set DummyInstance = Nothing
End Sub

Log = "(1) Direct Call :" & VbNewLine
Call CreateDestroyTwoInstances

Log = VbNewLine & Log & "(2) GetRef Call :" & vbNewLine
Set GetRefCall = GetRef ("CreateDestroyTwoInstances")
Call GetRefCall

MsgBox Log

由于我没有解决方案或没有官方消息解释该问题，因此我在等赏金到期。

我提出了一个不愉快的解决方法，该问题可以在错误修复之前提供帮助。

解决方法是不要使用任何局部变量将对象实例保存在可能通过来执行的过程中GetRef。

代替隐式或显式变量，可以使用局部（如果没有递归，则为全局）字典对象来保存对象实例，并通过该字典进行调用。

Sub CreateDestroyTwoInstances
  Dim Refs
  Set Refs = CreateObject("Scripting.Dictionary")
  Name = "First Instance"
  Refs.Add "DummyInstance", New IDummyInstance
  ' Call Refs("DummyInstance").DoSomething()
  Refs.Remove "DummyInstance"
  Name = "Second Instance"
  Refs.Add "DummyInstance", New IDummyInstance
  ' Call Refs("DummyInstance").DoSomething()
  Refs.Remove "DummyInstance"
End Sub

如果您的脚本不太复杂，那么似乎值得使用。