这将回答您对原始问题的评论中更具体的问题。因为它更具体，所以可能是一个新问题。
要设置当前所选文件的“颜色标签”，可以将AppleScript程序（或使用osascript的shell程序）与可以运行AppleScript的众多“启动器”应用程序（Quicksilver，FastScripts等）结合使用快捷键组合的程序（或Shell程序）。
对于以下任何脚本，请将它们粘贴到“ 脚本编辑器” /“ AppleScript编辑器”中，然后以“脚本”格式（或所选启动器使用的任何格式）保存。保存脚本的通常位置是〜/ Library / Scripts / Applications / Finder，但是根据启动器的不同，您可以使用其他位置。
这是一个简单的版本，您可以将其硬编码到任何一个标签上：
on run
tell application "Finder"
repeat with anItem in (get selection)
(*
* 0 - none
* 1 - Orange
* 2 - Red
* 3 - Yellow
* 4 - Blue
* 5 - Purple
* 6 - Green
* 7 - Gray
*)
set label index of anItem to 4
end repeat
end tell
end run
如果仅使用几个标签，则可以保存几个标签副本，并将密钥绑定到每个副本。
这是一个始终提示您应用哪个标签的版本：
on run
tell application "Finder" to set selectedItems to selection
if length of selectedItems is 0 then
display dialog "Select some items in Finder before running this program." with title "Apply Finder Label to Selected Items" buttons {"OK"} default button {"OK"}
return
end if
set labels to prependIndicies(getLabelNames())
set default to first item of labels
set labelIndex to choose from list labels default items default with prompt "Choose label to apply to selected items" without empty selection allowed and multiple selections allowed
if labelIndex is false then return
set labelIndex to (first word of first item of labelIndex) as number
tell application "Finder"
repeat with anItem in selectedItems
set label index of anItem to labelIndex
end repeat
end tell
end run
to getLabelNames()
set labelNames to {"Orange", "Red", "Yellow", "Blue", "Purple", "Green", "Gray"}
set useCustomLabelNames to true -- change to false if this is too slow or does not work for you
if useCustomLabelNames then
set cmds to {}
repeat with i from 1 to 7
set end of cmds to "defaults read com.apple.Labels Label_Name_" & (8 - i) & " || echo " & quoted form of item i of labelNames
end repeat
set text item delimiters to {";"}
set labelNames to paragraphs of (do shell script (cmds as text))
end if
end getLabelNames
to prependIndicies(theList)
repeat with i from 1 to length of theList
set item i of theList to (i as text) & " - " & (item i of theList)
end repeat
{"0 - none"} & theList
end prependIndicies
出现对话框时，键入0-7之一以选择标签，然后按Return键以将其应用于Finder中选择的项目。