将整数转换为十六进制，并将十六进制转换为整数

78

所以我有这个查询工作 signal_data在Sybase中列中），但在Microsoft SQL Server中不起作用：

HEXTOINT(SUBSTRING((INTTOHEX(signal_data)),5,2)) as Signal

我也在Excel（其中 A1包含值）：

=HEX2DEC(LEFT(DEC2HEX(A1),LEN(DEC2HEX(A1))-2))

有谁知道我将如何在SQL Server中执行此操作？

sql  sql-server  integer  hex 
— 尼克·西纳斯（Nick Sinas）
source

Answers:

117

将INT转换为十六进制：

SELECT CONVERT(VARBINARY(8), 16777215)

将十六进制转换为INT：

SELECT CONVERT(INT, 0xFFFFFF)

更新2015-03-16

上面的示例有一个局限性，即仅在将HEX值指定为整数文字时才起作用。为了完整起见，如果要转换的值是十六进制字符串（例如在varchar列中找到），请使用：

-- If the '0x' marker is present:
SELECT CONVERT(INT, CONVERT(VARBINARY, '0x1FFFFF', 1))

-- If the '0x' marker is NOT present:
SELECT CONVERT(INT, CONVERT(VARBINARY, '1FFFFF', 2))

注意：字符串必须包含偶数个十六进制数字。奇数个数字将产生错误。

可以在CAST和CONVERT（Transact-SQL）的“二进制样式”部分中找到更多详细信息。我认为需要SQL Server 2008或更高版本。

— 比尔·卡温
source
8
将其转换为VARBINARY将以十六进制值给出数据。无法对其执行字符串操作
— Pavan
1
@Bill Karwin，Pavan是正确的。Sql Server 2008可以通过该convert功能来执行此操作，但是2005及以下版本不能。
— 奔
2
当使用8字符十六进制时，例如与ARGB一起转换为BIGINT而不是INT。INT的最大值仅为2,147,483,647或7FFFFFFF。当心使用INT时，返回十六进制的往返行程将起作用，但是结果与Excel的Hex2Dec不同。
— DenverJT
SELECT CONVERT(INT, CONVERT(varbinary, '01', 2))返回12337 （SQL Server 2005）
— Ian Boyd
第一个示例不转换为十六进制：它们转换为二进制。（二进制值的存在独立于任何数字基础：数字基础仅在字符串表示形式的上下文中才有意义。）（此外，该参数不必是文字的（尽管它必须是整数）。）它们似乎正在转换为十六进制，因为在将二进制转换为字符串（例如显示）时，默认情况下以十六进制表示。（这可以用于转换为十六进制，如@KipBryan的答案所示，但DenNukem和wndproc的答案更简单。）
— John B. Lambe
27

SQL Server等同于Excel的基于字符串的DEC2HEX，HEX2DEC函数：

--Convert INT to hex string:
PRINT CONVERT(VARCHAR(8),CONVERT(VARBINARY(4), 16777215),2) --DEC2HEX

--Convert hex string to INT:
PRINT CONVERT(INT,CONVERT(VARBINARY(4),'00FFFFFF',2)) --HEX2DEC
— 基普·布莱恩（Kip Bryan）
source
12

可以使用SQL Server 2012及更高版本上提供的FORMAT函数 

select FORMAT(10,'x2')

结果是：

0a
— 温德普
source
5

传统的4位十六进制非常直接。十六进制字符串到整数（假定值存储在名为FHexString的字段中）：

CONVERT(BIGINT,CONVERT(varbinary(4),
                (SELECT master.dbo.fn_cdc_hexstrtobin(

                    LEFT(FMEID_ESN,8)                       
                ))
                ))

十六进制字符串的整数（假定值存储在名为FInteger的字段中）：

(SELECT master.dbo.fn_varbintohexstr(CONVERT(varbinary,CONVERT(int,
                    FInteger
                ))))

