我正在编写一个批处理文件以执行其他一些程序。在这种情况下，我需要提示输入密码。我有什么办法掩盖输入文本吗？我不需要打印*******字符而不是输入字符。Linux的密码提示行为（键入时不打印任何内容）就足够了。
@echo off
SET /P variable=Password :
echo %variable%
Pause
这将读取输入内容，但是我无法使用这种方法掩盖文本。
Answers:
在XP和Server 2003之前，您可以使用另一个附带的工具（VBScript）-以下两个脚本可以完成您想要的工作。
首先getpwd.cmd：
@echo off
<nul: set /p passwd=Password:
for /f "delims=" %%i in ('cscript /nologo getpwd.vbs') do set passwd=%%i
echo.
然后getpwd.vbs：
Set oScriptPW = CreateObject("ScriptPW.Password")
strPassword = oScriptPW.GetPassword()
Wscript.StdOut.WriteLine strPassword
在getpwd.vbs简单地使用密码对象到来自用户的输入的密码，然后将它打印到标准输出（下一段将解释为什么不在终端中显示）。
该getpwd.cmd命令脚本有点棘手，但它的基本工作原理如下。
该"<nul: set /p passwd=Password: "命令的作用是输出没有尾随换行符的提示-这是"echo -n"从bashshell 模拟命令的一种偷偷摸摸的方法 。它设置passwd为空字符串作为无关紧要的副作用，并且因为它从nul:设备获取输入，所以不等待输入。
该"for /f "delims=" %%i in ('cscript /nologo getpwd.vbs') do set passwd=%%i"声明最棘手。它在没有Microsoft“广告”的情况下运行VBScript，因此唯一的输出是密码（来自VBscript）"Wscript.StdOut.WriteLine strPassword"。
要捕获带空格的整个输入行，需要将定界符设置为空，否则，您只会得到第一个单词。该"for ... do set ..."位设置passwd为VBScript输出的实际密码。
然后，我们回显空白行（以终止该"Password: "行），并且passwd在代码运行后，密码将位于环境变量中。
如上所述，现在scriptpw.dll仅可用于XP / 2003。为了解决这个问题，您可以简单地将scriptpw.dll文件从Windows\System32XP / 2003系统的文件夹复制到您自己的系统上的Winnt\System32或Windows\System32文件夹。复制DLL之后，您需要通过运行以下命令进行注册：
regsvr32 scriptpw.dll
若要在Vista和更高版本上成功注册DLL，您将需要管理员权限。我还没有研究过这样一个举动的合法性。
如果你没有过度上试图追查并注册旧的DLL文件（为了方便或法律上的原因）敏锐的，还有另一种方式。Windows的更高版本（没有必需的DLL）应该可以使用Powershell。
而且，实际上，您确实应该考虑升级脚本以使其完全使用，因为它是一种比Java语言更强大的脚本语言cmd.exe。但是，如果要将大部分代码保留为cmd.exe脚本（例如，如果有很多不想转换的代码），则可以使用相同的技巧。
首先，修改cmd脚本，使其调用Powershell而不是CScript：
@echo off
for /f "delims=" %%i in ('powershell -file getpwd.ps1') do set passwd=%%i
Powershell脚本同样简单：
$password = Read-Host "Enter password" -AsSecureString
$password = [Runtime.InteropServices.Marshal]::SecureStringToBSTR($password)
$password = [Runtime.InteropServices.Marshal]::PtrToStringAuto($password)
echo $password
尽管需要经过整理才能获得实际的密码文本。
请记住，要在您的计算机上运行本地未签名的Powershell脚本，您可能需要使用以下内容（（严格，虽然很安全）默认值）来修改执行策略：
set-executionpolicy remotesigned
从Powershell本身内部。
scriptpw.dll。
是的-我迟了4年。
但是我找到了一种无需创建外部脚本就可以做到这一点的方法。通过从批处理文件调用powershell命令。
感谢TessellatingHeckler-无需输出到文本文件（我在变量中设置了powershell命令，因为它在for循环中的一行很长很乱）。
@echo off
set "psCommand=powershell -Command "$pword = read-host 'Enter Password' -AsSecureString ; ^
$BSTR=[System.Runtime.InteropServices.Marshal]::SecureStringToBSTR($pword); ^
[System.Runtime.InteropServices.Marshal]::PtrToStringAuto($BSTR)""
for /f "usebackq delims=" %%p in (`%psCommand%`) do set password=%%p
echo %password%
最初，我将其编写为输出到文本文件，然后从该文本文件读取。但是以上方法更好。在一条非常长的，难以理解的行中：
@echo off
powershell -Command $pword = read-host "Enter password" -AsSecureString ; $BSTR=[System.Runtime.InteropServices.Marshal]::SecureStringToBSTR($pword) ; [System.Runtime.InteropServices.Marshal]::PtrToStringAuto($BSTR) > .tmp.txt & set /p password=<.tmp.txt & del .tmp.txt
echo %password%
我将对此进行细分-您可以使用caret将其分成几行^，这要好得多...
@echo off
powershell -Command $pword = read-host "Enter password" -AsSecureString ; ^
$BSTR=[System.Runtime.InteropServices.Marshal]::SecureStringToBSTR($pword) ; ^
[System.Runtime.InteropServices.Marshal]::PtrToStringAuto($BSTR) > .tmp.txt
set /p password=<.tmp.txt & del .tmp.txt
echo %password%
本文介绍了powershell命令的功能。本质上，它使用来获取输入Read-Host -AsSecureString-接下来的两行代码将该安全字符串转换回纯文本，然后使用将该输出（纯文本密码）发送到文本文件>.tmp.txt。然后将该文件读入变量并删除。
for /f "usebackq tokens=*" %%p in (``powershell -Command "$pword = read-host 'Enter Password' -AsSecureString ; $BSTR=[System.Runtime.InteropServices.Marshal]::SecureStringToBSTR($pword); [System.Runtime.InteropServices.Marshal]::PtrToStringAuto($BSTR)"``) do set password=%%p然后echo %password%。注意 我无法获得此注释来正确转义反引号-在“ powershell”之前和在结束“）”之前是两个反引号，但应该是一个反引号。
1.发现（ab）使用XCOPY命令及其/P /L开关的纯批处理解决方案这里（这方面的一些改进可以在这里找到）：
:: Hidden.cmd
::Tom Lavedas, 02/05/2013, 02/20/2013
::Carlos, 02/22/2013
::https://groups.google.com/forum/#!topic/alt.msdos.batch.nt/f7mb_f99lYI
@Echo Off
:HInput
SetLocal EnableExtensions EnableDelayedExpansion
Set "FILE=%Temp%.\T"
Set "FILE=.\T"
Keys List >"%File%"
Set /P "=Hidden text ending with Ctrl-C?: " <Nul
Echo.
Set "HInput="
:HInput_
For /F "tokens=1* delims=?" %%A In (
'"Xcopy /P /L "%FILE%" "%FILE%" 2>Nul"'
) Do (
Set "Text=%%B"
If Defined Text (
Set "Char=!Text:~1,1!"
Set "Intro=1"
For /F delims^=^ eol^= %%Z in ("!Char!") Do Set "Intro=0"
Rem If press Intro
If 1 Equ !Intro! Goto :HInput#
Set "HInput=!HInput!!Char!"
)
)
Goto :HInput_
:HInput#
Echo(!HInput!
Goto :Eof
1.2 基于替换命令的另一种方法
@Echo Off
SetLocal EnableExtensions EnableDelayedExpansion
Set /P "=Enter a Password:" < Nul
Call :PasswordInput
Echo(Your input was:!Line!
Goto :Eof
:PasswordInput
::Author: Carlos Montiers Aguilera
::Last updated: 20150401. Created: 20150401.
::Set in variable Line a input password
For /F skip^=1^ delims^=^ eol^= %%# in (
'"Echo(|Replace.exe "%~f0" . /U /W"') Do Set "CR=%%#"
For /F %%# In (
'"Prompt $H &For %%_ In (_) Do Rem"') Do Set "BS=%%#"
Set "Line="
:_PasswordInput_Kbd
Set "CHR=" & For /F skip^=1^ delims^=^ eol^= %%# in (
'Replace.exe "%~f0" . /U /W') Do Set "CHR=%%#"
If !CHR!==!CR! Echo(&Goto :Eof
If !CHR!==!BS! (If Defined Line (Set /P "=!BS! !BS!" <Nul
Set "Line=!Line:~0,-1!"
)
) Else (Set /P "=*" <Nul
If !CHR!==! (Set "Line=!Line!^!"
) Else Set "Line=!Line!!CHR!"
)
Goto :_PasswordInput_Kbd
2.使用HTA弹出窗口的密码提交者 。这是一个hybrit .bat / jscript / mshta文件，应另存为.bat：
<!-- :
:: PasswordSubmitter.bat
@echo off
for /f "tokens=* delims=" %%p in ('mshta.exe "%~f0"') do (
set "pass=%%p"
)
echo your password is %pass%
exit /b
-->
<html>
<head><title>Password submitter</title></head>
<body>
<script language='javascript' >
window.resizeTo(300,150);
function entperPressed(e){
if (e.keyCode == 13) {
pipePass();
}
}
function pipePass() {
var pass=document.getElementById('pass').value;
var fso= new ActiveXObject('Scripting.FileSystemObject').GetStandardStream(1);
close(fso.Write(pass));
}
</script>
<input type='password' name='pass' size='15' onkeypress="return entperPressed(event)" ></input>
<hr>
<button onclick='pipePass()'>Submit</button>
</body>
</html>
3. 一个自编译的.net混合文件 .Again应该另存为.bat。与其他解决方案不同，它将创建/编译一个小的.exe文件，该文件将被调用（如果希望，可以将其删除）。还需要安装.net框架，但这不是问题：
@if (@X)==(@Y) @end /* JScript comment
@echo off
setlocal enableDelayedExpansion
for /f "tokens=* delims=" %%v in ('dir /b /s /a:-d /o:-n "%SystemRoot%\Microsoft.NET\Framework\*jsc.exe"') do (
set "jsc=%%v"
)
if not exist "%~n0.exe" (
"%jsc%" /nologo /out:"%~n0.exe" "%~dpsfnx0"
)
for /f "tokens=* delims=" %%p in ('"%~n0.exe"') do (
set "pass=%%p"
)
echo your password is !pass!
endlocal & exit /b %errorlevel%
*/
import System;
var pwd = "";
var key;
Console.Error.Write("Enter password: ");
do {
key = Console.ReadKey(true);
if ( (key.KeyChar.ToString().charCodeAt(0)) >= 20 && (key.KeyChar.ToString().charCodeAt(0) <= 126) ) {
pwd=pwd+(key.KeyChar.ToString());
Console.Error.Write("*");
}
if ( key.Key == ConsoleKey.Backspace && pwd.Length > 0 ) {
pwd=pwd.Remove(pwd.Length-1);
Console.Error.Write("\b \b");
}
} while (key.Key != ConsoleKey.Enter);
Console.Error.WriteLine();
Console.WriteLine(pwd);
我可能会做：
..
echo Before you enter your password, make sure no-one is looking!
set /P password=Password:
cls
echo Thanks, got that.
..
这样您会得到提示，然后在输入后清除屏幕。
请注意，如果从命令提示符处执行批处理文件，则输入的密码将存储在CMD历史记录中（谢谢）。 @Mark K Cowan）。
如果那还不够好，我要么切换到python，要么编写可执行文件而不是脚本。
我知道这些都不是完美的，但是也许对你来说足够好了:)
doskey /reinstall之后立即运行以清除先前的命令缓冲区cls。
C:\>start "console" cmd /c ireadconsole.bat
您可以对所有类型的格式化输入使用ReadFormattedLine子例程。例如，下面的命令读取8个字符的密码，在屏幕上显示星号，然后自动继续而不需要按Enter键：
call :ReadFormattedLine password="********" /M "Enter password (8 chars): "
该子例程是用纯批处理编写的，因此它不需要任何其他程序，并且允许几种格式化的输入操作，例如只读数字，将字母转换为大写字母等。您可以从“ 读取具有特定格式的行”中下载ReadFormattedLine子例程。
编辑2018-08-18：输入“隐形”密码的新方法
FINDSTR命令有一个奇怪的错误，当此命令用于以彩色显示字符并且此命令的输出重定向到CON设备时，会发生此错误。有关如何使用FINDSTR命令以彩色显示文本的详细信息，请参见本主题。
当这种形式的FINDSTR命令的输出重定向到CON时，以期望的颜色输出文本后会发生一些奇怪的事情：将所有文本输出为“不可见”字符，尽管更精确的描述是该文本是输出为黑色背景上的黑色文本。如果您使用COLOR命令重设整个屏幕的前景色和背景色，则将显示原始文本。但是，当文本为“不可见”时，我们可以执行SET / P命令，因此输入的所有字符都不会出现在屏幕上。
@echo off
setlocal
set /P "=_" < NUL > "Enter password"
findstr /A:1E /V "^$" "Enter password" NUL > CON
del "Enter password"
set /P "password="
cls
color 07
echo The password read is: "%password%"
另一个选择是我的EditV32（x86）或EditV64（x64）命令行工具。例如：
editv32 -m -p "Password: " PWD
-m表示“掩码输入”，-p表示提示符。用户的输入存储在PWD环境变量中。你可以在这里得到它：
如果缺乏源代码困扰您，我还有另一种选择。
@echo off
for /f "delims=" %%p in ('ReadLine -h -p "Enter password: "') do set PWD=%%p
echo You entered: %PWD%
您可以从https://westmesatech.com/?page_id=49获得。包含源代码。
我使用Blorgbeard的上述解决方案，这在我看来确实很棒。然后，我对其进行了如下增强：
像这样使用它：
@echo off
ansicon -p
set /p pwd=Password:ESC[0;37;47m
echo ESC[0m
这会将您的密码输入控制台切换为灰色到灰色，完成后又切换回灰色。ESC实际上应该是不可打印的字符，您可以将其从下载的示例文本文件（在记事本中看起来像左箭头）复制到批处理文件中。您可以使用示例文本文件查找所有颜色组合的代码。
如果您不是计算机的管理员，则可以将文件安装在非系统目录中，然后在调用程序和使用转义序列之前，必须将目录附加到脚本中的PATH中。如果您只需要几个文件的非管理员可分发软件包，则可能甚至是当前目录。
创建一个调用不可见字符所需的批处理文件，然后为要调用的批处理文件创建快捷方式。
右键点击
属性
颜色
文字==黑色
背景==黑色
应用
好
希望对您有帮助！！！！！
更新：
我添加了两个新方法，它们没有使用cls隐藏输入，而是创建了仅用一行显示的新弹出窗口。
缺点是一种方法（方法2）会在注册表中留下垃圾-“如果没有适当的权限运行”，而另一种方法（方法3）会在脚本中添加一些垃圾。不用说，它可以轻松地写入任何tmp文件并删除，我只是想出一个替代方案。
限制：密码只能是字母数字，不能有其他字符！
@echo off
if "%1"=="method%choice%" goto :method%choice%
::::::::::::::::::
::Your code here::
::::::::::::::::::
cls
echo :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
echo :::: Batch script to prompt for password! :::
echo :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
:choice
echo.
echo 1. First method
echo.
echo 2. Second method
echo.
echo 3. Third method
echo.
set/p choice=Choose a method:
if "%choice%" gtr "3" echo. & echo invalid option & echo. & pause & goto choice
call :vars
set options= %num%%smAlph%%cpAlph%
set pwdLen=6
if "%choice%" == "1" (
set /p=Password: <nul
for /l %%i in (1,1,%pwdLen%) do call :password
) else (
start /wait cmd /c call "%~f0" method%choice%
)
call :result%choice%
::just to see if it worked!
echo.
echo The Password you entered is: "%pwd%"&pause>nul
::::::::::::::::::
::More code here::
::::::::::::::::::
exit /b
:vars
set num=1234567890
set smAlph=abcdefghijklmnopqrstuvwxyz
set cpAlph=ABCDEFGHIJKLMNOPQRSTUVWXYZ
set pwd=
goto :EOF
:method2
call :popUp
setx result %pwd% >nul
goto :EOF
:method3
call :popUp
>> "%~f0" echo.
>> "%~f0" echo :result%choice%
>> "%~f0" echo set pwd=%pwd%
goto :EOF
:popUp
title Password
mode con lines=1 cols=30
color 5a
set /p=Password: <nul
for /l %%i in (1,1,%pwdLen%) do call :password
goto :EOF
:password
:: If you don't want case sensative remove "/cs" but remember to remove %cpAlph% from the %options%
choice /c %options% /n /cs >nul
call SET pwd=%pwd%%%options:~%errorlevel%,1%%
set /p =*<nul
GOTO :EOF
:result2
for /f "tokens=3" %%a in ('reg query hkcu\environment /v result') do set pwd=%%a
setx result "" >nul
reg delete hkcu\environment /v result /f >nul 2>&1
:result1
goto :EOF
::You can delete from here whenever you want.
更新： 我发现sachadee的帖子非常完美，我刚刚在其中添加了“弹出式”怪癖。
@Echo Off
SetLocal EnableDelayedExpansion
if "%1"==":HInput" goto :HInput
set r=r%random%
start /wait cmd /c call "%~f0" :HInput
For /f "tokens=2,13 delims=, " %%a in (
'tasklist /v /fo csv /fi "imagename eq cmd.exe"
^|findstr /v "Windows\\system32\\cmd.exe"
^|findstr "set /p=%r%"'
) do (
set pid=%%a
set Line=%%b
set Line=!Line:%r%=!
set Line=!Line:~,-2!
)
taskkill /pid %pid:"=%>nul
goto :HIEnd
:HInput
SetLocal DisableDelayedExpansion
title Password
mode con lines=2 cols=30
Echo Enter your Code :
Set "Line="
For /F %%# In (
'"Prompt;$H&For %%# in (1) Do Rem"'
) Do Set "BS=%%#"
:HILoop
Set "Key="
For /F "delims=" %%# In (
'Xcopy /W "%~f0" "%~f0" 2^>Nul'
) Do If Not Defined Key Set "Key=%%#"
Set "Key=%Key:~-1%"
SetLocal EnableDelayedExpansion
If Not Defined Key start /min cmd /k mode con lines=1 cols=14 ^&set/p %r%!Line!=&exit
If %BS%==^%Key% (Set /P "=%BS% %BS%" <Nul
Set "Key="
If Defined Line Set "Line=!Line:~0,-1!"
) Else Set /P "=*" <Nul
If Not Defined Line (EndLocal &Set "Line=%Key%"
) Else For /F delims^=^ eol^= %%# In (
"!Line!") Do EndLocal &Set "Line=%%#%Key%"
Goto :HILoop
:HIEnd
Echo(
Echo Your code is : "!Line!"
Pause
Goto :Eof
我写了一个名为的开源程序editenv，它代替了我以前的editv32/ editv64实用程序：
https://github.com/Bill-Stewart/editenv
在--maskinput（-m）选项[*]让您隐藏（掩码）的打字输入，并具有可配置的字符（默认字符为*）; 例如：
editenv -m -p "Password: " PWD
在--prompt（-p）选项可用于指定的输入提示。上面将显示Password:提示，并等待您输入内容。输入的字符将显示为*。按Ctrl+ C将结束程序，退出代码为1223。
下载在这里：
https://github.com/Bill-Stewart/editenv/releases
[*]请注意--maskinput（-m）选项不安全 -输入的字符串在环境中以纯文本形式输入。此功能仅是为了方便。
这可能是一个较旧的主题，但是如果您使用的是Windows Vista或7，则我有一个很好的解决方案。我在这里制作了一个视频：http : //www.youtube.com/watch?v=mk8uAa6PIFM
批处理文件的Pastebin在这里
@echo off
color 0f
MODE CON COLS=132 LINES=50
:start
cls
choice /C ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789!?.# /N /CS /M Please enter your password to continue. (Valid characters include all letters, numbers, and ! ? .) Press # to submit:
SET ecode=%ERRORLEVEL%
IF %ecode% EQU 66 goto submit
IF %ecode% EQU 1 SET out=A
IF %ecode% EQU 2 SET out=B
IF %ecode% EQU 3 SET out=C
IF %ecode% EQU 4 SET out=D
IF %ecode% EQU 5 SET out=E
IF %ecode% EQU 6 SET out=F
IF %ecode% EQU 7 SET out=G
IF %ecode% EQU 8 SET out=H
IF %ecode% EQU 9 SET out=I
IF %ecode% EQU 10 SET out=J
IF %ecode% EQU 11 SET out=K
IF %ecode% EQU 12 SET out=L
IF %ecode% EQU 13 SET out=M
IF %ecode% EQU 14 SET out=N
IF %ecode% EQU 15 SET out=O
IF %ecode% EQU 16 SET out=P
IF %ecode% EQU 17 SET out=Q
IF %ecode% EQU 18 SET out=R
IF %ecode% EQU 19 SET out=S
IF %ecode% EQU 20 SET out=T
IF %ecode% EQU 21 SET out=U
IF %ecode% EQU 22 SET out=V
IF %ecode% EQU 23 SET out=W
IF %ecode% EQU 24 SET out=X
IF %ecode% EQU 25 SET out=Y
IF %ecode% EQU 26 SET out=Z
IF %ecode% EQU 27 SET out=a
IF %ecode% EQU 28 SET out=b
IF %ecode% EQU 29 SET out=c
IF %ecode% EQU 30 SET out=d
IF %ecode% EQU 31 SET out=e
IF %ecode% EQU 32 SET out=f
IF %ecode% EQU 33 SET out=g
IF %ecode% EQU 34 SET out=h
IF %ecode% EQU 35 SET out=i
IF %ecode% EQU 36 SET out=j
IF %ecode% EQU 37 SET out=k
IF %ecode% EQU 38 SET out=l
IF %ecode% EQU 39 SET out=m
IF %ecode% EQU 40 SET out=n
IF %ecode% EQU 41 SET out=o
IF %ecode% EQU 42 SET out=p
IF %ecode% EQU 43 SET out=q
IF %ecode% EQU 44 SET out=r
IF %ecode% EQU 45 SET out=s
IF %ecode% EQU 46 SET out=t
IF %ecode% EQU 47 SET out=u
IF %ecode% EQU 48 SET out=v
IF %ecode% EQU 49 SET out=w
IF %ecode% EQU 50 SET out=x
IF %ecode% EQU 51 SET out=y
IF %ecode% EQU 52 SET out=z
IF %ecode% EQU 53 SET out=0
IF %ecode% EQU 54 SET out=1
IF %ecode% EQU 55 SET out=2
IF %ecode% EQU 56 SET out=3
IF %ecode% EQU 57 SET out=4
IF %ecode% EQU 58 SET out=5
IF %ecode% EQU 59 SET out=6
IF %ecode% EQU 60 SET out=7
IF %ecode% EQU 61 SET out=8
IF %ecode% EQU 62 SET out=9
IF %ecode% EQU 63 SET out=!
IF %ecode% EQU 64 SET out=?
IF %ecode% EQU 65 SET out=.
SET code=%out%
SET show=*
:loop
cls
choice /C ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789!?.# /N /CS /M Please enter your password to continue. (Valid characters include all letters, numbers, and ! ? .) Press # to submit: %code%
SET ecode=%ERRORLEVEL%
IF %ecode% EQU 66 goto submit
IF %ecode% EQU 1 SET out=A
IF %ecode% EQU 2 SET out=B
IF %ecode% EQU 3 SET out=C
IF %ecode% EQU 4 SET out=D
IF %ecode% EQU 5 SET out=E
IF %ecode% EQU 6 SET out=F
IF %ecode% EQU 7 SET out=G
IF %ecode% EQU 8 SET out=H
IF %ecode% EQU 9 SET out=I
IF %ecode% EQU 10 SET out=J
IF %ecode% EQU 11 SET out=K
IF %ecode% EQU 12 SET out=L
IF %ecode% EQU 13 SET out=M
IF %ecode% EQU 14 SET out=N
IF %ecode% EQU 15 SET out=O
IF %ecode% EQU 16 SET out=P
IF %ecode% EQU 17 SET out=Q
IF %ecode% EQU 18 SET out=R
IF %ecode% EQU 19 SET out=S
IF %ecode% EQU 20 SET out=T
IF %ecode% EQU 21 SET out=U
IF %ecode% EQU 22 SET out=V
IF %ecode% EQU 23 SET out=W
IF %ecode% EQU 24 SET out=X
IF %ecode% EQU 25 SET out=Y
IF %ecode% EQU 26 SET out=Z
IF %ecode% EQU 27 SET out=a
IF %ecode% EQU 28 SET out=b
IF %ecode% EQU 29 SET out=c
IF %ecode% EQU 30 SET out=d
IF %ecode% EQU 31 SET out=e
IF %ecode% EQU 32 SET out=f
IF %ecode% EQU 33 SET out=g
IF %ecode% EQU 34 SET out=h
IF %ecode% EQU 35 SET out=i
IF %ecode% EQU 36 SET out=j
IF %ecode% EQU 37 SET out=k
IF %ecode% EQU 38 SET out=l
IF %ecode% EQU 39 SET out=m
IF %ecode% EQU 40 SET out=n
IF %ecode% EQU 41 SET out=o
IF %ecode% EQU 42 SET out=p
IF %ecode% EQU 43 SET out=q
IF %ecode% EQU 44 SET out=r
IF %ecode% EQU 45 SET out=s
IF %ecode% EQU 46 SET out=t
IF %ecode% EQU 47 SET out=u
IF %ecode% EQU 48 SET out=v
IF %ecode% EQU 49 SET out=w
IF %ecode% EQU 50 SET out=x
IF %ecode% EQU 51 SET out=y
IF %ecode% EQU 52 SET out=z
IF %ecode% EQU 53 SET out=0
IF %ecode% EQU 54 SET out=1
IF %ecode% EQU 55 SET out=2
IF %ecode% EQU 56 SET out=3
IF %ecode% EQU 57 SET out=4
IF %ecode% EQU 58 SET out=5
IF %ecode% EQU 59 SET out=6
IF %ecode% EQU 60 SET out=7
IF %ecode% EQU 61 SET out=8
IF %ecode% EQU 62 SET out=9
IF %ecode% EQU 63 SET out=!
IF %ecode% EQU 64 SET out=?
IF %ecode% EQU 65 SET out=.
SET code=%code%%out%
SET show=%show%*
goto loop
:submit
cls
SET password=%code%
IF %password% EQU 0cZrocks! SET result=1
IF ELSE SET result=2
IF %result% EQU 1 echo password correct
IF %result% EQU 2 echo password incorrect
timeout /T 2 /NOBREAK >nul
cls
IF %result% EQU 1 goto end
IF ELSE goto start
:end
我在网络上阅读了所有笨拙的解决方案，涉及如何在批处理文件中屏蔽密码，使用hide.com解决方案提供的解决方案，甚至使文本和背景颜色相同的解决方案。hide.com解决方案工作得不错，它也不是很安全，并且在64位Windows中也不起作用。因此，无论如何，使用100％Microsoft实用程序是有办法的！
首先，让我解释一下我的用法。我大约有20个可以自动登录Windows的工作站。他们在桌面上有一个快捷方式-用于临床应用程序。机器被锁定，它们无法右键单击，除了访问桌面上的一个快捷方式之外，它们什么也不能做。有时，技术人员需要启动某些调试应用程序，浏览Windows资源管理器并查看日志文件而无需注销自动日志用户帐户。
这就是我所做的。
可以按照自己的意愿进行操作，但是我将两个批处理文件放在了锁定的计算机可以访问的网络共享上。
我的解决方案利用Windows的1个主要组件-runas。在客户端上将要创建的runas.bat的快捷方式。仅供参考，在我的客户上，我将快捷方式重命名为更好的查看目的，并更改了图标。
您将需要创建两个批处理文件。
我将批处理文件命名为runas.bat和Debug Support.bat
runas.bat包含以下代码：
cls
@echo off
TITLE CHECK CREDENTIALS
goto menu
:menu
cls
echo.
echo ....................................
echo ~Written by Cajun Wonder 4/1/2010~
echo ....................................
echo.
@set /p un=What is your domain username?
if "%un%"=="PUT-YOUR-DOMAIN-USERNAME-HERE" goto debugsupport
if not "%un%"=="PUT-YOUR-DOMAIN-USERNAME-HERE" goto noaccess
echo.
:debugsupport
"%SYSTEMROOT%\system32\runas" /netonly /user:PUT-YOUR-DOMAIN-NAME-HERE\%un% "\\PUT-YOUR-NETWORK-SHARE-PATH-HERE\Debug Support.bat"
@echo ACCESS GRANTED! LAUNCHING THE DEBUG UTILITIES....
@ping -n 4 127.0.0.1 > NUL
goto quit
:noaccess
cls
@echo.
@echo.
@echo.
@echo.
@echo \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
@echo \\ \\
@echo \\ Insufficient privileges \\
@echo \\ \\
@echo \\ Call Cajun Wonder \\
@echo \\ \\
@echo \\ At \\
@echo \\ \\
@echo \\ 555-555-5555 \\
@echo \\ \\
@echo \\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\\
@ping -n 4 127.0.0.1 > NUL
goto quit
@pause
:quit
@exit
您可以为要授予访问权限的所有用户添加尽可能多的if“％un％”，如果不是“％un％”。@ping是我的秒计时器定时器。
这样就可以处理第一个批处理文件-非常简单吗？
这是Debug Support.bat的代码：
cls
@echo off
TITLE SUPPORT UTILITIES
goto menu
:menu
cls
@echo %username%
echo.
echo .....................................
echo ~Written by Cajun Wonder 4/1/2010~
echo .....................................
echo.
echo What do you want to do?
echo.
echo [1] Launch notepad
echo.
:choice
set /P C=[Option]?
if "%C%"=="1" goto notepad
goto choice
:notepad
echo.
@echo starting notepad....
@ping -n 3 127.0.0.1 > NUL
start notepad
cls
goto menu
我不是编码员，大约一年前才真正开始使用批处理脚本，而我发现屏蔽批处理文件中的密码的这种方式非常棒！
我希望听到我以外的人可以从中得到一些利用！