批处理文件。删除目录中的所有文件和文件夹

我想要一个批处理文件，该文件将删除我的无线工具包的缓存文件夹中的所有文件夹和文件。

目前，我有以下内容：

cd "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS"
del *.db

这将删除我的RMS目录中的所有.db文件，但是我想从此目录中删除所有单个内容。我怎样才能做到这一点？

del *.*代替del *.db。这将删除所有内容。

用：

• 创建一个批处理文件

• 将以下文本复制到批处理文件中

  set folder="C:\test"
  cd /d %folder%
  for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
  

它将删除所有文件和文件夹。

IF EXIST "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" (
    rmdir "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" /s /q
)

这将从文件夹（和文件夹本身）中删除所有内容。

del *.*将仅删除文件，而不删除子目录。要核对目录的内容，可以使用以下脚本：

@echo off
setlocal enableextensions
if {%1}=={} goto :HELP
if {%1}=={/?} goto :HELP
goto :START

:HELP
echo Usage: %~n0 directory-name
echo.
echo Empties the contents of the specified directory,
echo WITHOUT CONFIRMATION. USE EXTREME CAUTION!
goto :DONE

:START
pushd %1 || goto :DONE
rd /q /s . 2> NUL
popd

:DONE
endlocal

在pushd其中的变化进入目录，你要删除的孩子。然后，当rd要求删除当前目录和所有子目录时，子目录的删除成功，但是当前目录的删除失败-因为我们在其中。这会产生错误并2> NUL吞下。（2是错误流）。

我只是从morty346发布的内容中得出以下结论：

set folder="C:\test"
IF EXIST "%folder%" (
    cd /d %folder%
    for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)
)

它快速检查了变量中定义的文件夹是否首先存在，将目录更改为该文件夹，然后删除了其中的内容。

您可以使用del和/S标志执行此操作（告诉它从所有子目录中递归所有文件）：

del /S C:\Path\to\directory\*

的RD命令也可以使用。递归删除而无提示：

@RD /S /Q %VAR_PATH%

Rmdir（rd）

set "DIR_TO_DELETE=your_path_to_the_folder"

IF EXIST %DIR_TO_DELETE% (
    FOR /D %%p IN ("%DIR_TO_DELETE%\*.*") DO rmdir "%%p" /S /Q
    del %DIR_TO_DELETE%\*.* /F /Q
)

尝试以下方法；这个对我有用。

我有一个将数据转储到我的“ C：\ tmp”文件夹中的应用程序，以下内容对我而言最合适。甚至不要求“ 是”或“ 否”删除数据。我已经制定了每5分钟运行一次的时间表

cd "C:\tmp"

del *.* /Q

更好的是，假设我要删除该C:\windows\temp文件夹下的所有内容。

@echo off
rd C:\windows\temp /s /q

您可以使用robocopy将空文件夹镜像到要清除的文件夹。

robocopy "C:\temp\empty" "C:\temp\target" /E /MIR

如果您无法删除或重新创建实际的文件夹，它也可以使用。

它确实需要一个现有的空目录。

用

set dir="Your Folder Path Here"
rmdir /s %dir%
mkdir %dir%

此版本删除时不询问：

set dir="Your Folder Here"
rmdir /s /q %dir%
mkdir %dir%

例：

set dir="C:\foo1\foo\foo\foo3"
rmdir /s /q %dir%
mkdir %dir%

这将清除C:\foo1\foo\foo\foo3。

_{（我想提一下阿卜杜拉·萨布因的回答。我抄袭他时有些困惑。我没有注意到他的帖子。我要感谢您梅尔波梅内指出了错误！）}

您不能使用任何一项rmdir或全部删除所有内容del：

• rmdir /s /q不接受通配符参数。所以rmdir /s /q *也会出错。
• del /s /f /q 将删除所有文件，但是将保留空的子目录。

我首选的解决方案（正如我在许多其他批处理文件中所使用的）是：

rmdir /s /q . 2>NUL

只是GregM答案的修改版本：

set folder="C:\test"
cd /D %folder%
if NOT %errorlevel% == 0 (exit /b 1)
echo Entire content of %cd% will be deleted. Press Ctrl-C to abort
pause

REM First the directories /ad option of dir
for /F "delims=" %%i in ('dir /b /ad') do (echo rmdir "%%i" /s/q)

REM Now the files /a-d option of dir
for /F "delims=" %%i in ('dir /b /a-d') do (echo del "%%i" /q)

REM To deactivate simulation mode remove the word 'echo' before 'rmdir' and 'del'.

@echo off
@color 0A

echo Deleting logs

rmdir /S/Q c:\log\

ping 1.1.1.1 -n 5 -w 1000 > nul

echo Adding log folder back

md c:\log\

您在正确的轨道上。只需添加代码即可添加再次删除的文件夹。

您应该运行此命令为了删除所有文件：

del*.*