需要注意的重要一点是，当您开始使用引起寄存器共享的位大小时，尤其是在intel机器上，由于Intel的小尾数性质，寄存器中的高，低，左和右将被交换。例如，当使用varbinary（3）时，我们正在谈论的是6个字符的十六进制。在这种情况下，您的位将从右到左配对为以下索引“ 54,32,10”。在英特尔系统中，您会期望“ 76,54,32,10”。由于您仅使用8个中的6个，因此需要记住自己进行交换。“ 76,54”将成为您的左侧，“ 32,10”将成为您的右侧。逗号将您的高低分开。英特尔交换高点和低点，然后交换左和右。因此，要进行转换...例如，您必须自己交换一下，

(SELECT master.dbo.fn_replvarbintoint(
                CONVERT(varbinary(3),(SELECT master.dbo.fn_cdc_hexstrtobin(
                    --intel processors, registers are switched, so reverse them 


                    ----second half
                    RIGHT(FHex8,2)+ --0,1 (0 indexed)
                    LEFT(RIGHT(FHex8,4),2)+ -- 2,3 (oindex)
                    --first half
                    LEFT(RIGHT(FHex8,6),2) --4,5

                )))
                ))

这有点复杂，所以我将尝试将转换保持为8个字符的十六进制（varbinary（4））。

总之，这应该可以回答您的问题。全面地。

— 尼尔·爱德华兹
source
5

这是SQL Server的函数，它将整数值转换为以varchar表示的十六进制表示形式。应该很容易适应其他数据库类型

例如：

SELECT dbo.ToHex(4095) --> FFF

SQL：

CREATE FUNCTION ToHex(@value int)
RETURNS varchar(50)
AS
BEGIN
    DECLARE @seq char(16)
    DECLARE @result varchar(50)
    DECLARE @digit char(1)
    SET @seq = '0123456789ABCDEF'

    SET @result = SUBSTRING(@seq, (@value%16)+1, 1)

    WHILE @value > 0
    BEGIN
        SET @digit = SUBSTRING(@seq, ((@value/16)%16)+1, 1)

        SET @value = @value/16
        IF @value <> 0 SET @result = @digit + @result
    END 

    RETURN @result
END
GO
— 马克西姆·科兹连科
source
这是工作！完善！您只需用“ IF @ value <> 0”替换“ IF @ value 0”
— M07，2014年
我喜欢这种解决方案，因为它很容易修改为功能更强大的解决方案。我提供了使用序列长度作为基础的示例解决方案。
— 格雷格
3

使用master.dbo.fnbintohexstr(16777215)转换为varchar表示。

— 淡蓝色
source
1
select master.sys.fn_varbintohexstr(1)在2008年
— ekkis 2013年
2 
Declare @Dato xml
Set @Dato = Convert(xml, '<dato>FF</dato>')
Select Cast( rw.value( 'xs:hexBinary( text()[1])' , 'varbinary(max)' ) as int ) From @Dato.nodes('dato') as T(rw)
— 多纳恰诺
source
2

Maksym Kozlenko的回答很好，可以稍作修改以处理将数字值编码为任何代码格式的问题。例如：

CREATE FUNCTION [dbo].[IntToAlpha](@Value int)
RETURNS varchar(30)
AS
BEGIN
    DECLARE @CodeChars varchar(100) 
    SET @CodeChars = 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'
    DECLARE @CodeLength int = 26
    DECLARE @Result varchar(30) = ''
    DECLARE @Digit char(1)

    SET @Result = SUBSTRING(@CodeChars, (@Value % @CodeLength) + 1, 1)
    WHILE @Value > 0
    BEGIN
        SET @Digit = SUBSTRING(@CodeChars, ((@Value / @CodeLength) % @CodeLength) + 1, 1)
        SET @Value = @Value / @CodeLength
        IF @Value <> 0 SET @Result = @Digit + @Result
    END 

    RETURN @Result
END

因此，一个很大的数字，例如1.5亿，仅变成6个字符（150,000,000 =“ MQGJMU”）

您还可以使用不同顺序的不同字符作为加密设备。或传递代码字符和字符长度，并用作加密的加密方法。

相反：

