折叠和缩小之间的区别？

尝试学习F＃，但在区分折叠和缩小时感到困惑。折叠似乎做同样的事情，但是需要一个额外的参数。是否存在这两个功能存在的正当理由，或者它们存在以容纳不同背景的人？（例如：字符串和C＃中的字符串）

这是从样本复制的代码片段：

let sumAList list =
    List.reduce (fun acc elem -> acc + elem) list

let sumAFoldingList list =
    List.fold (fun acc elem -> acc + elem) 0 list

printfn "Are these two the same? %A " 
             (sumAList [2; 4; 10] = sumAFoldingList [2; 4; 10])

Foldreduce使用累加器的显式初始值，同时使用输入列表的第一个元素作为初始累加器值。

这意味着累加器及其结果类型必须与列表元素类型匹配，而fold累加器是单独提供的，因此它们可能有所不同。这反映在以下类型中：

List.fold : ('State -> 'T -> 'State) -> 'State -> 'T list -> 'State
List.reduce : ('T -> 'T -> 'T) -> 'T list -> 'T

此外reduce，在空的输入列表上引发异常。

除了什么李先生说，你可以定义reduce来讲fold，而不是（容易）倒过来：

let reduce f list = 
  match list with
  | head::tail -> List.fold f head tail
  | [] -> failwith "The list was empty!"

fold为累加器取一个明确的初始值的事实也意味着该fold函数的结果可以具有与列表中的值类型不同的类型。例如，您可以使用类型的累加器string将列表中的所有数字连接为文本表示形式：

[1 .. 10] |> List.fold (fun str n -> str + "," + (string n)) ""

使用时reduce，累加器的类型与列表中的值的类型相同-这意味着如果您有一个数字列表，则结果必须为数字。要实现先前的示例，您必须string先将数字转换为数字，然后累加：

[1 .. 10] |> List.map string
          |> List.reduce (fun s1 s2 -> s1 + "," + s2)

让我们看看他们的签名：

> List.reduce;;
val it : (('a -> 'a -> 'a) -> 'a list -> 'a) = <fun:clo@1>
> List.fold;;
val it : (('a -> 'b -> 'a) -> 'a -> 'b list -> 'a) = <fun:clo@2-1>

有一些重要的区别：

• 虽然reduce仅对一种类型的元素起作用，但其中的累加器和列表元素fold可能属于不同类型。

• 使用reduce，您可以f对第一个列表元素开始的每个列表元素应用一个函数：

  f (... (f i0 i1) i2 ...) iN。

  使用fold，您可以f从累加器开始申请s：

  f (... (f s i0) i1 ...) iN。

因此，reduce导致一个ArgumentException空列表。而且，fold比reduce; 更通用。您可以fold用来reduce轻松实施。

在某些情况下，使用reduce更为简洁：

// Return the last element in the list
let last xs = List.reduce (fun _ x -> x) xs

如果没有任何合理的累加器，则更为方便：

// Intersect a list of sets altogether
let intersectMany xss = List.reduce (fun acc xs -> Set.intersect acc xs) xss

通常，fold使用任意类型的累加器功能更强大：

// Reverse a list using an empty list as the accumulator
let rev xs = List.fold (fun acc x -> x::acc) [] xs

fold是比reduce。更为重要的函数。您可以根据定义许多不同的功能fold。

reduce只是的子集fold。

折叠的定义：

let rec fold f v xs =
    match xs with 
    | [] -> v
    | (x::xs) -> f (x) (fold f v xs )

折叠定义的功能示例：

let sum xs = fold (fun x y -> x + y) 0 xs

let product xs = fold (fun x y -> x * y) 1 xs

let length xs = fold (fun _ y -> 1 + y) 0 xs

let all p xs = fold (fun x y -> (p x) && y) true xs

let reverse xs = fold (fun x y -> y @ [x]) [] xs

let map f xs = fold (fun x y -> f x :: y) [] xs

let append xs ys = fold (fun x y -> x :: y) [] [xs;ys]

let any p xs = fold (fun x y -> (p x) || y) false xs 

let filter p xs = 
    let func x y =
        match (p x) with
        | true -> x::y
        | _ -> y
    fold func [] xs