如何在awk中将定界字符串拆分成数组？

字符串中包含管道符号时如何拆分|。我想将它们拆分为数组。

我试过了

echo "12:23:11" | awk '{split($0,a,":"); print a[3] a[2] a[1]}'

哪个工作正常。如果我的字符串是类似的，"12|23|11"那么如何将它们拆分为数组？

你有没有尝试过：

echo "12|23|11" | awk '{split($0,a,"|"); print a[3],a[2],a[1]}'

要将字符串拆分为数组，请awk使用函数split()：

 awk '{split($0, a, ":")}'
 #           ^^  ^  ^^^
 #            |  |   |
 #       string  |   delimiter
 #               |
 #               array to store the pieces

如果未指定分隔符，则使用FS，默认为空格：

$ awk '{split($0, a); print a[2]}' <<< "a:b c:d e"
c:d

我们可以给一个分离器，例如:：

$ awk '{split($0, a, ":"); print a[2]}' <<< "a:b c:d e"
b c

这等效于通过以下方式进行设置FS：

$ awk -F: '{split($0, a); print a[1]}' <<< "a:b c:d e"
b c

在gawk中，您还可以提供分隔符作为正则表达式：

$ awk '{split($0, a, ":*"); print a[2]}' <<< "a:::b c::d e" #note multiple :
b c

甚至通过使用第四个参数来了解分隔符在每个步骤中的作用：

$ awk '{split($0, a, ":*", sep); print a[2]; print sep[1]}' <<< "a:::b c::d e"
b c
:::

让我们引用GNU awk的手册页：

split（字符串，数组[，fieldsep [，sep]]）

将字符串划分为由fieldsep分隔的片段，并将片段存储在数组中，并将分隔符字符串存储在seps数组中。第一块存储在中array[1]，第二块存储在中array[2]，依此类推。第三个参数的字符串值fieldsep是一个正则表达式，描述了在哪里拆分字符串（就像FS可以是一个正则表达式，描述了在哪里拆分输入记录）。如果省略fieldsep，则使用FS的值。split()返回创建的元素数。seps是gawk扩展名，seps[i]是之间的分隔符array[i]和array[i+1]。如果fieldsep是单个空格，则任何前导空格都会进入seps[0]，任何尾随空格都会进入seps[n]，其中n是的返回值split()（即数组中元素的数量）。

请更具体！“不起作用”是什么意思？发布确切的输出（或错误消息），您的操作系统和awk版本：

% awk -F\| '{
  for (i = 0; ++i <= NF;)
    print i, $i
  }' <<<'12|23|11'
1 12
2 23
3 11

或者，使用split：

% awk '{
  n = split($0, t, "|")
  for (i = 0; ++i <= n;)
    print i, t[i]
  }' <<<'12|23|11'
1 12
2 23
3 11

编辑：在Solaris上，您需要使用POSIX awk（/ usr / xpg4 / bin / awk）才能正确处理4000个字段。

我不喜欢该echo "..." | awk ...解决方案，因为它调用了不必要的调用fork和exec系统调用。

我更喜欢Dimitre的解决方案

awk -F\| '{print $3 $2 $1}' <<<'12|23|11'

或更短的版本：

awk -F\| '$0=$3 $2 $1' <<<'12|23|11'

在这种情况下，输出记录放在一起是真实条件，因此将其打印出来。

在这种特定情况下，stdin可以通过设置awk 内部变量：

awk -v T='12|23|11' 'BEGIN{split(T,a,"|");print a[3] a[2] a[1]}'

我用了 sh 相当一段时间，但在 重击这可以通过内部字符串操作来管理。在第一种情况下，原始字符串由内部终止符分割。在第二种情况下，假定字符串始终包含由一个字符分隔符分隔的数字对。

T='12|23|11';echo -n ${T##*|};T=${T%|*};echo ${T#*|}${T%|*}
T='12|23|11';echo ${T:6}${T:3:2}${T:0:2}

在所有情况下的结果是

112312

实际上awk具有称为“输入字段分隔符变量” 链接的功能。这是如何使用它。它实际上不是数组，但是使用内部$变量。对于拆分一个简单的字符串，它更容易。

echo "12|23|11" | awk 'BEGIN {FS="|";} { print $1, $2, $3 }'

echo "12|23|11" | awk '{split($0,a,"|"); print a[3] a[2] a[1]}'

应该管用。

echo "12|23|11" | awk '{split($0,a,"|"); print a[3] a[2] a[1]}'

玩笑？:)

怎么样 echo "12|23|11" | awk '{split($0,a,"|"); print a[3] a[2] a[1]}'

这是我的输出：

p2> echo "12|23|11" | awk '{split($0,a,"|"); print a[3] a[2] a[1]}'
112312

所以我想它毕竟在工作。

我知道这是一个古老的问题，但我认为也许有人喜欢我的把戏。特别是由于该解决方案不限于特定数量的项目。

# Convert to an array
_ITEMS=($(echo "12|23|11" | tr '|' '\n'))

# Output array items
for _ITEM in "${_ITEMS[@]}"; do
  echo "Item: ${_ITEM}"
done

输出将是：

Item: 12
Item: 23
Item: 11