检查XSLT中的字符串是否为空或为空

如何使用XSL检查值是否为null或为空？

例如，如果categoryName为空？我在选择构造时使用了a 。

例如：

<xsl:choose>
    <xsl:when test="categoryName !=null">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>

test="categoryName != ''"

编辑：我认为，这涵盖了从问题中得出的对[[not] null or empty“的最可能的解释，包括其伪代码和我自己对XSLT的早期经验。即，“以下Java等价于什么？”：

!(categoryName == null || categoryName.equals(""))

有关更多详细信息，例如，明确标识空值还是空值，请参阅下面的约翰维答案和/或我根据该答案改编的XSLT“小提琴”，其中包括迈克尔·凯的评论中的选项以及第六种可能的解释。

缺少任何其他信息，我将假定以下XML：

<group>
    <item>
        <id>item 1</id>
        <CategoryName>blue</CategoryName>
    </item>
    <item>
        <id>item 2</id>
        <CategoryName></CategoryName>
    </item>
    <item>
        <id>item 3</id>
    </item>
    ...
</group>

一个样例用例如下所示：

<xsl:for-each select="/group/item">
    <xsl:if test="CategoryName">
        <!-- will be instantiated for item #1 and item #2 -->
    </xsl:if>
    <xsl:if test="not(CategoryName)">
        <!-- will be instantiated for item #3 -->
    </xsl:if>
    <xsl:if test="CategoryName != ''">
        <!-- will be instantiated for item #1 -->
    </xsl:if>
    <xsl:if test="CategoryName = ''">
        <!-- will be instantiated for item #2 -->
    </xsl:if>
</xsl:for-each>

从空元素：

测试某个节点的值是否为空

这取决于您的意思是空的。

• 不包含任何子节点： not(node())
• 不包含文字内容： not(string(.))
• 除空格外，不包含其他任何文本： not(normalize-space(.))
• 除评论外不包含任何内容： not(node()[not(self::comment())])

关于什么？

test="not(normalize-space(categoryName)='')"

前两个处理空值，第二个处理空字符串。

<xsl:if test="USER/FIRSTNAME">
    USERNAME is not null
</xsl:if>
<xsl:if test="not(USER/FIRSTNAME)">
    USERNAME is null
 </xsl:if>
 <xsl:if test="USER/FIRSTNAME=''">
     USERNAME is empty string
 </xsl:if>
 <xsl:if test="USER/FIRSTNAME!=''">
     USERNAME is not empty string
 </xsl:if>

在某些情况下，您可能想知道该值何时特别为null，这在使用从.NET对象进行序列化的XML时尤其必要。尽管可接受的答案可以解决此问题，但当字符串为空或为空时，也返回相同的结果，即“''，因此您无法区分。

<group>
    <item>
        <id>item 1</id>
        <CategoryName xsi:nil="true" />
    </item>
</group>

因此，您可以简单地测试属性。

<xsl:if test="CategoryName/@xsi:nil='true'">
   Hello World.
</xsl:if>

有时有必要知道确切的状态，并且您不能简单地检查CategoryName是否已实例化，因为与Javascript不同

<xsl:if test="CategoryName">
   Hello World.
</xsl:if>

对于null元素将返回true。

我知道这个问题很旧，但是在所有答案之间，我都错过了一个在XSLT开发中用例通用的方法。

我正在想象OP中缺少的代码如下所示：

<xsl:template match="category">
    <xsl:choose>
        <xsl:when test="categoryName !=null">
            <xsl:value-of select="categoryName " />
        </xsl:when>
        <xsl:otherwise>
            <xsl:value-of select="other" />
        </xsl:otherwise>
    </xsl:choose>
</category>

输入看起来像这样：

<categories>
    <category>
       <categoryName>Books</categoryName>
    </category>
    <category>
       <categoryName>Magazines</categoryName>
       <categoryName>Periodicals</categoryName>
       <categoryName>Journals</categoryName>
    </category>
    <category>
        <categoryName><!-- please fill in category --></categoryName>
    </category>
    <category>
        <categoryName />
    </category>
    <category />
</categories>

即，我假设可以有零，空，单个或多个categoryName元素。使用xsl:choose-style构造来处理所有这些情况，换句话说，势在必行，很快就会变得混乱（如果元素可以在不同的级别上，则更是如此）。XSLT中典型的编程习惯是使用模板（因此XSLT中的T）是声明性编程，而不是强制性的（您不告诉处理器要做什么，只要满足某些条件，您就可以告诉您想要输出什么）。对于此用例，可能类似于以下内容：

<!-- positive test, any category with a valid categoryName -->
<xsl:template match="category[categoryName[text()]]">
    <xsl:apply-templates />
</xsl:template>

<!-- any other category (without categoryName, "null", with comments etc) -->
<xsl:template match="category">
    <xsl:text>Category: Other</xsl:text>
</xsl:template>

<!-- matching the categoryName itself for easy handling of multiple names -->
<xsl:template match="categoryName">
    <xsl:text>Category: </xsl:text>
    <xsl:value-of select="." />
</xsl:template>

这适用于任何XSLT版本，因为上面的第一个优先级更高（具有谓词）。第二个匹配模板是“穿透”匹配模板，可以捕获所有无效模板。然后，第三个负责输出categoryName以适当的方式值。

请注意，在这种情况下，无需特别匹配categories或category，因为处理器将自动处理所有子项，除非我们另行通知（在此示例中，第二个和第三个模板不会进一步处理子项，因为没有xsl:apply-templatesin他们）。

这种方法比命令式方法更容易扩展，因为它可以自动处理多个类别，并且可以通过添加另一个匹配模板将其扩展为其他元素或例外。无需if分支的编程。

注意：nullXML中没有这样的东西。有xsi：nil，但是很少使用，尤其是在没有某种类型的架构的无类型脚本中很少使用。

如何使用XSL检查值是否为null或为空？

例如，如果categoryName为空？

这可能是最简单的XPath表达式（接受的答案中的一个提供了相反的测试，如果被否定，则更长）：

not(string(categoryName))

说明：

not()上面函数的参数false()恰好在categoryName上下文项没有子代（“ null”）或（单个）categoryName子代有字符串值（即空字符串）的情况下。

我在选择构造时使用了a 。

例如：

<xsl:choose>
    <xsl:when test="categoryName !=null">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>

在XSLT 2.0中使用：

<xsl:copy-of select="concat(categoryName,  $vOther[not(string(current()/categoryName))])"/>

这是一个完整的示例：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
     <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vOther" select="'Other'"/>

 <xsl:template match="/">
  <xsl:copy-of select="concat(categoryName,$vOther[not(string(current()/categoryName))])"/>
 </xsl:template>
</xsl:stylesheet>

在以下XML文档上应用此转换时：

<categoryName>X</categoryName>

产生想要的正确结果：

X

当应用于此XML文档时：

<categoryName></categoryName>

或在此：

<categoryName/>

或在此

<somethingElse>Y</somethingElse>

产生正确的结果：

Other

同样，使用以下XSLT 1.0转换：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:variable name="vOther" select="'Other'"/>

  <xsl:template match="/">
    <xsl:copy-of select=
    "concat(categoryName,  substring($vOther, 1 div not(string(categoryName))))"/>
  </xsl:template>
</xsl:stylesheet>

注意：完全不使用任何条件。在这个不错的Pluralsight课程中了解有关避免条件构造的重要性的更多信息：

“ .NET中的战术设计模式：控制流 ”

如果XML中不存在该元素，我将测试该元素是否存在以及字符串长度是否大于零：

<xsl:choose>
    <xsl:when test="categoryName and string-length(categoryName) &gt; 0">
        <xsl:value-of select="categoryName " />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>

如果节点在输入xml中没有可用值，例如xpath下方，

<node>
    <ErrorCode/>
</node>

string（）函数将转换为空值。所以这很好用：

string(/Node/ErrorCode) =''

这样的事情对我有用：

<xsl:choose>
  <xsl:when test="string(number(categoryName)) = 'NaN'"> - </xsl:when> 
  <xsl:otherwise> 
    <xsl:number value="categoryName" />
  </xsl:otherwise>
</xsl:choose>

或反过来：

<xsl:choose>
  <xsl:when test="string(number(categoryName)) != 'NaN'">
    <xsl:number value="categoryName" />
  </xsl:when> 
  <xsl:otherwise> - </xsl:otherwise>
</xsl:choose>

注意：如果您不检查空值或处理空值，则IE7返回-2147483648而不是NaN。

实际上，我发现仅测试字符串长度会更好，因为很多时候该字段都不为空，而是为空

<xsl：when test =“字符串长度（您要测试的字段）<1”>

以我的经验，最好的方法是：

<xsl:when test="not(string(categoryName))">
    <xsl:value-of select="other" />
</xsl:when>
<otherwise>
    <xsl:value-of select="categoryName" />
</otherwise>

使用简单的categoryName / text（）这样的测试可以正常工作 <categoryName/>和上也<categoryName></categoryName>。

<xsl:choose>
    <xsl:when test="categoryName/text()">
        <xsl:value-of select="categoryName" />
    </xsl:when>
    <xsl:otherwise>
        <xsl:value-of select="other" />
    </xsl:otherwise>
</xsl:choose>