自动热键，如何创建下拉列表以选择项目

我有几个简短的热字符串/热键。如果键入“一个”，则有一个对应的动作；如果键入两个，则有另一个对应的动作。

我的问题是，如何为所有人制作一个热键，当我按下一个键时，将出现一个下拉列表/ msgbox，然后我可以选择一个项目，然后单击它，它将执行基于在下面的列表上？

::one::

{

    do this

    do that

}

return

::two::

{

    do this

    do that

}

return

::three::

{

    do this

    do that

}

return

::four::

{

    do this

    do that

}

return

::five::

{

    do this

    do that

}

return

另外，Autohotkey是学习脚本的好工具吗？还是AutoIT？或者我应该学习主要的脚本语言（例如我通常听到的语言-Perl，PhP等）

我们是那些编程语言能够执行简单的步骤，例如仅记录键盘按下和鼠标移动吗？

。谢谢，

王菲

AHK，例如：

; create the gui:
Gui, +AlwaysOnTop
; DropDownList:
; Gui, Add, DDL, gAction vChoise Choose1 w200, one|two|three|four
; ListBox:
Gui, Add, ListBox, gAction vChoise w200 h60, one|two|three|four
return

; Press F1 to show the gui:
F1::
CoordMode, Mouse, Screen
MouseMove, 40, 50, 0
Gui, Show, x0 y0, Actions
return


Action:
Gui, Submit ; or
; Gui, Submit, NoHide   ; if you don't want to hide the gui-window after an action
If (Choise = "one")
    MsgBox, 1st action 
If (Choise = "two")
    MsgBox, 2nd action
If (Choise = "three")
    MsgBox, 3rd action
If (Choise = "four")
    MsgBox, 4th action
return

GuiClose:
ExitApp

编辑

如果要使用向上/向下箭头和Enter选择操作，则需要向gui 添加默认按钮

或这个：

Gui, +AlwaysOnTop
Gui, Add, ListBox, gAction vChoise w200 h60, one|two|three|four
return

; Press F1 to show the gui:
F1:: Gui, Show, x0 y0, Actions

Action:
If ((A_GuiEvent = "DoubleClick") || (Trigger_Action))
{
    Gui, Submit
    If (Choise = "one")
        MsgBox, 1st action 
    If (Choise = "two")
        MsgBox, 2nd action
    If (Choise = "three")
        MsgBox, 3rd action
    If (Choise = "four")
        MsgBox, 4th action
}
return

#If WinActive("Actions ahk_class AutoHotkeyGUI")

    Enter::
        Trigger_Action := true
        GoSub, Action
        Trigger_Action := false
    return

#If

GuiClose:
ExitApp