CREATE FUNCTION [dbo].[AlphaToInt](@Value varchar(7))
RETURNS int
AS
BEGIN
    DECLARE @CodeChars varchar(100) 
    SET @CodeChars = 'ABCDEFGHIJKLMNOPQRSTUVWXYZ'
    DECLARE @CodeLength int = 26
    DECLARE @Digit char(1)
    DECLARE @Result int = 0
    DECLARE @DigitValue int
    DECLARE @Index int = 0
    DECLARE @Reverse varchar(7)
    SET @Reverse = REVERSE(@Value)

    WHILE @Index < LEN(@Value)
    BEGIN
        SET @Digit = SUBSTRING(@Reverse, @Index + 1, 1)
        SET @DigitValue = (CHARINDEX(@Digit, @CodeChars) - 1) * POWER(@CodeLength, @Index)
        SET @Result = @Result + @DigitValue
        SET @Index = @Index + 1
    END 
    RETURN @Result
— 杰森·吉利
source
1

鉴于：

declare @hexStr varchar(16), @intVal int

IntToHexStr：

select @hexStr = convert(varbinary, @intVal, 1)

HexStrToInt：

declare
    @query varchar(100),
    @parameters varchar(50)

select
    @query = 'select @result = convert(int,' + @hb + ')',
    @parameters = '@result int output'

exec master.dbo.Sp_executesql @query, @parameters, @intVal output
— 鲍勃·普拉特
source
1

马克西姆Kozlenko有一个很好的解决方案，和其他人接近解锁它的全部潜力，但后来完全错过向意识到，你可以定义任何字符序列，而使用它的长度为基。这就是为什么我喜欢他的解决方案的这个经过稍微修改的版本，因为它可以用于base 16或base 17等。

例如，如果您想要字母和数字，但又不喜欢我看起来像1，而O喜欢看起来像0，该怎么办呢？您可以通过这种方式定义任何序列。以下是“基础36”的一种形式，它跳过了I和O来创建“修改后的基础34”。取消注释十六进制行，改为运行为十六进制。

declare @value int = 1234567890

DECLARE @seq varchar(100) = '0123456789ABCDEFGHJKLMNPQRSTUVWXYZ' -- modified base 34
--DECLARE @seq varchar(100) = '0123456789ABCDEF' -- hex
DECLARE @result varchar(50)
DECLARE @digit char(1)
DECLARE @baseSize int = len(@seq)
DECLARE @workingValue int = @value

SET @result = SUBSTRING(@seq, (@workingValue%@baseSize)+1, 1)

WHILE @workingValue > 0
BEGIN
    SET @digit = SUBSTRING(@seq, ((@workingValue/@baseSize)%@baseSize)+1, 1)

    SET @workingValue = @workingValue/@baseSize
    IF @workingValue <> 0 SET @result = @digit + @result
END 

select @value as Value, @baseSize as BaseSize, @result as Result

值，基本大小，结果

1234567890、34，T5URAA

我还根据个人喜好将价值移至工作价值，然后从工作价值副本中开展工作。

以下是用于反转任何序列的转换的附加内容，其碱基定义为序列的长度。

declare @value varchar(50) = 'T5URAA'

DECLARE @seq varchar(100) = '0123456789ABCDEFGHJKLMNPQRSTUVWXYZ' -- modified base 34
--DECLARE @seq varchar(100) = '0123456789ABCDEF' -- hex
DECLARE @result int = 0
DECLARE @digit char(1)
DECLARE @baseSize int = len(@seq)
DECLARE @workingValue varchar(50) = @value

DECLARE @PositionMultiplier int = 1
DECLARE @digitPositionInSequence int = 0

WHILE len(@workingValue) > 0
BEGIN
    SET @digit = right(@workingValue,1)
    SET @digitPositionInSequence = CHARINDEX(@digit,@seq)
    SET @result = @result + ( (@digitPositionInSequence -1) * @PositionMultiplier)

    --select @digit, @digitPositionInSequence, @PositionMultiplier, @result

    SET @workingValue = left(@workingValue,len(@workingValue)-1)
    SET @PositionMultiplier = @PositionMultiplier * @baseSize
END 

select @value as Value, @baseSize as BaseSize, @result as Result
— 格雷格
source
0 
IIF(Fields!HIGHLIGHT_COLOUR.Value="","#FFFFFF","#" & hex(Fields!HIGHLIGHT_COLOUR.Value) & StrDup(6-LEN(hex(Fields!HIGHLIGHT_COLOUR.Value)),"0"))

正在为我作为字体颜色的一种表达方式

— 朱利安
source
0

