当小区D的值改变时，需要VBA代码来清除小区AQ的内容; Microsoft Excel for Office 365 MSO 32位

我会先说这个编程不是我的强项，但我会感激任何帮助。

当单元格D（在同一行上）的值发生变化时，我使用了以下公式来尝试清除单元格AQ的内容。目前，当单元格D中的值变为1时，内容仅在AQ中被清除（可能是由于“如果目标= 1然后”行。我使用什么代替“1”以便所有更改，从任何值到任何值，将启动单元格AQ的ClearContents指令？

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range("D7:D506")) Is Nothing Then
        If Target = 1 Then
            Range("AQ" & Target.Row).ClearContents
        End If
    End If
End Sub

为确保发生真正的更改，我们首先将所选单元格的值保存为公共变量。由于您可以一次选择多个单元格，因此我决定使用公共集合。

然后，当发生更改时，我们将该单元格的新值与集合中的旧值进行比较，并且只有在它们不匹配时才清除AQ的内容。就像是：

Public coll As New Collection

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Dim cel As Range
    Set coll = New Collection
    If Not Intersect(Target, Range("D7:D506")) Is Nothing Then
        For Each cel In Target
            coll.Add cel.Value, cel.Address
        Next cel
    End If
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range("D7:D506")) Is Nothing Then
        If Not Target.Value = coll(Target.Address) Then
           Range("AQ" & Target.Row).ClearContents
        End If
    End If
End Sub

编辑更新以在选择多个单元格时起作用。

显然，如果在Range("D7:D506")没有实际选择单元格的情况下更改值，则此代码将引发错误。

想想看，如果删除该值，可以一次编辑多个单元格。那么这段代码也会抛出一个错误。但我们可以通过使用与Worksheet_Change我们相同的方法来解决这个问题Worksheet_SelectionChange：

Private Sub Worksheet_Change(ByVal Target As Range)
Dim cel As Range
    If Not Intersect(Target, Range("D7:D506")) Is Nothing Then
        For Each cel In Target
            If Not cel.Value = coll(cel.Address) Then
                Range("AQ" & cel.Row).ClearContents
            End If
        Next cel
    End If
End Sub