如何设置Outlook阅读窗格的缩放比例？
Answers:
这似乎链接到计算机上的DPI设置以及Outlook中设置的缩放级别。
一件事可能是更改电子邮件上的文本大小-
自定义纯文本消息的字体大小
对于纯文本，您可以通过以下方式修改显示字体
- Outlook 2007和以前的版本：
工具→选项…→选项卡邮件格式→按钮信纸和字体（或在早期版本的Outlook中只是字体…）- Outlook 2010：
文件→选项→邮件部分→按钮信纸和字体
如何在MS Outlook 2010中为传入电子邮件设置默认缩放：
- 开始-Microsoft Office-工具和Microsoft Office-Project VBA的数字证书，使用名称（例如，缩放）创建证书
- 启动Outlook
- 在文件-选项-信任中心-信任中心设置-选项中，选择宏，或“通知所有宏”或“数字签名的宏的通知，所有未签名的宏均被禁用”
- Alt+ F11-运行VBA编辑器
- 在左上方窗口中，单击“草稿项目-MS Outlook对象”，然后双击ThisOutlookSession
- 在右侧打开一个窗口（
View.Zoom.Percentage = 150 - scale默认情况下） - 工具-参考，请检查Microsoft Word 14.0对象库
- F5 -提出一个名称，例如“缩放-创建”
- 工具-数字签名：选择我们先前创建的，名为Zoom的签名
- 文件-保存
- Alt+Q
- 重新启动Outlook
- 出现带有要求添加到受信任区域证书的请求的框。
Option Explicit
Dim WithEvents objInspectors As Outlook.Inspectors
Dim WithEvents objOpenInspector As Outlook.Inspector
Dim WithEvents objMailItem As Outlook.MailItem
Private Sub Application_Startup()
Set objInspectors = Application.Inspectors
End Sub
Private Sub Application_Quit()
Set objOpenInspector = Nothing
Set objInspectors = Nothing
Set objMailItem = Nothing
End Sub
Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
If Inspector.CurrentItem.Class = olMail Then
Set objMailItem = Inspector.CurrentItem
Set objOpenInspector = Inspector
End If
End Sub
Private Sub objOpenInspector_Close()
Set objMailItem = Nothing
End Sub
Private Sub objOpenInspector_Activate()
Dim wdDoc As Word.Document
Set wdDoc = objOpenInspector.WordEditor
wdDoc.Windows(1).Panes(1).View.Zoom.Percentage = 150
End Sub
我很震惊，对于Windows 7上的Outlook 2010没有更好的答案，因此我将进行检查。我所确定的结果非常差：使用Windows 7中的“使您更容易阅读屏幕上的内容”功能，并将总放大倍率设置为125％。不幸的是，您必须先注销然后重新登录才能看到效果，这使实验变得很痛苦。
在Windows 7中，可以通过右键单击桌面，选择“屏幕分辨率”，然后单击底部附近的“使文本和其他项目变大或变小”来访问此功能。还有一个选项“设置自定义文本大小（DPI）”，但是我没有花时间尝试一下。您还可以通过在控制面板搜索中键入“使它更易于阅读”来访问此对话框。
我尝试了150％，但这在某些程序（例如MATLAB）中造成了字体无法接受的降级。在125％的情况下，我对某些效果感到不满意，但是可以平衡阅读所有电子邮件而无法阅读我的电子邮件，这是一个合理的平衡。另一方面，克服一个应用程序中的缺陷是一个很大的缺点，因此我认为当我有很多电子邮件要阅读然后重新切换时，我可能会切换到该模式-尽管注销并重新登录了两次！
我也一直在Outlook 2013中寻找解决方案来解决这个问题，并且刚刚从http://www.sperrysoftware.com/上遇到了一个第三方商业附件，以帮助它解决这个问题，称为“缩放电子邮件Windows加载项” 。 outlook / zoom-email-windows.asp。
我刚刚在Outlook 2013 32bit中安装了该试用版，对我来说效果很好，即它会自动将“阅读窗格”中的缩放值设置为我配置的值。如果您仍在寻找解决方案，我想建议您。
这是更新的Outlook VBA代码，它同时调整了打开的邮件和阅读窗格的大小。Microsoft阻止了对Zoom参数的访问，因此您必须首先安装Redemption驱动程序（http://www.dimastr.com/redemption/home.htm），然后在VBA工具/参考下激活“ Microsoft Word 15.0对象库”和“兑换Outlook和MAPI COM库”。粘贴并运行以下代码，在MsgZoom常量中设置缩放。
Option Explicit
Dim WithEvents objInspectors As Outlook.Inspectors
Dim WithEvents objOpenInspector As Outlook.Inspector
Dim WithEvents objMailItem As Outlook.MailItem
Dim WithEvents myOlExp As Outlook.Explorer
Dim sExplorer As Object
Dim Document As Object
Dim Msg
Const MsgZoom = 130
Private Sub Application_Startup()
Set objInspectors = Application.Inspectors
Set myOlExp = Application.ActiveExplorer
Set sExplorer = CreateObject("Redemption.SafeExplorer")
End Sub
Private Sub Application_Quit()
Set objOpenInspector = Nothing
Set objInspectors = Nothing
Set objMailItem = Nothing
End Sub
Private Sub objInspectors_NewInspector(ByVal Inspector As Inspector)
If Inspector.CurrentItem.Class = olMail Then
Set objMailItem = Inspector.CurrentItem
Set objOpenInspector = Inspector
End If
End Sub
Private Sub objOpenInspector_Close()
Set objMailItem = Nothing
End Sub
Private Sub objOpenInspector_Activate()
Dim wdDoc As Word.Document
Set wdDoc = objOpenInspector.WordEditor
wdDoc.Windows(1).Panes(1).View.Zoom.Percentage = MsgZoom
End Sub
Private Sub myOlExp_SelectionChange()
On Error GoTo ErrHandler:
Set Msg = Application.ActiveExplorer.Selection(1)
Application.ActiveExplorer.RemoveFromSelection (Msg)
Application.ActiveExplorer.AddToSelection (Msg)
sExplorer.Item = Application.ActiveExplorer
Set Document = sExplorer.ReadingPane.WordEditor
Document.Windows.Item(1).View.Zoom.Percentage = MsgZoom
Exit Sub
ErrHandler:
Exit Sub
End Sub