无人参与安装后的Office 2010静默激活

我已经使用OCT创建了无人值守的Office 2010安装。我们使用的是MAK而不是KMS（不是我的决定）。安装后有没有激活Office 2010的方法？即使在安装过程中设置了密钥，它也不会激活。

我不希望提示用户激活，因为这将在实验室环境中进行。

万一有人想知道-Office将OSPP.VBS安装在office14目录中，并且可以处理Office激活等问题。

在OCT中，我将其设置为c:\windows\system32\cscript C:\"Program Files (x86)\Microsoft Office\Office14\OSPP.VBS" /act在安装后运行。

之后将激活所有办公产品。我让它静默安装Visio，Project和Office，并在同时激活所有三个产品之后启动Office的激活。

不要
弄混本文的内容，但是我在OCT中使用以下命令进行了设置：[WindowsFolder] \ system32 \ cscript [INSTALLLOCATION] \ OSPP.VBS
参数为/ act

以防万一其他人需要该信息。罗斯

只需将这批文件放在您的sysprep脚本中，即可为您解决问题。在32位和64位系统以及不同的OS上进行了测试。

也许有人可以vbs这个或任何东西。

activateproper.cmd

REM CUSTOMER NAME HERE
REM DATE LAST MODIFIED

set _win7vlk=XXXXX-8FFQX-YYYYY-33XHT-ZZZZZ
set _2010vlk=YYYYY-YYYYY-WQGB6-KW8P8-XXXXX

REM Use current working dir
cd /d "%~dp0"

if not defined _win7vlk if not defined _2010vlk goto :nokey

echo Checking for internet connectivity needed to activate
echo This screen will not progress until internet is established
echo If you are using firewall please disable the firewall temporarily

:LOOP
PING -n 3 google.com|find "TTL" >NUL
IF NOT ERRORLEVEL 1 goto :ENDLOOP
IF     ERRORLEVEL 1 goto :LOOP
:ENDLOOP
echo Internet Detected

echo Change the time
net time \\LANMACHINEWITHCORRECTTIME /set /y

echo Prompt to activate Windows 7 if needed
if exist "%windir%\system32\slmgr.vbs" FOR /F "tokens=5" %%a in ('cscript "%windir%\system32\slmgr.vbs" -xpr') do (set _act=%%a)
if "%_act%" neq "activated." if defined _win7vlk (
    cscript "%windir%\system32\slmgr.vbs" -ipk %_win7vlk%
    cscript "%windir%\system32\slmgr.vbs" -ato
    )

echo Prompt to activate Office 2010 if needed
if exist "%PROGRAMFILES%\Microsoft Office\Office14\WINWORD.exe" set _offver=%PROGRAMFILES%
if exist "%PROGRAMFILES% (x86)\Microsoft Office\Office14\WINWORD.exe" set _offver=%PROGRAMFILES% (x86)

if defined _offver if defined _2010vlk (FOR /F "tokens=3* delims=: " %%a in ('cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /dstatus') do (
    if "%%a" == "---OOB_GRACE---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    if "%%a" == "---OOT_GRACE---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    if "%%a" == "---NOTIFICATIONS---" (cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /inpkey:%_2010vlk%
                    cscript "%_offver%\Microsoft Office\Office14\OSPP.VBS" /act)
    ))



:nokey

您还可以通过设置AUTO_ACTIVATE属性值在安装MAK密钥时激活Office 2010。为此，请按照下列步骤操作：

1. 在OCT中，在左窗格中选择“ 修改设置”属性，然后在右窗格中单击“ 添加 ”。

2. 在“ 添加属性值”对话框的“ 名称”框中，键入AUTO_ACTIVATE。请注意，属性名称必须为大写。

3. 在“ 值”框中，键入1，然后单击“ 确定”。