过去已经使用过将十六进制字符串转换为INT的方法。可以对其进行修改，以将任何基数实际上转换为INT（八进制，二进制，任何形式）

Declare @Str varchar(200)
Set @str = 'F000BE1A'

Declare @ndx int
Set @ndx = Len(@str)
Declare @RunningTotal  BigInt
Set @RunningTotal = 0

While @ndx > 0
Begin
    Declare @Exponent BigInt
    Set @Exponent = Len(@Str) - @ndx

    Set @RunningTotal = @RunningTotal + 

    Power(16 * 1.0, @Exponent) *
    Case Substring(@str, @ndx, 1)
        When '0' then 0
        When '1' then 1
        When '2' then 2 
        When '3' then 3
        When '4' then 4
        When '5' then 5
        When '6' then 6
        When '7' then 7
        When '8' then 8
        When '9' then 9
        When 'A' then 10
        When 'B' then 11
        When 'C' then 12
        When 'D' then 13
        When 'E' then 14
        When 'F' then 15
    End
    Set @ndx = @ndx - 1
End

Print @RunningTotal
— j_s_kelley
source
0

下面是两个函数：dbo.HexToInt和dbo.IntToHex，我将它们用于这种转换：

if OBJECT_ID('dbo.HexToInt') is not null
    drop function dbo.HexToInt
GO
create function dbo.HexToInt (@chars varchar(max))
returns int
begin
    declare @char varchar(1), @len int, @i int, @r int, @tmp int, @pow int
    set @chars = RTRIM(LTRIM(@chars))
    set @len = LEN(@chars)
    set @i = 1
    set @r = 0
    while @i <= @len
    begin
        set @pow = @len - @i
        set @char = SUBSTRING(@chars, @i, 1)
        if @char = '0'
            set @tmp = 0
        else if @char = '1'
            set @tmp = 1
        else if @char = '2'
            set @tmp = 2
        else if @char = '3'
            set @tmp = 3
        else if @char = '4'
            set @tmp = 4
        else if @char = '5'
            set @tmp = 5
        else if @char = '6'
            set @tmp = 6
        else if @char = '7'
            set @tmp = 7
        else if @char = '8'
            set @tmp = 8
        else if @char = '9'
            set @tmp = 9
        else if @char = 'A'
            set @tmp = 10
        else if @char = 'B'
            set @tmp = 11
        else if @char = 'C'
            set @tmp = 12
        else if @char = 'D'
            set @tmp = 13
        else if @char = 'E'
            set @tmp = 14
        else if @char = 'F'
            set @tmp = 15
        set @r = @r + @tmp * POWER(16,@pow)
        set @i = @i + 1     
    end
    return @r
end

第二个：

if OBJECT_ID('dbo.IntToHex') is not null
    drop function dbo.IntToHex
GO
create function dbo.IntToHex (@val int)
returns varchar(max)
begin
    declare @r varchar(max), @tmp int, @v1 int, @v2 int, @char varchar(1)
    set @tmp = @val
    set @r = ''
    while 1=1
    begin
        set @v1 = @tmp / 16
        set @v2 = @tmp % 16
        if @v2 = 0
            set @char = '0'
        else if @v2 = 1
            set @char = '1'
        else if @v2 = 2
            set @char = '2'
        else if @v2 = 3
            set @char = '3'
        else if @v2 = 4
            set @char = '4'
        else if @v2 = 5
            set @char = '5'
        else if @v2 = 6
            set @char = '6'
        else if @v2 = 7
            set @char = '7'
        else if @v2 = 8
            set @char = '8'
        else if @v2 = 9
            set @char = '9'
        else if @v2 = 10
            set @char = 'A'
        else if @v2 = 11
            set @char = 'B'
        else if @v2 = 12
            set @char = 'C'
        else if @v2 = 13
            set @char = 'D'
        else if @v2 = 14
            set @char = 'E'
        else if @v2 = 15
            set @char = 'F'
        set @tmp = @v1 
        set @r = @char + @r
        if @tmp = 0
            break
    end
    return @r
end
— 字节
source
By using our site, you acknowledge that you have read and understand our Cookie Policy and Privacy Policy.
Licensed under cc by-sa 3.0 with attribution required.