如何使用键盘快捷键在当前文件夹中打开命令提示符？

如何在Windows 7中使用键盘快捷键在当前文件夹中打开命令提示符？
有什么办法可以实现呢？
我认为Autohotkey可以做到这一点，但不知道如何做。

使用此键盘快捷键：Shift+ Menu，W，Enter

1. Shift+ Menu（或者，Shift+ F10），（在当前文件夹中打开扩展的右键单击菜单）

2. W （选择“在此处打开命令窗口”），

3. Enter（激活选择；因为“ New”也可以通过选择，所以是必需的W）

该Menu键是指由微软推出，通常在右边右侧的特殊键Win键。

在没有任何第三方软件的Windows（7）的默认安装中，可以使用此快捷方式。

AHK方式。您只需要按Win+C（或您要定义的任何方式）：

SetTitleMatchMode RegEx
return

; Stuff to do when Windows Explorer is open
;
#IfWinActive ahk_class ExploreWClass|CabinetWClass

    ; create new text file
    ;
    #t::Send !fwt

    ; open 'cmd' in the current directory
    ;
    #c::
        OpenCmdInCurrent()
    return
#IfWinActive


; Opens the command shell 'cmd' in the directory browsed in Explorer.
; Note: expecting to be run when the active window is Explorer.
;
OpenCmdInCurrent()
{
    ; This is required to get the full path of the file from the address bar
    WinGetText, full_path, A

    ; Split on newline (`n)
    StringSplit, word_array, full_path, `n

    ; Find and take the element from the array that contains address
    Loop, %word_array0%
    {
        IfInString, word_array%A_Index%, Address
        {
            full_path := word_array%A_Index%
            break
        }
    }  

    ; strip to bare address
    full_path := RegExReplace(full_path, "^Address: ", "")

    ; Just in case - remove all carriage returns (`r)
    StringReplace, full_path, full_path, `r, , all


    IfInString full_path, \
    {
        Run,  cmd /K cd /D "%full_path%"
    }
    else
    {
        Run, cmd /K cd /D "C:\ "
    }
}

另外，上面的脚本还使用以下快捷方式创建了一个新的文本文件：Win+T

归功于：Eli Bendersky

按Alt+ D，输入cmd，然后按Enter。有关更多详细信息，请参见此处的博客文章。

在Windows7中执行类似操作的本机方法是按住shift鼠标右键同时将鼠标右键单击要“命令提示符”的文件夹，然后新菜单项将出现在上下文菜单中，为您提供以下确切信息：“在此处打开命令提示符” ”。

如果您想要纯键盘操作，则必须执行以下操作：

• 打开 regedit
• 转到HKEY_CLASSES_ROOT\Directory\shell\cmd并将Extended键重命名为Extended_save
• 转到HKEY_CLASSES_ROOT\Drive\shell\cmd并重命名Extended key toExtended_save`

这会将“此处打开命令窗口”条目永久添加到上下文菜单。您可以通过按以下按钮触发此条目：

• alt
• 放开，上下文菜单打开
• 按下“此处打开命令窗口”条目的“下划线”字符，或使用光标键向下移动并点击 enter

菜单条目的名称根据您的操作系统语言进行标记。

一种替代方法是：

• 通过资源管理器在命令提示符中打开所需的文件夹
• f4
• ctrla
• ctrlc
• winr
• cmd /k cd ctrlventer

它从资源管理器的地址栏中获取当前路径并执行cmd /k cd PATH。使用自动热键，您可以执行相同的操作，但是我不知道自动热键。

从如何通过快捷方式Windows 10在当前文件夹中打开cmd

如果您使用的是Windows 8/10，则有一种更快，更原始的方法：

Alt+ F，P

只需三个键，然后键入两次，无需其他程序的帮助。

由于采用了最新的Windows 10的更新，Leftium的答案的Shift+ Menu，W方法不再起作用。但是，尽管有几次击键，但进行小的修改仍可以提供一种解决方法。

问题是命令提示符在扩展的右键单击菜单中不再可用。相反，您现在拥有Windows Powershell。

Shift+ Menu，S在目标文件夹中打开Windows Powershell。在Windows Powershell中，键入cmd然后按Enter.

这将使您可以访问Windows Powershell中的命令提示符。

聚苯乙烯

Ashwin Nanjappa的方法Ctrl+ L，cmd然后按即可Enter。但是，仅当您不打算返回Windows资源管理器窗口继续在目录之间导航时，它才是优雅的。不幸的是，该方法使Windows资源管理器中的光标远离主窗口，并且需要多次Tab击键才能使其回到使用箭头键浏览文件夹的位置。当您按下这些Tab按键时，视觉确认有限，这可能会令人沮丧。

尽管Windows Powershell在大多数方面的工作方式与命令提示符相同，但我至少遇到一种情况，其中Windows Powershell错误地误读了我的@tag（在生成javadocs时）并且未产生预期的结果。通过cmd在Windows Powershell中键入然后Enter，您可以改用命令提示符来解决此类问题。

最简单的方法是转到Windows资源管理器地址栏并输入cmd，它将立即从该位置打开命令提示符。

AutoHotKey脚本使用@Ashwin的方法打开命令提示符

使用以下命令打开Powershell控制台 Win P

#P::
{
    Send !D
    Send powershell
    Send {Enter}    
    return
}

使用打开命令提示符 Win C

#C::
{
    Send !D
    Send CMD
    Send {Enter}    
    return
}

比所选问题中的脚本更简单的AHK脚本

#c::cmdHere()

cmdHere() {
    If WinActive("ahk_class CabinetWClass") || WinActive("ahk_class ExploreWClass") {
        WinHWND := WinActive()
        For win in ComObjCreate("Shell.Application").Windows
            If (win.HWND = WinHWND) {
                dir := SubStr(win.LocationURL, 9) ; remove "file:///"
                dir := RegExReplace(dir, "%20", " ")
                Break
            }
    }
    Run, cmd, % dir ? dir : A_Desktop
}

来自这里的来源：https : //autohotkey.com/boards/viewtopic.php?t=5796

如果您使用的是德语版本的Windows，则可以执行以下操作：

按Alt+ D，E

Alt+ D打开菜单，您可以在其中选择cmd以外的其他内容

对于AHK，以下是我的约束：

#c::
Run, C:\Windows\system32\cmd.exe
return

这不会打开当前文件夹，但是很方便。