如何从Perl输出UTF-8？

我正在尝试使用“ utf8”编译指示来编写Perl脚本，并且得到了意外的结果。我正在使用Mac OS X 10.5（Leopard），并且正在使用TextMate进行编辑。我的编辑器和操作系统的所有设置都默认为以utf-8格式写入文件。

但是，当我在文本文件中输入以下内容，将其另存为“ .pl”并执行时，我得到了友好的“带问号的钻石”来代替非ASCII字符。

#!/usr/bin/env perl -w

use strict;
use utf8;

my $str = 'Çirçös';
print( "$str\n" );

知道我在做什么错吗？我期望在输出中得到'Çirçös'，但是我得到的是'.ir s'。

use utf8;不启用Unicode 输出 -它使您可以在程序中键入Unicode。在您print()声明之前，将其添加到程序中：

binmode(STDOUT, ":utf8");

看看是否有帮助。那应该STDOUT以UTF-8而不是普通的ASCII输出。

您可以使用开放式编译指示。

例如。下面将STDOUT，STDIN和STDERR设置为使用UTF-8...。

use open qw/:std :utf8/;

TMTOWTDI，选择了最适合您工作方式的方法。我使用环境方法，因此无需考虑。

在环境中：

export PERL_UNICODE=SDL

在命令行上：

perl -CSDL -le 'print "\x{1815}"';

或使用binmode：

binmode(STDOUT, ":utf8");          #treat as if it is UTF-8
binmode(STDIN, ":encoding(utf8)"); #actually check if it is UTF-8

或使用PerlIO：

open my $fh, ">:utf8", $filename
    or die "could not open $filename: $!\n";

open my $fh, "<:encoding(utf-8)", $filename
    or die "could not open $filename: $!\n";

或使用开放式编译指示：

use open ":encoding(utf8)";
use open IN => ":encoding(utf8)", OUT => ":utf8";

您还想说，您代码中的字符串是utf-8。请参见为什么现代的Perl默认情况下会避免使用UTF-8？。因此，不仅PERL_UNICODE=SDAL要设置PERL5OPT=-Mutf8。

谢谢，终于有了一个解决方案，不要在整个代码中都放置utf8 :: encode。要综合和完成其他情况，例如在utf8中写入和读取文件，并且还可以与utf8中的YAML文件的LoadFile一起使用

use utf8;
use open ':encoding(utf8)';
binmode(STDOUT, ":utf8");

open(FH, ">test.txt"); 
print FH "something éá";

use YAML qw(LoadFile Dump);
my $PUBS = LoadFile("cache.yaml");
my $f = "2917";
my $ref = $PUBS->{$f};
print "$f \"".$ref->{name}."\" ". $ref->{primary_uri}." ";

其中cache.yaml是：

---
2917:
  id: 2917
  name: Semanário
  primary_uri: 2917.xml

在您的shell中执行：$ env | grep LANG

这可能表明您的外壳未使用utf-8语言环境。