检查是否存在行，否则插入

我需要编写一个T-SQL存储过程来更新表中的一行。如果该行不存在，则将其插入。所有这些步骤都由事务包装。

这是用于预订系统的，因此它必须是原子性和可靠的。如果已提交交易并预订了航班，则必须返回true。

我是T-SQL的新手，不确定如何使用@@rowcount。这是我到目前为止所写的。我在正确的道路上吗？我相信这对您来说是一个简单的问题。

-- BEGIN TRANSACTION (HOW TO DO?)

UPDATE Bookings
 SET TicketsBooked = TicketsBooked + @TicketsToBook
 WHERE FlightId = @Id AND TicketsMax < (TicketsBooked + @TicketsToBook)

-- Here I need to insert only if the row doesn't exists.
-- If the row exists but the condition TicketsMax is violated, I must not insert 
-- the row and return FALSE

IF @@ROWCOUNT = 0 
BEGIN

 INSERT INTO Bookings ... (omitted)

END

-- END TRANSACTION (HOW TO DO?)

-- Return TRUE (How to do?)

看一下MERGE命令。你可以做UPDATE，INSERT和DELETE在一个声明。

这是使用的有效实现MERGE
-在进行更新之前检查飞行是否已满，否则进行插入。

if exists(select 1 from INFORMATION_SCHEMA.TABLES T 
              where T.TABLE_NAME = 'Bookings') 
begin
    drop table Bookings
end
GO

create table Bookings(
  FlightID    int identity(1, 1) primary key,
  TicketsMax    int not null,
  TicketsBooked int not null
)
GO

insert  Bookings(TicketsMax, TicketsBooked) select 1, 0
insert  Bookings(TicketsMax, TicketsBooked) select 2, 2
insert  Bookings(TicketsMax, TicketsBooked) select 3, 1
GO

select * from Bookings

然后 ...

declare @FlightID int = 1
declare @TicketsToBook int = 2

--; This should add a new record
merge Bookings as T
using (select @FlightID as FlightID, @TicketsToBook as TicketsToBook) as S
    on  T.FlightID = S.FlightID
      and T.TicketsMax > (T.TicketsBooked + S.TicketsToBook)
  when matched then
    update set T.TicketsBooked = T.TicketsBooked + S.TicketsToBook
  when not matched then
    insert (TicketsMax, TicketsBooked) 
    values(S.TicketsToBook, S.TicketsToBook);

select * from Bookings

我为每个航班假设一行？如果是这样的话：

IF EXISTS (SELECT * FROM Bookings WHERE FLightID = @Id)
BEGIN
    --UPDATE HERE
END
ELSE
BEGIN
   -- INSERT HERE
END

我假设我说的是，因为您的处事方式可能会使航班超额预订，因为当最多有10张票并且您预订20张票时，它将插入新的一行。

在测试行是否存在时传递updlock，rowlock，holdlock提示。

begin tran /* default read committed isolation level is fine */

if not exists (select * from Table with (updlock, rowlock, holdlock) where ...)
    /* insert */
else
    /* update */

commit /* locks are released here */

updlock提示会强制查询对行进行更新锁定（如果该更新已存在），从而防止其他事务修改该行，直到您提交或回滚为止。

holdlock提示会强制查询进行范围锁定，从而防止其他事务添加符合您的过滤条件的行，直到您提交或回滚为止。

行锁提示会强制将粒度锁定到行级别，而不是默认的页面级别，因此您的事务将不会阻止其他事务尝试更新同一页面中不相关的行（但要注意减少争用和增加页之间的权衡）锁定开销-您应该避免在单个事务中使用大量的行级锁定）。

有关更多信息，请参见http://msdn.microsoft.com/en-us/library/ms187373.aspx。

请注意，锁是作为执行锁的语句执行的-调用begin tran并不能使您免于受到其他事物的束缚，而在获得锁之前先将其锁定。您应通过尽快提交事务（延迟获取，提前释放），尝试使SQL保持锁定的时间最短。

请注意，如果您的PK是bigint，则行级锁的有效性可能会降低，因为SQL Server上的内部散列会退化为64位值（不同的键值可能会散列到相同的锁id）。

我正在写我的解决方案。我的方法不支持“如果”或“合并”。我的方法很简单。

