CMake和CTest：make测试不会建立测试

我正在CMake中尝试CTest，以便使用来自动运行某些测试 make testtarget。问题在于CMake不能“理解”我愿意运行的测试，因为它是项目的一部分，因此必须进行构建。

因此，我正在寻找一种明确指定此依赖性的方法。

可以说这是CMake的一个错误（以前在这里跟踪），它无法立即使用。解决方法是执行以下操作：

add_test(TestName ExeName)
add_custom_target(check COMMAND ${CMAKE_CTEST_COMMAND}
                  DEPENDS ExeName)

然后可以运行make check，它将编译并运行测试。如果您有多个测试，则必须DEPENDS exe1 exe2 exe3 ...在上一行中使用。

实际上有一种使用方法make test。您需要将测试可执行文件的构建定义为测试之一，然后在测试之间添加依赖项。那是：

ADD_TEST(ctest_build_test_code
         "${CMAKE_COMMAND}" --build ${CMAKE_BINARY_DIR} --target test_code)
ADD_TEST(ctest_run_test_code test_code)
SET_TESTS_PROPERTIES(ctest_run_test_code
                     PROPERTIES DEPENDS ctest_build_test_code)

我使用richq的答案的变体。在顶层CMakeLists.txt，我添加了一个自定义目标build_and_test，用于构建和运行所有测试：

find_package(GTest)
if (GTEST_FOUND)
    enable_testing()
    add_custom_target(build_and_test ${CMAKE_CTEST_COMMAND} -V)
    add_subdirectory(test)
endif()

在下的各个子项目CMakeLists.txt文件中test/，我将每个测试可执行文件添加为以下项的依赖项build_and_test：

include_directories(${CMAKE_SOURCE_DIR}/src/proj1)
include_directories(${GTEST_INCLUDE_DIRS})
add_executable(proj1_test proj1_test.cpp)
target_link_libraries(proj1_test ${GTEST_BOTH_LIBRARIES} pthread)
add_test(proj1_test proj1_test)
add_dependencies(build_and_test proj1_test)

使用这种方法，我只需要make build_and_test代替make test（或make all test），它的好处是仅构建测试代码（及其依赖项）。可惜我不能使用目标名称test。就我而言，这还不错，因为我有一个顶层脚本，该脚本通过调用cmake然后进行树外调试和发行（和交叉编译）make，并将其转换test为build_and_test。

显然，不需要GTest东西。我只是碰巧使用/喜欢Google Test，并想与CMake / CTest分享使用它的完整示例。恕我直言，这种方法还具有允许我使用的好处ctest -V，它可以在测试运行时显示Google Test的输出：

1: Running main() from gtest_main.cc
1: [==========] Running 1 test from 1 test case.
1: [----------] Global test environment set-up.
1: [----------] 1 test from proj1
1: [ RUN      ] proj1.dummy
1: [       OK ] proj1.dummy (0 ms)
1: [----------] 1 test from proj1 (1 ms total)
1:
1: [----------] Global test environment tear-down
1: [==========] 1 test from 1 test case ran. (1 ms total)
1: [  PASSED  ] 1 test.
1/2 Test #1: proj1_test .......................   Passed    0.03 sec

如果您尝试模仿make check，则可能会发现此Wiki条目有用：

http://www.cmake.org/Wiki/CMakeEmulateMakeCheck

我刚刚检查了它是否成功说明了问题（CMake 2.8.10）。

避免头痛：

make all test

对于我来说，它是开箱即用的，并且会在运行测试之前建立依赖关系。鉴于这很简单，它几乎使本机make test功能变得很方便，因为即使您的代码已损坏，它也使您可以选择运行最后的编译测试。

如果您使用的是CMake> = 3.7，则建议的方法是使用灯具：

add_executable(test test.cpp)
add_test(test_build
  "${CMAKE_COMMAND}"
  --build "${CMAKE_BINARY_DIR}"
  --config "$<CONFIG>"
  --target test
)
set_tests_properties(test_build PROPERTIES FIXTURES_SETUP    test_fixture)
add_test(test test)
set_tests_properties(test       PROPERTIES FIXTURES_REQUIRED test_fixture)

这将执行以下操作：

• 添加test从中构建的可执行目标test.cpp
• 添加一个test_build运行Cmake的“测试”以构建目标test
• 将test_build测试标记为夹具的设置任务test_fixture
• 添加一个test仅运行test可执行文件的测试
• 标记test测试需要夹具test_fixture。

因此，每次test要运行测试时，它都会首先运行test test_build，它会构建必要的可执行文件。

这是我锤击并一直使用的：

set(${PROJECT_NAME}_TESTS a b c)

enable_testing()
add_custom_target(all_tests)
foreach(test ${${PROJECT_NAME}_TESTS})
        add_executable(${test} EXCLUDE_FROM_ALL ${test}.cc)
        add_test(NAME ${test} COMMAND $<TARGET_FILE:${test}>)
        add_dependencies(all_tests ${test})
endforeach(test)

build_command(CTEST_CUSTOM_PRE_TEST TARGET all_tests)
string(CONFIGURE \"@CTEST_CUSTOM_PRE_TEST@\" CTEST_CUSTOM_PRE_TEST_QUOTED ESCAPE_QUOTES)
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake" "set(CTEST_CUSTOM_PRE_TEST ${CTEST_CUSTOM_PRE_TEST_QUOTED})" "\n")

青年汽车

Derrick的答案经过简化和评论：

# It is impossible to make target "test" depend on "all":
# https://gitlab.kitware.com/cmake/cmake/-/issues/8774
# Set a magic variable in a magic file that tells ctest
# to invoke the generator once before running the tests:
file(WRITE "${CMAKE_BINARY_DIR}/CTestCustom.cmake"
    "set(CTEST_CUSTOM_PRE_TEST ${CMAKE_MAKE_PROGRAM})\n"
)

这不是完全正确的，因为它不能解决running的并发问题ninja all test，以防万一有人这样做。相反，因为现在有两个忍者进程。

（Ftr，我也在这里共享了此解决方案。）

以上所有答案都是完美的。但是实际上CMake使用CTest作为其测试工具，因此执行任务的标准方法（我认为是）是：

enable_testing ()
add_test (TestName TestCommand)
add_test (TestName2 AnotherTestCommand)

然后运行cmake的和使建立的目标。之后，您可以运行make test，也可以只运行

ctest

您将得到结果。这是在CMake 2.8下测试的。

在以下位置检查详细信息：http : //cmake.org/Wiki/CMake/Testing_With_CTest#Simple_Testing

所有的答案都是好的，但它们暗示着违反传统，只能凭命令进行测试make test。我已经完成了这个技巧：

add_test(NAME <mytest>
WORKING_DIRECTORY ${CMAKE_BINARY_DIR}
COMMAND sh -c "make <mytarget>; $<TARGET_FILE:<mytarget>>")

这意味着测试由构建（可选）和运行可执行目标组成。