INSERT INTO TableName (col1,col2)
SELECT @par1, @par2
   WHERE NOT EXISTS (SELECT col1,col2 FROM TableName
                     WHERE col1=@par1 AND col2=@par2)

例如：

INSERT INTO Members (username)
SELECT 'Cem'
   WHERE NOT EXISTS (SELECT username FROM Members
                     WHERE username='Cem')

说明：

（1）从TableName中选择col1，col2 WHERE col1 = @ par1 AND col2 = @ par2从TableName中选择搜索值

（2）SELECT @ par1，@ par2哪里不存在（1）子查询中是否不存在

（3）插入TableName（2）步骤值

我终于可以使用以下模型在不存在的情况下插入行：

INSERT INTO table ( column1, column2, column3 )
(
    SELECT $column1, $column2, $column3
      WHERE NOT EXISTS (
        SELECT 1
          FROM table 
          WHERE column1 = $column1
          AND column2 = $column2
          AND column3 = $column3 
    )
)

我发现在：

http://www.postgresql.org/message-id/87hdow4ld1.fsf@stark.xeocode.com

这是我最近要做的事情：

set ANSI_NULLS ON
set QUOTED_IDENTIFIER ON
GO
ALTER PROCEDURE [dbo].[cjso_UpdateCustomerLogin]
    (
      @CustomerID AS INT,
      @UserName AS VARCHAR(25),
      @Password AS BINARY(16)
    )
AS 
    BEGIN
        IF ISNULL((SELECT CustomerID FROM tblOnline_CustomerAccount WHERE CustomerID = @CustomerID), 0) = 0
        BEGIN
            INSERT INTO [tblOnline_CustomerAccount] (
                [CustomerID],
                [UserName],
                [Password],
                [LastLogin]
            ) VALUES ( 
                /* CustomerID - int */ @CustomerID,
                /* UserName - varchar(25) */ @UserName,
                /* Password - binary(16) */ @Password,
                /* LastLogin - datetime */ NULL ) 
        END
        ELSE
        BEGIN
            UPDATE  [tblOnline_CustomerAccount]
            SET     UserName = @UserName,
                    Password = @Password
            WHERE   CustomerID = @CustomerID    
        END

    END

您可以使用合并功能来实现。否则，您可以执行以下操作：

declare @rowCount int

select @rowCount=@@RowCount

if @rowCount=0
begin
--insert....

完整的解决方案在下面（包括游标结构）。非常感谢Cassius Porcus提供了begin trans ... commit上面发布的代码。

declare @mystat6 bigint
declare @mystat6p varchar(50)
declare @mystat6b bigint

DECLARE mycur1 CURSOR for

 select result1,picture,bittot from  all_Tempnogos2results11

 OPEN mycur1

 FETCH NEXT FROM mycur1 INTO @mystat6, @mystat6p , @mystat6b

 WHILE @@Fetch_Status = 0
 BEGIN

 begin tran /* default read committed isolation level is fine */

 if not exists (select * from all_Tempnogos2results11_uniq with (updlock, rowlock, holdlock)
                     where all_Tempnogos2results11_uniq.result1 = @mystat6 
                        and all_Tempnogos2results11_uniq.bittot = @mystat6b )
     insert all_Tempnogos2results11_uniq values (@mystat6 , @mystat6p , @mystat6b)

 --else
 --  /* update */

 commit /* locks are released here */

 FETCH NEXT FROM mycur1 INTO @mystat6 , @mystat6p , @mystat6b

 END

 CLOSE mycur1

 DEALLOCATE mycur1
 go

INSERT INTO [DatabaseName1].dbo.[TableName1] SELECT * FROM [DatabaseName2].dbo.[TableName2]
 WHERE [YourPK] not in (select [YourPK] from [DatabaseName1].dbo.[TableName1])

INSERT INTO table ( column1, column2, column3 )
SELECT $column1, $column2, $column3
EXCEPT SELECT column1, column2, column3
FROM table

解决此问题的最佳方法是首先使数据库列为UNIQUE

ALTER TABLE table_name ADD UNIQUE KEY

THEN INSERT IGNORE INTO table_name ，如果该值导致表中存在重复的键/已经存在，则不会插入该值。